如何测试某个字段是否设置为某个值？

Question

这似乎很基本，所以我认为这是一个骗局......但我还没有找到任何可以回答这个问题的东西。

我的应用代码也是 Groovy。说我有一个字段

def something

在我的测试中（CUT 是 Spock Spy）我运行了一个中间有一行的方法

something = null 

或

something = new Bubble()

...我只是想找到一种方法来测试确实设置为null（或任何值...）

在我尝试过的then 块中：

1 * spyCUT.setSomething( null ) 

和

1 * spyCUT.setSomething(_)

和

1 * spyCUT.set( 'something', _ )

顺便说一句，为了回答我可以在then 块中测试something 的值的反对意见，情况是something 意味着首先设置为一个值，然后设置为另一个值这个方法的过程...

阅读了Groovy In Action 2nd Ed，我对 Groovy 如何处理获取和设置字段有最模糊的概念......显然还不够。

MCVE（FWIW！）

class Spocko {
    def something

    def doStuff() {
        something = 'fruit'
    }
}

class SpockoTest extends Specification {
    def 'test it'(){
        given:
        Spocko spySpocko = Spy( Spocko )

        when:
        spySpocko.doStuff()

        then:
        1 * spySpocko.setSomething(_)
    }
}

稍后（在 kriegaex 非常有帮助的回复之后）

上面的SpockTest setSomething 被调用：

class Spocko {
    def something

    def doStuff() {
        this.each{
            it.something = 'fruit' 
        }
    }
}

...通过！我现在正试图理解为什么......

顺便说一句，我还发现以下通过（并且没有关闭）：

1 * spySpocko.setProperty( 'something', _ )

Answer 1

在我看过你的 MCVE 之后，可以这样回答这个问题：你不能测试一个永远不会发生的方法调用。 doStuff() 只是给一个字段赋值，它不会在内部调用 setter 方法。看看这个：

package de.scrum_master.stackoverflow

import spock.lang.Specification

class SpockoTest extends Specification {
  static class Spocko {
    def something

    def doStuff() {
      something = 'fruit'
    }

    def doMoreStuff() {
      setSomething('vegetable')
    }
  }

  def 'test it'(){
    given: 'Spocko spy'
    Spocko spySpocko = Spy(Spocko)

    when: 'calling method assigning value to property'
    spySpocko.doStuff()

    then: 'no setter is called'
    0 * spySpocko.setSomething(_)
    spySpocko.something == 'fruit'

    when: 'calling method using setter'
    spySpocko.doMoreStuff()

    then: 'setter gets called'
    1 * spySpocko.setSomething('vegetable')

    when: 'using Groovy setter-like syntax from another class'
    spySpocko.something = 'fish'

    then: 'actually a setter gets called'
    1 * spySpocko.setSomething('fish')
  }
}

这就是发生的事情。调用时

javap -v target/test-classes/de/scrum_master/stackoverflow/SpockoTest\$Spocko.class

你看（输出缩短）：

public java.lang.Object doStuff();
  descriptor: ()Ljava/lang/Object;
  flags: ACC_PUBLIC
  Code:
    stack=2, locals=3, args_size=1
       0: invokestatic  #24                 // Method $getCallSiteArray:()[Lorg/codehaus/groovy/runtime/callsite/CallSite;
       3: astore_1
       4: ldc           #36                 // String fruit
       6: astore_2
       7: aload_2
       8: aload_0
       9: swap
      10: putfield      #38                 // Field something:Ljava/lang/Object;
      13: aload_2
      14: areturn
      15: aconst_null
      16: areturn

public java.lang.Object doMoreStuff();
  descriptor: ()Ljava/lang/Object;
  flags: ACC_PUBLIC
  Code:
    stack=3, locals=2, args_size=1
       0: invokestatic  #24                 // Method $getCallSiteArray:()[Lorg/codehaus/groovy/runtime/callsite/CallSite;
       3: astore_1
       4: aload_1
       5: ldc           #40                 // int 0
       7: aaload
       8: aload_0
       9: ldc           #42                 // String vegetable
      11: invokeinterface #48,  3           // InterfaceMethod org/codehaus/groovy/runtime/callsite/CallSite.callCurrent:(Lgroovy/lang/GroovyObject;Ljava/lang/Object;)Ljava/lang/Object;
      16: areturn
      17: aconst_null
      18: areturn

你能看出区别吗？

---

问题编辑 2 后更新：您想知道为什么这会触发 setter 调用：

def doStuff() {
  this.each {
    it.something = 'fruit' 
  }
}

这是因为this 作为参数提供给闭包，因此it.something = 'fruit' 像我的示例spySpocko.something = 'fish' 一样动态解析，因为它不是something = 'fruit' 中的内部赋值（相当于@987654330 @) 了。

其实我认为即使不看字节码也不是那么难理解，只要按照通常的 Groovy 教程进行操作即可。我在重复自己，但我确实认为您对事情进行了过度设计和过度复杂化，对事情进行了过于深入的测试。我不会将这样的测试放入生产代码库中。尝试测试你的类的行为（想想规范和特性！），而不是内部的复杂性。但如果它有助于您了解 Groovy 的工作原理，请继续玩。

截至目前，请不要进行进一步的问题编辑和后续问题。如果您有新问题，最好使用新的 MCVE 创建一个新问题。