为整组复选框实现右键单击？

Question

我在GroupBox 中有一系列CheckBox(es)，用于选择用户想要运行的报告。它们通常都是Checked，这是最常见的情况，但只想运行一个也很常见。我认为右键单击一个框将其打开并关闭所有其他框会很有用。

在复选框上实现MouseClick 事件很容易，但问题是它们有很多，并且列表不断被添加。所以第一个问题：有没有办法让单个 MouseClick 处理程序适用于任何复选框，甚至是我们还没有的复选框？

另一种选择似乎是使用GroupBox.Controls 集合循环检查复选框并查看单击了哪个复选框，然后根据需要为所有复选框设置Checked。然而，CheckBox always 似乎拦截了MouseClick 事件，即使AutoCheck 已关闭。所以我的第二个问题：有没有办法关闭复选框中的点击处理，以便群组处理事件？

如果有其他方法可以解决这个问题，请告诉我！

Answer 1

这是我在我的 cmets 中谈论的一个例子。将 FlowLayoutPanel 添加到表单（保留它 flowlayoutpanel1）

'This is done to show automatic generation of a list of reports.
'You might get this from a folder of reports, or a database or similar store
'By adding and taking away from this list you will notice that the code still functions the same.
'Just remember, you would dynamically fill the reports list in your real-world application.
Dim Reports As New List(Of String) From {"Report1", "Report2", "Report3", "Report4", "Report5", "Report6", "Report7", "Report8"}

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    'I'm using a flowlayoutpanel so that the controls are added
    'without having to worry about placement
    FlowLayoutPanel1.AutoScroll = True
    'Here is where we loop through the list of reports and add them to the 
    'flowlayoutpanel and give them a common handler
    For Each rpt As String In Reports
        Dim chkRpt As New CheckBox
        chkRpt.Text = rpt
        chkRpt.Height = 17
        chkRpt.Checked = True
        AddHandler chkRpt.MouseDown, AddressOf CustomMouseDown
        FlowLayoutPanel1.Controls.Add(chkRpt)
    Next
End Sub

'Here is the code to allow a right click to select the current checkbox
'and remove all other checked items.
Private Sub CustomMouseDown(sender As Object, e As MouseEventArgs)
    If e.Button = Windows.Forms.MouseButtons.Right Then
        Dim curChk As CheckBox = CType(sender, CheckBox)
        For Each chk As CheckBox In FlowLayoutPanel1.Controls.OfType(Of CheckBox)()
            chk.Checked = False
        Next
        curChk.Checked = True
    End If
End Sub