Grails - grails.config.locations 不适用于类路径和 .properties 文件

Question

我正在使用 Grails 2.5.3 版本进行应用程序。我想把数据库代码和Log4j部分外包出去。

Log4j 的代码在一个外部的 .groovy 文件中。用户不会修改此文件，因此不必是 /classes 目录中的属性文件。 在数据库代码的情况下，最好的方法是在外部属性文件中包含几个功能，因为将继续作为 /classes 目录中的属性文件。此外，DataSource.groovy 与其余配置一起存在。

然后，我只实现了使用 Log4j conf 工作：

grails.config.locations = ["file:./grails-app/conf/LogConfig.groovy"]

虽然我将文件放在 /grails-app/conf 目录中，但类路径不起作用。这不起作用：

grails.config.locations = ["classpath:LogConfig.groovy"]

另外，我添加了两种情况（运行应用程序和战争模式）。但是，当我运行 grails prod war 并部署 Tomcat 时，无法识别 Logconfig.groovy。

grails.config.locations = ["file:./grails-app/conf/LogConfig.groovy",
"classpath:LogConfig.groovy"]

对于数据库代码，我无法使用 .properties 文件。 这个文件我放在 grails-app/conf 中，它的包含是：

# DB properties
dataSource.username = xxx
dataSource.password = xxx
dataSouce.driverClassName = xxx
environments.development.dataSource.url = jdbc:mysql://localhost/xxx
environments.test.dataSource.url = jdbc:mysql://localhost/xxx
environments.production.dataSource.url = jdbc:mysql://localhost/xxx

我已经阅读了很多教程和博客，但我不知道如何才能做到这一点。

感谢您的帮助。

Answer 1

我们如何在开发和生产模式下做到这一点。

your-application/
    conf/
        dev/
        qa/
        prod/
    grails-app/
        conf/
          Config.groovy

grails-app 目录下的 Config.groovy：

environments {

    development {
        grails.logging.jul.usebridge = true

        grails.config.locations = [
          "file:conf/dev/XXXConfig.groovy",
          "file:conf/dev/XXXDataSource.groovy",
          "file:conf/dev/XXXLog4JConfig.groovy",
          "file:conf/dev/plugins/XXXSecurityConfig.groovy",
        ]        
    }
    production {
        grails.logging.jul.usebridge = false

        grails.config.locations = [
          "classpath:XXXConfig.groovy",
          "classpath:XXXDataSource.groovy",
          "classpath:XXXLog4JConfig.groovy",
          "classpath:plugins/XXXSecurityConfig.groovy",
        ]
    }
}

对于应用程序服务器（Tomcat、Websphere 等）中的部署，您只需将配置文件所在的目录添加到类路径。当您在类路径中有配置文件目录时，一切正常。

例如，我们运行 Tomcat 并具有将配置目录导出到类路径的启动脚本。

对于 Grails 3.x，我写了对这个 grails.config.locations 的支持，因为他们删除了这个特性，我不想改变我们做配置的方式。所以把你的 grails.config.locations -configurations 放到 grails-app/conf -directory 中的 application.groovy 中。

import org.grails.core.io.DefaultResourceLocator
import org.springframework.core.env.Environment
import grails.boot.config.GrailsAutoConfiguration
import org.springframework.core.env.MapPropertySource

class ApplicationConfigurationLoader {

    private ApplicationConfigurationLoader() {}

    public static load(GrailsAutoConfiguration application, Environment environment) {
        if (application && environment) {
            DefaultResourceLocator resourceLocator = new DefaultResourceLocator()
            def applicationGroovy = application.getClass().classLoader.getResource('application.groovy')
            if (applicationGroovy) {
                def applicationConfiguration = new ConfigSlurper(grails.util.Environment.current.name).parse(applicationGroovy)
                for (String configLocation in applicationConfiguration.grails.config.locations) {
                    def configurationResource = resourceLocator.findResourceForURI(configLocation)
                    if (configurationResource) {
                        def config = new ConfigSlurper(grails.util.Environment.current.name).parse(configurationResource.getURL())
                        environment.propertySources.addFirst(new MapPropertySource(configLocation, config))
                    }
                }
            }
        }
    }
}

在你的 grails-app/init 文件夹中你有你的 Application.groovy

import grails.boot.GrailsApp
import grails.boot.config.GrailsAutoConfiguration

import org.springframework.core.env.Environment
import org.springframework.context.EnvironmentAware

import com.bcbmedical.bfw.core.util.ApplicationConfigurationLoader

class Application extends GrailsAutoConfiguration implements EnvironmentAware {
    static void main(String[] args) {
        GrailsApp.run(Application, args)
    }

    @Override
    void setEnvironment(Environment environment) {
        ApplicationConfigurationLoader.load(this, environment)
    }

}

Answer 2

在我们的团队中，我们通常会放入 conf/Config.groovy：

def ENV_NAME = "PROJECT_NAME_CONFIG"

grails.config.locations = [EventHandlers]

if (System.getenv(ENV_NAME)) {
    println "Loading configuration file founded in environment variable - " + System.getenv(ENV_NAME)
    grails.config.locations << "file:" + System.getenv(ENV_NAME)
}
else if (System.getProperty(ENV_NAME)) {
    println "Loading configuration from property: " + System.getProperty(ENV_NAME)
    grails.config.locations << "file:" + System.getProperty(ENV_NAME)
}

并指定具有特定名称 PROJECT_NAME_CONFIG 的环境变量，以及 dev config f.e. 的路径：

导出 PROJECT_NAME_CONFIG=/home/user/Documents/work/my_project/My_Project_Config.groovy

导出 PATH="$PATH:$PROJECT_NAME_CONFIG"

示例 My_Project_Config.groovy：

environments {
    development {

        dataSource {
            username = "root"
            password = "password"
            
            logSql = true
            dbCreate = "update"
            url = "jdbc:mysql://localhost/my_project?useUnicode=yes&characterEncoding=UTF-8&autoReconnect=true"
        }
    }
}