CoffeeScript 动态方法

Question

我正在尝试在咖啡脚本中动态创建方法，但正如我的代码所示，我用来创建方法的迭代器不会在迭代之间重置其变量，因此我遇到了冲突的共享变量：

class MyClass
  constructor: (@name) ->

  for k, v of ['get', 'set']
    console.log('creating method: ' + v)
    MyClass::[v] = (args...) ->
      method = v
      console.log('executing method: ' + method)

o = new MyClass('dummy')
o.get()
o.set()

输出：

> creating method: get
> creating method: set
> executing method: set
> executing method: set

知道我做错了什么吗？

Answer 1

mu 已正确诊断出问题。最直接的解决方案是使用 CoffeeScript 语言的 do 关键字，它创建并运行一个内部函数，该函数捕获您传入的变量的值：

for k, v of ['get', 'set']
  do (k, v) ->
    console.log('creating method: ' + v)
    MyClass::[v] = (args...) ->
      method = v
      console.log('executing method: ' + method)

我在我的 PragPub 文章 A CoffeeScript Intervention 中谈到了这个功能。

Answer 2

你的内在功能：

(args...) ->
  method = v
  console.log('executing method: ' + method)

实际上是v 上的闭包，所以当它被执行时，v 将计算为它在循环中的最后一个值（即set）。看起来你只需要一点关闭破坏：

build_method = (v) ->
  (args...) ->
    method = v
    console.log('executing method: ' + method)

然后：

for k, v of ['get', 'set']
  console.log('creating method: ' + v)
  MyClass::[v] = build_method(v)

请记住，CoffeeScript 只是具有不同构成的 JavaScript，因此它存在许多相同的问题（就像任何具有闭包的语言一样）并且这些问题具有相同的解决方案。