未设置错误子类中的属性

Question

我有一个 Error 的 Coffeescript 子类。以下 CoffeeScript 脚本

class MyError extends Error
  constructor: (message, @cause) ->
    super message

myError = new MyError 'This is the error message!'

console.log myError instanceof MyError
console.log myError instanceof Error
console.log "'#{myError.message}'"
console.log myError.message == ''

展示

true
true
''
true

在 Node.js v0.10.20 下。

为什么myError的message属性是空的？

Answer 1

显式设置@message 有效

class MyError extends Error
  constructor: (@message,@cause)->
    Error.captureStackTrace(@,@)

coffee> ee=new MyError 'test'
{ message: 'test', cause: undefined }
coffee> "#{ee}"
'Error: test'
coffee> ee.message
'test'
coffee> ee instanceof MyError
true
coffee> ee instanceof Error
true
coffee> throw new MyError 'test'
Error: test
    at new MyError (repl:10:11)
...

当另一个类基于MyError 构建时，super 可以正常工作

class OError extends MyError
   constructor: (msg)->
     super msg
     @name='OError'

以下显示正确的消息，对于util.isError 是正确的，是instanceof Error，但不是instanceof Error1。所以它是Error 的专用构造函数，而不是“子类”。

class Error1 extends Error
   constructor: (@message)->
     self = super
     self.name = 'Error1'
     return self

这是给node: '0.10.1', 'coffee-script': '1.6.3'

bjb.io 文章中的最后一个示例是（在 Coffeescript 中）：

CustomError = (msg)->
  self = new Error msg
  self.name = 'CustomError'
  self.__proto__ = CustomError.prototype
  return self
CustomError.prototype.__proto__= Error.prototype
# CustomError::__proto__= Error::  # I think

满足所有测试，util.isError、instanceof Error、instanceof CustomError、"#{new CustomError 'xxx'}"。