XSLT：为元素生成一个新的 int 唯一 ID

Question

我必须使用 XSLT 更新 XML。

我之前的 XML 元素有一个属性为Id 的元素，其值为int。有些元素没有这个Id，因为它们不能被任何其他元素引用。

XML 示例：

<Object Id="12359" Type="TypeX">
 <Object Type="TypeA">
    <SomeOtherObject Id="112"  Type="TypeV"/>
 </Object>
 <SomeOtherOtherObject Id="1596" Type="TypeM"/>
</Object>

对于一个特定的项目（我可以通过 XPATH 请求轻松地选择它，我想生成一个新的 ID，它不被任何其他元素使用。

这可以通过 XSLT 完成吗？

我已经有了一些钥匙：

<xsl:key name="node-reference-key" match="*[@Id]" use="@Id" />

我可以像这样选择缺少属性的元素：

<xsl:template match="*[@Type='TypeA']">

这将由 C# 应用程序运行，但我想不惜一切代价避免任何 C# 代码。

Answer 1

您无法在 XSLT 中修改变量，因此无法设置全局变量并在您跟踪下一个唯一 ID 时对其进行递增。

但你可以这样做：

• 选择文档中的最大ID：

  <xsl:variable name="max-id" select="//@Id[not(. &lt; //@Id)]" />
  

• 创建一个以逗号分隔的元素唯一 ID 列表（在 generate-id() 的帮助下）和一个命名模板：

  <xsl:variable name="missing-list">
    <xsl:call-template name="list-ids">
      <xsl:with-param name="nodes" select="//*[not(@Id)]" />
    </xsl:call-tempalte>
  </xsl:variable>
  
  <!-- and -->
  
  <xsl:template name="list-ids">
    <xsl:param name="nodes" />
    <xsl:for-each select="$nodes">
      <xsl:value-of select="concat(generate-id(), ',')" />
    </xsl:for-each>
  </xsl:template>
  

• 使用该列表作为参考点。对于任何给定的元素（没有@Id），新的唯一ID 将是$max-id 加上它在该列表中的位置（您可以使用substring-before($missing-list, generate-id()) 获得它；要获得我们计算逗号的位置：

  <xsl:variable name="pos" select="
    string-length($preceding-ids)
    - string-length(translate($preceding-ids, ',', ''))
  "/>
  
  <xsl:attribute name="Id">
    <xsl:value-of select="$max-id + $pos + 1" />
  </xsl:attribute>
  

所以，放在一起看起来像这样：

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output encoding="UTF-8" indent="yes" />

    <xsl:variable name="max-id" select="//@Id[not(. &lt; //@Id)]" />

    <xsl:variable name="missing-list">
      <xsl:call-template name="list-ids">
        <xsl:with-param name="nodes" select="//*[not(@Id)]" />
      </xsl:call-template>
    </xsl:variable>

    <xsl:template match="@*|node()">
      <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="*[not(@Id)]">
      <xsl:copy>
        <xsl:apply-templates select="@*" />

        <xsl:variable name="preceding-ids" select="
          substring-before($missing-list, generate-id())
        "/>
        <xsl:variable name="pos" select="
          string-length($preceding-ids)
          - string-length(translate($preceding-ids, ',', ''))
        "/>

        <xsl:attribute name="Id">
          <xsl:value-of select="$max-id + $pos + 1" />
        </xsl:attribute>

        <xsl:apply-templates select="node()" />
      </xsl:copy>
    </xsl:template>

    <xsl:template name="list-ids">
      <xsl:param name="nodes" />
      <xsl:for-each select="$nodes">
        <xsl:value-of select="concat(generate-id(), ',')" />
      </xsl:for-each>
    </xsl:template>        
</xsl:transform>