【问题标题】:Groovy metaClass override java.time.Year static method now() but productive code is not using the overriden behaviour of now() at runtimeGroovy 元类覆盖 java.time.Year 静态方法 now() 但生产代码在运行时未使用 now() 的覆盖行为
【发布时间】:2020-12-16 10:05:02
【问题描述】:

我试图覆盖 java.time.Year 类的公共静态方法 now() 因为我希望它返回一个不同的值,而不仅仅是当前年份。在我的生产代码中,我有一个正在测试的方法,它使用 Year.now() 方法:

被测Java类

public class SomeClass {

  public LocalDate methodUnderTest() {
    return Year.now()
        .atMonth(JANUARY)
        .atDay(1);
  }

}

在 Spock groovy 测试中,我尝试以这种方式覆盖 java.time.Year.now() 方法: 我打算在我的生产代码中使用静态方法 now() 的覆盖行为,方法是 methodUnderTest()

class SomeClassSpec extends Specification {

  @Subject
  SomeClass classUnderTest = new SomeClass()

  def "test method with overriden behaviour"() {

    setup:
    Year.metaClass.'static'.now = { -> Year.of(year) }

    expect:
    classUnderTest .methodUnderTest() == expectedDate

    where:
    year           || expectedDate
    2019           || LocalDate.of(2019, JANUARY, 1)
    2020           || LocalDate.of(2020, JANUARY, 1)
    2021           || LocalDate.of(2021, JANUARY, 1)
  }
}

但是,该测试仅适用于 2020 年(当年),其他两个值 2019 和 2021 不起作用,因为似乎预期的覆盖行为显然没有在生产代码中使用。 为什么在运行时 methodUnderTest() 的生产代码中没有使用预期的覆盖行为?

【问题讨论】:

    标签: testing groovy overriding runtime spock


    【解决方案1】:

    一些基础知识:

    1. Groovy 元类的东西只适用于 Groovy 类,不适用于 Java 类。 IE。 Java 类对任何已定义的元类覆盖一无所知,只有调用您的 Java 类代码的 Groovy 才知道。

    2. JRE 引导类 java.time.Year 是 final,即您不能通过常规方式创建模拟实例。您需要在加载时使用特殊的类加载器取消对类的最终确定。我自己的工具Sarek 仍在开发中,它提供了这个功能。 PowerMock 等其他工具提供了更间接的方法,通过检测调用它们的类来帮助您对最终类进行存根。

    3. 您要存根的方法Year.now() 不仅在final 类中,而且在static 中。除了 Groovy 方法之外,Spock 没有任何内置方法来存根静态方法。同样,您的方法在 Java 类中,也由 Java 类调用,所以这对您没有帮助。 Sarek 或 PowerMock 等其他工具同样可以帮助您。

    这里有一个在 Sarek 做的小例子。我刚刚为你推送了一个快照到Maven Central,所以你应该可以使用它。

        <dependency>
          <groupId>dev.sarek</groupId>
          <artifactId>sarek</artifactId>
          <version>1.0-SNAPSHOT</version>
          <scope>test</scope>
        </dependency>
        <dependency>
          <groupId>dev.sarek</groupId>
          <artifactId>sarek-spock-extension</artifactId>
          <version>1.0-SNAPSHOT</version>
          <scope>test</scope>
        </dependency>
    
    package de.scrum_master.stackoverflow.q65321086;
    
    import java.time.LocalDate;
    import java.time.Year;
    
    import static java.time.Month.JANUARY;
    
    public class SomeClass {
      public LocalDate methodUnderTest() {
        return Year.now()
          .atMonth(JANUARY)
          .atDay(1);
      }
    }
    
    package de.scrum_master.stackoverflow.q65321086
    
    import dev.sarek.agent.mock.MockFactory
    import spock.lang.Specification
    import spock.lang.Subject
    import spock.lang.Unroll
    
    import java.time.LocalDate
    import java.time.Year
    
    import static java.time.Month.JANUARY
    import static net.bytebuddy.matcher.ElementMatchers.named
    
    class SomeClassTest extends Specification {
      @Subject
      SomeClass classUnderTest = new SomeClass()
    
      @Unroll
      def "override static JRE method Year.now() for #year"() {
        setup:
        MockFactory<Year> mockFactory = MockFactory
          .forClass(Year.class)
          .mockStatic(
            named("now"),
            { method, args -> false },
            { method, args, proceedMode, returnValue, throwable -> Year.of(year) }
          )
          .build()
    
        expect:
        classUnderTest.methodUnderTest() == expectedDate
    
        cleanup:
        mockFactory.close()
    
        where:
        year || expectedDate
        2019 || LocalDate.of(2019, JANUARY, 1)
        2020 || LocalDate.of(2020, JANUARY, 1)
        2021 || LocalDate.of(2021, JANUARY, 1)
      }
    }
    

    我通过了这个测试。除了非常好的 JavaDoc(查看源代码)和不同模块中的大量示例测试之外,还没有关于 Sarek 的深入文档或教程。

    至于 Sarek,我计划将它集成到 Spock 中,甚至比现在更好,因此将来使用它会感觉模拟“怪异”。我最近很忙。但它已经完全可用,并且还集成了 JUnit 4、Junit 5、TestNG。

    【讨论】:

    • 更新: 以前我忘记将 Sarek 快照上传到 Maven Central,因为我遇到了一些身份验证问题,现在已经修复。如果您想使用 Sarek,现在可以开始了。
    猜你喜欢
    • 1970-01-01
    • 2017-07-09
    • 2018-06-21
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    相关资源
    最近更新 更多