委托内的动态属性名称分配

Question

我试图在中继器的委托中包含一个设置对象，以便我可以保存 SpinBox 的值。但是，我不知道如何动态设置属性别名。

我想要实现的是让属性别名与modelData相同。例如对于item1：“属性别名item1：box.value”；对于item2：“属性别名item2：box.value”等

Column {
    Repeater {
        model: ["item1", "item2", "item3", "item4", "item5"]
        delegate: RowLayout {
            Settings {
                fileName: "config"
                category: modelData
                property alias value: box.value
            }
            Label {
                text: modelData
            }
            SpinBox {
                id: box
            }
        }
    }
}

上面的代码生成以下设置，并且是我想要做的工作：

[item1]
value=""
[item2]
value=""
[item3]
value=""
...

我想要的是具有值的单个类别，如下所示：

[category]
item1=""
item2=""
item3=""
...

Answer 1

对于这种情况，您不能使用属性，只能使用 value() 和 setValue() 方法：

import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
import Qt.labs.settings

ApplicationWindow {
    width: 640
    height: 480
    visible: true

    readonly property var values: ["item1", "item2", "item3", "item4", "item5"]
    Settings {
        id: settings
        category: "category"
    }

    Column {
        Repeater {
            model: values
            delegate: RowLayout {
                id: row_layout
                Label {
                    text: modelData
                }
                SpinBox {
                    id: box
                }
                Component.onCompleted: box.value = settings.value(modelData, 0)
                Component.onDestruction: settings.setValue(modelData, box.value)
            }
        }
    }
}

输出：

[category]
item1=6
item2=6
item3=4
item4=2
item5=2