从 Internet 下载文件，同时可以随时中止下载答案

【问题标题】：Downloading a file from the Internet while being able to abort the download any time从 Internet 下载文件，同时可以随时中止下载
【发布时间】：2011-04-02 16:27:31
【问题描述】：

我想在专用于下载的单独线程中从我的 Delphi 程序下载文件。

问题是主程序可以随时关闭（因此下载线程也可以随时终止）。因此，即使没有连接或服务器延迟了宝贵的几秒钟，我也需要一种方法在一两秒内终止下载线程。

你们推荐使用什么功能？

我已经尝试过 InterOpenURL/InternetReadFile，但它没有超时参数。它确实有一个异步版本，但我找不到任何可用的 Delphi 示例，我不确定异步版本是否会保护我免于挂起......

之前有人推荐过使用socket，但是TClientSocket好像也没有超时功能。

我需要做好充分准备，这样如果用户在他/她的计算机上出现互联网连接问题或网络服务器一直滞后，我的应用程序在关闭前不会挂起。

在回答我不想使用任何第三方组件或 Indy 时请记住。非常感谢任何示例代码。

谢谢！

【问题讨论】：

InternetReadFile 可以在循环中调用任意数量的字节。如果您将此与线程中的 Terminated 检查结合使用，则在关闭应用程序时将线程标记为终止并等待线程终止，您不应该有任何“挂起”。

标签： multithreading delphi download delphi-7 wininet

【解决方案1】：

这行得通。

var
  DownloadAbort: boolean;

procedure Download(const URL, FileName: string);
var
  hInet: HINTERNET;
  hURL: HINTERNET;
  Buffer: array[0..1023] of AnsiChar;
  BufferLen, amt: cardinal;
  f: file;
const
  UserAgent = 'Delphi Application'; // Change to whatever you wish
begin
  DownloadAbort := false;
  hInet := InternetOpen(PChar(UserAgent), INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  try
    hURL := InternetOpenUrl(hInet, PChar(URL), nil, 0, 0, 0);
    try
      FileMode := fmOpenWrite;
      AssignFile(f, FileName);
      try
        Rewrite(f, 1);
        repeat
          InternetReadFile(hURL, @Buffer, SizeOf(Buffer), BufferLen);
          BlockWrite(f, Buffer[0], BufferLen, amt);
          if DownloadAbort then
            Exit;
        until BufferLen = 0;
      finally
        CloseFile(f);
      end;
    finally
      InternetCloseHandle(hURL);
    end;
  finally
    InternetCloseHandle(hInet);
  end;
end;

实际上，上面的代码将成为你线程的Execute方法的一部分，你不需要DownloadAbort；而是，你检查

if Terminated then
  Exit;

【讨论】：

您好！如果 InternetReadFile 挂起，上面的代码将不起作用。在发布我的问题之前，我已经浏览了几个小时并阅读了有关这种情况的报告。
@Steve：你有没有观察到InternetReadFile挂起？通常，您可以信任 Windows API。毕竟，数百万开发人员每天都在使用它。
不难找到有关它的信息，例如查看此信息：codeguru.com/forum/archive/index.php/t-355462.html 但是如果您考虑一下，有很多地方可能会出错：用户的互联网连接问题，代理不工作，wifi 路由器有问题，互联网服务器响应缓慢......我认为即使 InternetOpenURL 也可能会一直挂起。所以我需要的功能不会等待响应，而是立即交还控制权，并在需要时允许取消。有什么想法吗？
将上面的代码放到一个线程中，如果线程没有响应正常的中止，则终止该线程
@Steve：如果您关闭应用程序，内存泄漏并不重要。操作系统将回收内存。

【解决方案2】：

TWinSocketStream 超时。您基本上创建了一个阻塞套接字，然后使用该套接字创建一个 TWinSocketStream 进行读/写。（有点像使用 StreamWriter）。然后循环直到连接关闭、线程终止或达到预期字节数。有一个 WaitForData() 允许您检查传入数据是否有超时，因此您永远不会“锁定”超过该超时值。

不过，您必须自己处理 http 进程。即，发送“GET”，然后读取响应标头以确定预期的字节数，但这并不太难。

【讨论】：

唉，不是个人。我通常将突触库用于此类事情。我确实在网上找到了这个 - 看起来不错，但是 YMMV。 delphi.xcjc.net/viewthread.php?tid=29580这个例子使用的是socketthread，但是原理是一样的——等待数据，读取数据，超时退出。

【解决方案3】：

感谢 GrandmasterB，这是我设法整理的代码：（它在我线程的 Execute 块中）

var
  Buffer: array [0..1024 - 1] of Char;
  SocketStream: TWinSocketStream;
  RequestString: String;
  BytesRead: Integer;
begin
  try
    ClientSocket.Active := true;
    DownloadedData := '';
    FillChar(Buffer, SizeOf(Buffer), #0);

    if not Terminated then
    begin
      // Wait 10 seconds
      SocketStream := TWinSocketStream.Create(ClientSocket.Socket, 10000);
      try
        // Send the request to the webserver
        RequestString := 'GET /remotedir/remotefile.html HTTP/1.0'#13#10 +
          'Host: www.someexamplehost.com'#13#10#13#10;
        SocketStream.Write(RequestString[1], Length(RequestString));

        // We keep waiting for the data for 5 seconds
        if (not Terminated) and SocketStream.WaitForData(5000) then
          repeat
            // We store the data in our buffer
            BytesRead := SocketStream.Read(Buffer, SizeOf(Buffer));

            if BytesRead = 0 then
              break
            else
              DownloadedData := DownloadedData + Buffer;
          until Terminated or (not SocketStream.WaitForData(2000));
      finally
        // Close the connection
        SocketStream.Free;
        if ClientSocket.Active then
          ClientSocket.Active := false;
      end;
    end;
  except
  end;

你必须把这个放到线程的构造函数中：

  ClientSocket := TClientSocket.Create(nil);
  ClientSocket.Host := 'www.someexamplehost.com';
  ClientSocket.Port := 80;
  ClientSocket.ClientType := ctBlocking;

  inherited Create(false);  // CreateSuspended := false;

这就是析构函数：

  ClientSocket.Free;
  inherited;

【讨论】：

看起来不错！响应中将包含 http 响应标头，因此您收到的文件实际上将在两个连续的 #D#A 之后开始，这将标头与数据分开。您可以在收到响应标头中指定的字节数后立即关闭套接字 - 这将防止最后 5 秒在等待查看是否有更多数据到来时挂起。

【解决方案4】：

来自delphi.about.com


uses ExtActns, ...

type
   TfrMain = class(TForm)
   ...
   private
     procedure URL_OnDownloadProgress
        (Sender: TDownLoadURL;
         Progress, ProgressMax: Cardinal;
         StatusCode: TURLDownloadStatus;
         StatusText: String; var Cancel: Boolean) ;
   ...

implementation
...

procedure TfrMain.URL_OnDownloadProgress;
begin
   ProgressBar1.Max:= ProgressMax;
   ProgressBar1.Position:= Progress;
end;

function DoDownload;
begin
   with TDownloadURL.Create(self) do
   try
     URL:='http://0.tqn.com/6/g/delphi/b/index.xml';
     FileName := 'c:\ADPHealines.xml';
     OnDownloadProgress := URL_OnDownloadProgress;

     ExecuteTarget(nil) ;
   finally
     Free;
   end;
end;

{ 笔记： URL 属性指向 Internet FileName 是本地文件 }

【讨论】：