来自数据库备份的属性文件的 Grails i18n？

Question

我想找到一种情况，我可以使用由数据库备份的 i18n 属性文件？

所以对于一些标准的东西，我想使用属性文件，但最终用户必须可以编辑某些字段，所以我计划在数据库中使用 i18n。所以真正的组合会很棒。如果在属性文件中找不到 i18n 代码，则在 DB 中查找。

知道我该如何解决这个问题吗？我看过帖子Grails i18n From Database but Default Back To File

但是这个问题没有真正的答案，还有其他关于如何解决这个问题的建议吗？

Answer 1

在你的项目中加入一个新的领域类：

class Message {
    String code
    Locale locale
    String text
}

将以下行添加到您的resources.groovy：

// Place your Spring DSL code here
beans = {
    messageSource(DatabaseMessageSource) {
        messageBundleMessageSource = ref("messageBundleMessageSource")
    }    
    messageBundleMessageSource(org.codehaus.groovy.grails.context.support.PluginAwareResourceBundleMessageSource) {
        basenames = "WEB-INF/grails-app/i18n/messages"
    }
}

并将以下类添加到您的 src/groovy 文件夹中：

class DatabaseMessageSource extends AbstractMessageSource {

    def messageBundleMessageSource

    protected MessageFormat resolveCode(String code, Locale locale) {
         Message msg = messageBundleMessageSource.resolveCode(code, locale)
         def format
         if(msg) {
             format = new MessageFormat(msg.text, msg.locale)
         }
         else {
             format = Message.findByCodeAndLocale(code, locale)
         }
         return format;
    }
}

现在 grails 将尝试从消息包中解析消息。如果不可用，它将从数据库中查找。您可以添加一些错误处理，但如果所有消息至少在一个地方可用，则此版本有效。

有关更多详细信息，请参阅http://graemerocher.blogspot.com/2010/04/reading-i18n-messages-from-database.html。

---

resources.groovy中所做更改的一些细节：

在此文件中，您可以定义可注入的 groovy 类，只需定义一个与 resources.groovy 中定义的名称相同的变量即可包含这些类。例如。在此文件中，有messageSource 和messageBundleMessageSource，您可以将它们包含在任何控制器或服务文件中。如果定义了此变量，则会创建括号中的类的实例。

在这种情况下，我们会覆盖通用 messageSource 以使用我们的自定义实现 DatabaseMessageSource。所以 I18n 函数message 现在将使用我们的自定义实现。

由于我们的自定义实现需要检查message.properties-文件，我们将原始消息源保留在第二个bean中。通过在我们的自定义实现中定义这个实例，我们仍然可以使用旧的实现（因此以通常的方式查找消息）。

Answer 2

我不确定我知道你的意思

使用数据库备份的 i18n 属性文件

但是，如果您只是想使用数据库表（而不是 .properties 文件）来解析消息键，那么您可以通过编写自己的 MessageSource 接口实现来做到这一点

class DBMessageSource implements MessageSource {
  String getMessage(MessageSourceResolvable resolvable, Locale locale) {
   // IMPLEMENT ME
  }

  String getMessage(String code, Object[] args, Locale locale) {
   // IMPLEMENT ME    
  }

  String getMessage(String code, Object[] args, String defaultMessage, Locale locale) {
   // IMPLEMENT ME    
  }
}

然后只需将messageSource bean 的默认实现替换为您的实现，方法是将以下内容添加到resources.groovy

messageSource(DBMessageSource)

Answer 3

在@crudolf 的回答之后，我实施了以下方法来实现我的目标。

class DatabaseMessageSource extends AbstractMessageSource {
    // the message bundle resource that holds all of the messages
    def messageBundleMessageSource

    // the default locale used when there is no correct results found
    // if a visitor (x) comes along with an unknown locale in the DB
    // then this locale will be used as fallback!
    Locale fallbackLocale = new Locale("nl", "NL")

    protected MessageFormat resolveCode(String code, Locale locale) {
        // first try to find the message in the messagebundles
        MessageFormat messageFormat = messageBundleMessageSource.resolveCode(code, locale)

        if(!messageFormat) {
            // no message found so lets find one in the database
            def message = Message.findByCodeAndLocale(code, locale) ?: Message.findByCodeAndLocale(code, fallbackLocale)
            if (message) {
                // found one create a message format!
                messageFormat = new MessageFormat(message.text, message.locale)
            } else {
                // not found! create a standard message format
                messageFormat = new MessageFormat(code, locale)
            }
        }
        return messageFormat
    }

}

Answer 4

看看https://github.com/goeh/grails-i18n-db 和https://github.com/halfbaked/grails-localizations。两者都提供了一个 GUI 来管理本地化。