`const` 字符串参数（线程）是否安全

Question

这段代码

procedure MyThreadTestA(const AStr: string);

比

快

procedure MyThreadTestB(AStr: string);

在做同样的工作时，两者都传递了一个指针。

但是，B 版“正确”更新了AStr 的引用计数，并在我更改时复制它。
版本 A 只传递一个指针，只有编译器阻止我更改 AStr。

如果我在 Assembler 中使用肮脏的技巧或以其他方式规避编译器保护，版本 A 是不安全的，这是众所周知的，但是...

通过引用传递AStr 作为const 参数线程安全吗？
如果AStr 在其他线程中的引用计数变为零并且字符串被破坏，会发生什么？

Answer 1

不，这样的技巧不是线程安全的。 Const 阻止添加引用，因此另一个线程的更改将以不可预知的方式影响该值。示例程序，尝试修改P定义中的const：

{$apptype console}
uses SysUtils, Classes, SyncObjs;

type
  TObj = class
  public
    S: string;
  end;

  TWorker = class(TThread)
  public
    procedure Execute; override;
  end;

var
  lock: TCriticalSection;
  obj: TObj;

procedure P(const x: string);
// procedure P(x: string);
begin
  Writeln('P(1): x = ', x);
  Writeln('Releasing obj');
  lock.Release;
  Sleep(10); // give worker a chance to run
  Writeln('P(2): x = ', x);
end;

procedure TWorker.Execute;
begin
  // wait until TMonitor is freed up
  Writeln('Worker started...');
  lock.Acquire;
  Writeln('worker fiddling with obj.S');
  obj.S := 'bar';
  TMonitor.Exit(obj);
end;

procedure Go;
begin
  lock := TCriticalSection.Create;
  obj := TObj.Create;
  obj.S := 'foo';
  UniqueString(obj.S);
  lock.Acquire;
  TWorker.Create(False);
  Sleep(10); // give worker a chance to run and block
  P(obj.S);
end;

begin
  Go;
end.

但它不仅限于线程；修改底层变量位置也有类似的效果：

{$apptype console}
uses SysUtils, Classes, SyncObjs;

type
  TObj = class
  public
    S: string;
  end;

var
  obj: TObj;

procedure P(const x: string);
begin
  Writeln('P(1): x = ', x);
  obj.S := 'bar'; 
  Writeln('P(2): x = ', x);
end;

procedure Go;
begin
  obj := TObj.Create;
  obj.S := 'foo';
  UniqueString(obj.S);
  P(obj.S);
end;

begin
  Go;
end.

Answer 2

补充巴里的回答：如果传递的字符串来自调用者范围内的局部变量，那绝对是线程安全的。

在这种情况下，该局部变量将保存一个有效的引用，并且要更改该局部变量的唯一方法（假设只是有效的 Pascal 代码，而不是在 asm 中摆弄）是如果您的调用返回。

这还包括字符串变量的源是函数调用的结果的所有情况（包括属性访问，例如 TStrings.Strings[]），因为在这种情况下，编译器必须将字符串存储在本地临时变量中.

只有在调用返回之前直接从可以更改字符串的位置（通过相同或另一个线程）传递字符串时，才会导致线程安全问题。