在 Perl 中执行后将数据从子级传递给父级

Question

我想在另一个perl程序parent.pl中调用一个perl程序child.pl，并希望将数据从child.pl传递到parent.pl并通过parent.pl打印这些数据。 system("perl child.pl") 可能不起作用，因为在 child.pl 完成之前， parent.pl 不会做任何事情。我读了the online doc of perlipc，似乎pipe() 和fork() 可以满足我的一些需求，但是在exec 之后我找不到将数据从子进程传递给父进程的方法。这是parent.pl的代码：

#!/usr/bin/perl -w

pipe(FROM_CHILD, TO_PARENT);  

$pid = fork();  

if ($pid == 0) {  
    # We're in the child process.  
    close(FROM_CHILD);  
    # Send data to parent.  
    print TO_PARENT "Hello, parent\n"; #  I can pass data to parent before exec
    exec("perl child.pl");             #  But how what should I do after exec, in child.pl?
    exit(0);  # Terminate child.  
} 
elsif (undef $pid) {  
    print "Not defined: means an error.";  
} 
else {  
    # Parent process.  
    close(TO_PARENT);  
    $data = <FROM_CHILD>;  
    print "From child: $data\n";  
    $id = wait();  
    print "Child $id is dead.\n"; 

Answer 1

这可能会有所帮助：

#!/usr/bin/perl
open (my $child, "-|","./child.pl") or die("$!");
while (<$child>) {
  print "P: $_";
}
close($child);

打开函数，from perldoc：

对于三个或更多参数，如果 MODE 是 |- ，则文件名是 解释为输出将通过管道传输到的命令，并且 如果 MODE 是 -| ，文件名被解释为通过管道输出的命令 我们。

如果你不想接触标准输出，那么你需要孩子的合作，然后你可以使用命名管道：

parent.pl

#!/usr/bin/perl
use strict;
use warnings;
use Fcntl;
use POSIX;
my $fpath = '.named.pipe';

mkfifo($fpath, 0666) or die "mknod $!";
system("perl child.pl &");
sysopen(my $fifo, $fpath, O_RDONLY) or die "sysopen: $!";

while (<$fifo>) {
  print "P: $_";
}
close($fifo);
unlink($fifo);

child.pl

#!/usr/bin/perl
use strict;
use warnings;
use Fcntl;
use POSIX;

my $fpath = '.named.pipe';
sysopen(my $fifo, $fpath, O_WRONLY) or die "sysopen: $!";
print "screen hello\n";
print $fifo "parent hello\n";
close($fifo);