如何使用列表的内容搜索字典

Question

假设我有一个 todo 文件 (todo.txt)，它看起来像这样：

• 就 Foo 项目给 Tom 打电话
• 完成 Bar 项目的总结并发送给 Thomas
• 让 Susan 向我和 Tom 发送她对 Foo 项目的预测

我希望能够编写这些任务并让 Vim 将相应的类别附加到每一行（@ 代表人员，& 代表项目）：

Tom（或 Thomas）应该生成 @Tom， 苏珊应该生成@Susan， Foo 应该生成 &Foo 和 Bar &Bar

因此结果应该是：

• 就 Foo 项目联系 Tom @Tom &Foo
• 完成 Bar 项目的总结并发送给 Thomas @Tom &Bar
• 让 Susan 将她对 Foo 项目的预测发送给我和 Tom @Susan @Tom & Foo

我创建了一个字典：

let dictodo = {'Tom': "@Tom", 'Thomas': "@Tom", 'Susan': "@Susan", 'Foo': "&Foo", 'Bar': "&Bar",}

我怎样才能每次在这个特定文件中创建一个新任务并离开插入模式时有一个自动命令启动一个函数（:autocmd InsertLeave todo.txt :call Filltodo() ？）

1) 这将创建一个包含该行不同单词的列表：我想

let words = split(getline('.'), '\W\+')

2) 使用此列表浏览 dictodo Dictionary

3) 并将字典中对应的单词（2 的 result）附加到行尾？我想

call setline(line('.'), getline('.') . ' ' . result)

如果我对 1) 和 3) 的解决方案没有弄错，那么 2) 是缺少的部分（我尝试了 keyvar 但失败了）

Answer 1

类似这个函数：

function! AddCat(pairs)
  let lines = []
  for line in getline(1,'$')
    let pairs = copy(a:pairs)
    let words = split(line, '\W\+')
    let cats = []
    " Looks for a category for every word and add it only once.
    call map(words,
          \'has_key(pairs, v:val) && index(cats, pairs[v:val]) == -1'
          \ . '? add(cats, pairs[v:val])'
          \ . ': ""')
    " Add the categories if non-empty.
    call add(lines, join([line]+cats))
  endfor
  call setline(1, lines)
endfunction

Define your pairs:

let dictodo = {'Tom': "@Tom", 'Thomas': "@Tom", 'Susan': "@Susan", 'Foo': "&Foo", 'Bar': "&Bar",}

然后这样称呼它：

:call AddCat(dictodo)

注意： @ZyX 的回答比我的更容易理解，我什至将他的建议用于我的。自己去看看吧。

Answer 2

function! s:AppLine(pairs, line)
    let pairs=copy(a:pairs)
    let r=a:line
    for word in split(a:line, '\W\+')
        if has_key(pairs, word)
            let tag=remove(pairs, word)
            call filter(pairs, 'v:val isnot# tag')
            let r.=' '.tag
        endif
    endfor
    return r
endfunction
function! AddCat(pairs)
    return setline('.', s:AppLine(a:pairs, getline('.')))
endfunction

用法：

%call AddCat(dictodo)

Answer 3

我认为你应该使用列表而不是字典。

根据您在问题中提供的构建块，这个快速而幼稚的功能似乎可以满足您的需求。不过要小心：变量的范围不正确，它不会检查是否已经有一些标签。

function! TidyTodo()
  let listodo = [['Tom','@Tom'],['Thomas','@Tom'],['Susan','@Susan'],['Foo','&Foo'],['Bar','&Bar']]
  let words = split(getline('.'), '\W\+')
  let appendix = ''
  for word in words
    for item in listodo
      if word == item[0]
        let appendix = appendix . ' ' . item[1]
      endif
    endfor
  endfor
  call setline(line('.'), getline('.') . appendix)
endfunction