QML 中的两种方式绑定 C++ 模型

Question

我正在尝试了解有关 QtQuick 和 QML 的更多信息。我目前的目标是了解如何将数据从 C++ 模型绑定到我的视图。到目前为止，我已经能够在我的 QML 中设置模型并从模型中获取数据，但我不知道如何更新我的数据。

如何为我的 C++ 模型设置双向绑定？下面是我目前写的代码。

message.h

class Message : public QObject
{
    Q_OBJECT

    Q_PROPERTY(QString author READ getAuthor WRITE setAuthor NOTIFY authorChanged)
    Q_PROPERTY(QString message READ getMessage WRITE setMessage NOTIFY messageChanged)

    Q_SIGNALS:
        void authorChanged(QString author);
        void messageChanged(QString message);

    public:
        Message(QObject *parent = 0);

        QString getAuthor();
        void setAuthor(QString author);

        QString getMessage();
        void setMessage(QString message);

    private:
        QString _author;
        QString _message;
};

message.cpp

#include "message.h"

Message::Message(QObject *parent) : QObject(parent)
{
}

QString Message::getAuthor()
{
    return _author;
}

void Message::setAuthor(QString author)
{
    if(author != _author)
    {
        _author = author;
        emit authorChanged(author);
    }
}

QString Message::getMessage()
{
    return _message;
}

void Message::setMessage(QString message)
{
    if(message != _message)
    {
        _message = message;
        emit messageChanged(message);
    }
}

ma​​in.qml

import QtQuick 2.7
import QtQuick.Controls 2.0
import QtQuick.Layouts 1.0
import com.butts.messaging 1.0

ApplicationWindow {
    visible: true
    width: 640
    height: 480
    title: "Test"

    Message {
        id: testMessage
        author: "Batman"
        message: "Hello World!"
    }

    Flow {
        TextField {
            text: testMessage.message
        }

        Label {
            text: testMessage.message
        }
    }
}

ma​​in.cpp

#include <QGuiApplication>
#include <QQmlApplicationEngine>
#include "message.h"

int main(int argc, char *argv[])
{
    qmlRegisterType<Message>("com.butts.messaging", 1, 0, "Message");

    //Message msg = Message();

    QCoreApplication::setAttribute(Qt::AA_EnableHighDpiScaling);
    QGuiApplication app(argc, argv);

    QQmlApplicationEngine engine;
    engine.load(QUrl(QLatin1String("qrc:/main.qml")));

    return app.exec();
}

附：我在这方面是个大菜鸟，所以请随时指出我的代码中存在的任何其他问题（格式、标准等），我需要以某种方式学习大声笑

编辑 1

阅读@derM 的回答后，我更改了代码以实现我想要的效果

TextField {
    id: editor

    //Binding model -> view
    text: testMessage.message

    //Binding model <- view
    Binding {
        target: testMessage
        property: "message"
        value: editor.text
    }
}

Label {
    id: display

    //Binding model -> view
    text: testMessage.message
}

Answer 1

双向绑定在 QML 中是一件复杂的事情，因为它通常作为一些赋值工作。

所以，如果你用propertyname: valuetobeboundto 绑定一个属性，然后又给propertyname 赋值，这个绑定就会丢失。

作为一种解决方法，有两种方法：使用Binding-Objects 或不使用绑定，而是手动处理所有属性更改信号（理想情况下，您的模型会正确发出）。

第一个可以找到详细说明here. 在这里，他们为每个方向使用一个Binding-Object。好消息是，那些Bindings 不会被新的Binding 赋值覆盖。

考虑：

Row {
    spacing: 2
    Rectangle {
        id: r0
        width: 50
        height: 30
    }

    Rectangle {
        id: r1
        width: 50
        height: 30
        color: b2.pressed ? 'red' : 'blue'
    }

    Button {
        id: b2
    }

    Button {
        id: b3
        onPressed: r1.color = 'black'
        onReleased: r1.color = 'green'
    }

    Binding {
        target: r0
        property: 'color'
        value: b2.pressed ? 'red' : 'blue'
    }


    Binding {
        target: r0
        property: 'color'
        value: (b3.pressed ? 'black' : 'green')
    }
}

一开始r1的值被绑定到b2的状态，但是一旦b3被按下一次，r1就不会再通过点击b2来更新.对于r0，更新将由两个Binding-Objects 完成，因此Binding 不会丢失。但是，您可以看到绑定是如何工作的：当Button 的状态发生变化时，Binding 将被更新。 因此，按下 AND 释放b2 将触发信号，这将由第一个Binding 处理，而按下 AND 释放@987654342 也是如此@。

现在介绍双向绑定。在这里避免 Binding-Loops 很重要。

Row {
    Button {
        id: count0
        property int count: 0
        onClicked: count += 1
        text: count
    }

    Button {
        id: count1
        property int count: 0
        onClicked: count += 1
        text: count
    }

    Binding {
        target: count0
        property: 'count'
        value: count1.count
    }

    Binding {
        target: count1
        property: 'count'
        value: count0.count
    }
}

虽然这个例子很好。 count0.count 的更改将触发count1.count 的更改。现在检查count0.count是否需要更新，但值已经是正确的，所以递归结束，没有发生绑定循环。

将第二个绑定更改为

    Binding {
        target: count1
        property: 'count'
        value: count0.count + 1
    }

极大地改变了情况：现在随着count0.count 的每次更改，count1.count 需要提高。第一个Binding 然后尝试将count0.count 设置为与count1.count 相同的值，但是不可能同时满足Binding，并且不需要进行任何更改，在另一个Binding 之后它的工作。它将导致绑定循环。幸运的是，这些在 QML 中被很好地检测到，因此避免了锁定。

现在只有最后一件事需要处理： 考虑这个组件定义：

// TestObj.qml
Item {
    width: 150
    height: 40
    property alias color: rect.color
    Row {
        spacing: 10
        Rectangle {
            id: rect
            width: 40
            height: 40
            radius: 20
            color: butt.pressed ? 'green' : 'red'
        }
        Button {
            id: butt
            text: 'toggle'
        }
    }
}

这里我们使用propertyname: valueToBeBoundTo-语法对color-属性进行了内部绑定。这意味着，内部绑定可能会被color-property 的任何外部assignemtn 覆盖。 用Binding-Object 替换这个绑定，应该没问题。

反之亦然：color 外部绑定到某个值，然后您在内部处理信号并为其分配值，如果不是由 @987654361 创建，外部绑定将丢失@-对象。

这只是一般概述。还有更多细节可能会改变绑定的行为。但我想我已经展示了如何创建双向绑定，并提到了一些你可能会遇到的陷阱。

Answer 2

这对我有用，使用 Qt Quick Controls 2：

TextField {
    id: txt

    text: testMessage.message

    onTextChanged: testMesage.message = txt.text
}