为什么我的共享库在使用 CMake 时链接不正确？

Question

这是一个非常微不足道的问题，可能是由于我对 CMake 缺乏经验。我已按照http://fabzter.com/blog/cmake-tutorial-1 的教程进行操作，但遇到链接问题。

基本上我有一个库 MathFuncs 和一个使用 MathFuncs 的可执行文件。 MathFuncs 的 CMakeLists 是：

cmake_minimum_required(VERSION 2.8)
project(MathFuncs)

include_directories(${PROJECT_SOURCE_DIR})

SET (HEADER_FILES mysqrt.hpp)
add_library(MathFuncs SHARED mysqrt.cpp ${HEADER_FILES})

而可执行的 CMakeLists 是：

cmake_minimum_required (VERSION 2.6)
project (Tutorial)

set (Tutorial_VERSION_MAJOR 1)
set (Tutorial_VERSION_MINOR 0)
set (Tutorial_VERSION_BUGFIX 0)

#configure header file to pass some of the CMake settings 
#to the source code
configure_file(
    "${PROJECT_SOURCE_DIR}/TutorialConfig.h.in"
    "${PROJECT_BINARY_DIR}/TutorialConfig.h"
) 

# add the binary tree to the search path for include files
# so that we will find TutorialConfig.h
include_directories("${PROJECT_BINARY_DIR}")

# add the include directories necessary to build library
include_directories("${PROJECT_SOURCE_DIR}/MathFuncs}")
add_subdirectory(MathFuncs)

SET (MATHFUNCTIONS_DIR ${PROJECT_SOURCE_DIR}/MathFuncs)
add_executable(tutorial tutorial.cpp ${MATHFUNCTIONS_DIR}/mysqrt.hpp)

target_link_libraries(tutorial MathFuncs)

CMake 运行良好。但是，当我尝试使用 Visual Studio 进行编译时，我收到一个链接器错误，指出它无法打开 MathFuncs.lib。当我从 MathFuncs CMakeList 中删除“SHARED”选项时，它会运行，因为它正在构建一个静态库，但是对于我的应用程序，我想要一个共享库 DLL。

如何让 CMake 将库引用设置为共享？

谢谢，

Answer 1

您似乎没有正确地从 DLL 中导出类/函数。详细说明见this article。

这并不完全简单，但幸运的是 CMake 可以在这里提供一些帮助。您可以使用 GenerateExportHeader 模块自动生成包含正确导出库的公共函数所需的所有预处理器定义的标头。

以下是我将如何更改您的文件的示例。希望每个都得到足够的评论，让您了解正在发生的事情。如果没有，请添加评论，我会展开。

顶级 CMakeLists.txt：

cmake_minimum_required (VERSION 3.0)
project(Tutorial)

add_subdirectory(MathFuncs)

set(Tutorial_VERSION_MAJOR 1)
set(Tutorial_VERSION_MINOR 0)
set(Tutorial_VERSION_BUGFIX 0)

# Configure header file to pass some of the CMake settings to the source code.
set(TutorialConfigHeader "${PROJECT_BINARY_DIR}/TutorialConfig.h")
configure_file(TutorialConfig.h.in "${TutorialConfigHeader}")

# Include the output file of 'configure_file' to ensure it gets configured.
add_executable(tutorial tutorial.cpp "${TutorialConfigHeader}")

# Add TutorialConfig.h's path to include dirs for 'tutorial'.
target_include_directories(tutorial PRIVATE "${PROJECT_BINARY_DIR}")

target_link_libraries(tutorial MathFuncs)

# If 'MathFuncs' is a shared lib, copy it to 'tutorial's bin dir so
# it can be found at runtime.
get_target_property(MathFuncsType MathFuncs TYPE)
if(MathFuncsType STREQUAL "SHARED_LIBRARY")
  add_custom_command(TARGET tutorial POST_BUILD
                     COMMAND ${CMAKE_COMMAND} -E copy_if_different
                         $<TARGET_FILE:MathFuncs> $<TARGET_FILE_DIR:tutorial>
                     COMMENT "Copying MathFuncs shared lib alongside tutorial."
                     VERBATIM)
endif()

MathFuncs/CMakeLists.txt：

cmake_minimum_required(VERSION 3.0)
project(MathFuncs)

add_library(MathFuncs SHARED
            mysqrt.cpp
            mysqrt.hpp
            "${PROJECT_BINARY_DIR}/mathfuncs_export.h")

# Write appropriate export PP definitions in a file called
# 'mathfuncs_export.h' in the current binary dir
include(GenerateExportHeader)
generate_export_header(MathFuncs)

# Add the current source dir as a PUBLIC include dir
# (to allow mysqrt.hpp to be found by dependent targets)
# Add the current binary dir as a PUBLIC include dir
# (to allow mathfuncs_export.h to be found by dependent targets)
target_include_directories(MathFuncs PUBLIC
                           ${PROJECT_SOURCE_DIR} ${PROJECT_BINARY_DIR})

然后要使用生成的导出标头，您只需要让 mysqrt.hpp 包含以下内容：

#ifndef MYSQRT_HPP_
#define MYSQRT_HPP_

#include "mathfuncs_export.h"

double MATHFUNCS_EXPORT MySqrt(double input);

#endif  // MYSQRT_HPP_

现在这应该会导致 VS 创建一个导出库 ${CMAKE_BINARY_DIR}/MathFuncs/Debug/MathFuncs.lib（修复链接器问题）和实际的 DLL ${CMAKE_BINARY_DIR}/MathFuncs/Debug/MathFuncs.dll。