使用主复选框选择特定复选框

Question

我正在尝试创建一个宏来选择某一列的所有复选框。 例如，我每列有 10 个标准复选框，每列的主复选框为“全选”。 我有代码来选择每个复选框，但无法弄清楚如何稍微调整它以仅选择或取消选择单元格 A2:A10，而不是列 B、C 等中的框。

我正在使用这个简单的脚本；

Sub SelectAll_Click()
Dim CB As Checkbox
For Each CB In ActiveSheet.CheckBoxes
If CB.Name <> ActiveSheet.CheckBoxes("Check Box 1").Name Then
CB.Value = ActiveSheet.CheckBoxes("Check Box 1").Value
End If
Next CB
End Sub

我尝试更改复选框名称的 , = 以识别比列 B 的第一个复选框更少的内容，但未成功 以及添加 =range()

我对这一切都是全新的，我相信随着时间的推移和学习，我会回顾并嘲笑我在这里遇到的障碍，但如果有人可以暂时将他们的专业知识借给我，那就是非常感谢。

谢谢

Answer 1

要让一个宏适用于所有主复选框，请使用调用者并比较 topleftcell.column：

Sub CheckComboboxesInColumn()
Dim CallerString As String, CallerBox As CheckBox
Dim chk As CheckBox

    CallerString = Application.Caller
    Set CallerBox = ActiveSheet.CheckBoxes(CallerString)

    For Each chk In ActiveSheet.CheckBoxes
        If chk.TopLeftCell.Column = CallerBox.TopLeftCell.Column Then chk.Value = CallerBox.Value
    Next chk
End Sub

Answer 2

在我看来，您想根据它们所在的列选中/取消选中您的复选框。因此，我建议使用以下代码：

Public Sub CheckComboBoxBasedOnColumn()

Dim chk As CheckBox

For Each chk In Sheet2.CheckBoxes
    Select Case Split(chk.TopLeftCell.Address, "$")(1)
    Case "A"
        'If the checkbox is in column A then check it.
        chk.Value = True
    Case "B"
        'If the checkbox is in column B then un-check it.
        chk.Value = False
    Case "C"
        '... what ever you want for column C
    Case Else
        '... or any other column
    End Select
Next chk

End Sub

如果这解决了您的问题，请告诉我。

Answer 3

如果您在工作表中将复选框引用为 Shape 对象，那么您可以访问属性 .TopLeftCell ，它将告诉您复选框位于哪一列。以下代码适用于 A 列中的所有表单控件复选框。只需将列 #（此代码中的 1）更改为您想要的列，并在每种情况下更改您的主复选框的名称。

Sub SelectAllColumnA_Click()
Dim shp As Shape
For Each shp In ActiveSheet.Shapes
    If shp.Type = msoFormControl Then 'Form control
        If shp.FormControlType = xlCheckBox Then
            If shp.Name = "Check Box 1" Then
                'Do not alter value of master check box "Check Box 1"
            ElseIf shp.TopLeftCell.Column = 1 Then
                shp.ControlFormat.Value = ActiveSheet.CheckBoxes("Check Box 1").Value
            End If
        End If
    End If
Next shp
End Sub

编辑：我简化了代码，因为您说您使用的是表单控件。

Edit2：这是一个简单的添加，它将改变主复选框的状态。

Sub SelectSubCheckBoxA()
ActiveSheet.CheckBoxes("Check Box 1").Value = 2
End Sub

只需将此宏分配给 A 列中的每个复选框。对于其他列，创建此宏的新版本并更改主复选框的名称。这样，当您单独选择任何复选框时，它会在视觉上“禁用”主复选框。