使用 Apple Script 在 QuickTime 中录制音频

Question

我在 QuickTime Player 中运行 AppleScript 来执行音频录制。当用户单击按钮停止录音时，我如何等待片刻？我们需要将“延迟5”替换为等待。

set filePath to (path to desktop as text) & "test.m4a"
delay 1
tell application "QuickTime Player"
    activate
    set new_recording to (new audio recording)
    tell new_recording
        start
        delay 5
        stop
    end tell
    
    open for access file filePath
    close access file filePath
    export (first document) in filePath using settings preset "Audio Only"
    close (first document) without saving
    ignoring application responses
        quit
    end ignoring
end tell

Answer 1

这就是我等待用户手动停止录制然后继续并继续其余代码的方式：

set filePath to (path to desktop as text) & "test.m4a"

tell application "QuickTime Player"
    activate
    set newRecording to (new audio recording)
    set docName to name of newRecording
    tell newRecording to start
    repeat while document docName exists
        set clickedCancelButton ¬
            to my checkForSheet1AndClickCancel()
        if clickedCancelButton then ¬
            tell application "QuickTime Player" to ¬
                tell newRecording to stop
        delay 1
    end repeat
end tell

open for access file filePath
close access file filePath

tell application "QuickTime Player"
    export (first document) in filePath ¬
        using settings preset "Audio Only"
    close (first document) without saving
    quit
end tell

on checkForSheet1AndClickCancel()
    tell application "System Events"
        tell application process "QuickTime Player"
            if (exists sheet 1 of window 1) then
                click button 2 of sheet 1 of window 1
                return true
            else
                return false
            end if
        end tell
    end tell
end checkForSheet1AndClickCancel

---

注意事项：

open for access 和 close access 命令 是 标准添加 的一部分，当包裹在 tell application "QuickTime Player" block 以及他们分开的原因。这避免了浪费的 CPU cycles 因为不必在tell current application 下再次调用它们而对静默错误太正确了。

按照编码，这假设一次只有一个 QuickTime Player 窗口 进行音频录制，并且仍然是最前面的QuickTime Player的>窗口。

它也被编码，所以如果用户点击new audio recording 窗口上的关闭 按钮 取消 按钮被点击，脚本停止并保存录音。

调整repeat循环内delaycommand的值，你觉得合适。

这是在 ma​​cOS Catalina 下测试的，其中 Language & Region 在 System Preferences 中设置为 English (US)并按照编码为我工作。

---

_{注意：示例 AppleScript 代码 就是这样，并且没有任何包含的错误处理不包含任何适当的额外错误处理。用户有责任根据需要或需要添加任何错误处理。查看AppleScript Language Guide 中的try statement 和error statement。另请参阅Working with Errors。此外，在适当的情况下，可能需要在事件之间使用delay 命令，例如delay 0.5，延迟的值设置得当。}