如何使用 spock“where”表测试重载方法

Question

我想测试将null 传递给这些重载方法：

public static Object someMethod(String n) { /* some impl */ }
public static Object someMethod(Integer n) { /* some impl */ }

我试过了：

def "test someMethod"() {
    expect:
    someMethod(input) == expected
    where:
    input           | expected
    null as String  | someValue
    null as Integer | someValue
}

但我得到了错误：

groovy.lang.GroovyRuntimeException: Ambiguous method overloading for method com.foo.MyClass#someMethod.
Cannot resolve which method to invoke for [null] due to overlapping prototypes between:  
    [class java.lang.String]  
    [class java.lang.Integer]

如何使用一种 spock 方法在 where 块中输入空值（使用其他值）来测试这些？

Answer 1

在这种情况下，类型转换不会被 Spock 继承，也不能被 Spock 继承。 但是您可以手动使用PojoWrapper，这就是Groovy 在内部表示类型转换的null：

import org.codehaus.groovy.runtime.wrappers.PojoWrapper

def "test someMethod"() {
    expect:
    someMethod(input) == expected
    where:
    input                          | expected
    new PojoWrapper(null, String)  | someValue
    new PojoWrapper(null, Integer) | someValue
}

一个重要的注意事项是，第一组输入必须包含包装器，否则 Groovy 会优化 someMethod 调用，而不会解包参数。

所以这会起作用：

import org.codehaus.groovy.runtime.wrappers.PojoWrapper

def "test someMethod"() {
    expect:
    someMethod(input) == expected
    where:
    input                          | expected
    new PojoWrapper(null, Integer) | someValue
    0                              | someValue
}

虽然这不起作用但抛出ClassCastException:

import org.codehaus.groovy.runtime.wrappers.PojoWrapper

def "test someMethod"() {
    expect:
    someMethod(input) == expected
    where:
    input                          | expected
    0                              | someValue
    new PojoWrapper(null, Integer) | someValue
}

Answer 2

我试图用 Spock 1.3 和 Groovy 2.5.8 重现您的问题，但不能。相反，我遇到了另一个 Spock 问题，请参阅 here。您必须使用其他版本的 Spock 和/或 Groovy。

无论如何，我刚刚链接到的 Spock 错误的一种解决方法是不要从 then: 或 expect: 块中调用带有 null 参数的方法，而是从 when: 调用该方法，稍后在 @987654325 中进行比较@ 堵塞。另请参阅我的代码示例。

除此之外，您需要将您的功能方法拆分为两种方法，一种用于您要测试的每种类型的null 对象。

正在测试的 Java 类：

package de.scrum_master.stackoverflow.q58279620;

public class ClassUnderTest {
  public static Object someMethod(String n) {
    return n == null ? "nothing" : "something";
  }

  public static Object someMethod(Integer n) {
    return n == null ? -999 : 11;
  }
}

Spock 测试解决方法：

package de.scrum_master.stackoverflow.q58279620


import spock.lang.Specification
import spock.lang.Unroll

class PassingNullToOverloadedMethodTest extends Specification {
  @Unroll
  def "someMethod('#input') returns #expected"() {
    when:
    def result = ClassUnderTest.someMethod(input as String)

    then:
    result == expected

    where:
    input | expected
    "foo" | "something"
    ""    | "something"
    null  | "nothing"
  }

  @Unroll
  def "someMethod(#input) returns #expected"() {
    when:
    def result = ClassUnderTest.someMethod(input as Integer)

    then:
    result == expected

    where:
    input | expected
    0     | 11
    123   | 11
    null  | -999
  }
}