删除过滤行时出现错误 1004？

Question

我试图在过滤指示项目是否仅限供应商（是/否）的列后删除行。

我想删除该列下的值指示“是”的所有行。但是，当我选择要删除的可见行时遇到错误。

我以前在其他宏中使用过相同的代码，但这次它不起作用。

Dim VisibleCell As Long 'Variable to count the number of visible cells after filtering

VisibleCell = Application.WorksheetFunction.Subtotal(3, Range("A3:A50000"))
Range("Table1").Select

'Filter and remove all Vendor Only items
Rows("2:2").Select 'Find column for Vendor Only and filter for Yes values
    Cells.Find(What:="Vendor Item?", After:=ActiveCell, LookIn:=xlFormulas, _
    LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
    MatchCase:=False, SearchFormat:=False).Activate

MyCol = ActiveCell.Column
ActiveSheet.ListObjects("Table1").Range.AutoFilter Field:=MyCol, Criteria1:= _
    "Yes", Operator:=xlAnd
VisibleCell = Application.WorksheetFunction.Subtotal(3, Range("A3:A50000"))

If VisibleCell > 0 Then
    Range("A3:A2000").SpecialCells(xlCellTypeVisible).Select
    Selection.EntireRow.Delete 'Error occurs here
End If

Answer 1

由于您有一个ListObject，您可以通过其标题（“供应商项目？”）引用ListColumn，而不是Find第2行中的单元格。

另外，当你想过滤时，我会参考那个ListColumn 的Index，而不是它的Column。 Index 返回它在表格中的列号，而Column 将是它在工作表上的列。如果您的表格从 A 列开始（这里听起来就是这种情况），这两者会重合，但如果您的表格位置发生变化，Index 会更加稳健。

最后，不需要Activate 或Select。

Option Explicit

Sub DeleteVendorOnly()
    Dim tbl As ListObject
    Dim colIndex As Integer
    Dim rngToDelete As Range

    Set tbl = Sheets("Sheet1").ListObjects("Table1")  ' Change to your sheet name
    colIndex = tbl.ListColumns("Vendor Item?").Index

    tbl.Range.AutoFilter Field:=colIndex, Criteria1:="Yes"

    On Error Resume Next
        Set rngToDelete = tbl.DataBodyRange.SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If Not rngToDelete Is Nothing Then
        rngToDelete.EntireRow.Delete
    End If
End Sub