Actionscript 3.0 - 鼠标事件不起作用答案

【问题标题】：Actionscript 3.0 - MouseEvents not workingActionscript 3.0 - 鼠标事件不起作用
【发布时间】：2014-04-29 19:23:38
【问题描述】：

我正在尝试通过 FlashDevelop 编写一种策略游戏，但在尝试使用事件（尤其是 MouseEvents）时遇到了问题。与其说事件返回错误，不如说它们什么都不做，甚至没有得到任何跟踪。

我试图让六边形 HexObject 图像在点击时不可见（只是一个简单的测试，看看 MouseEvent 是否真的有效）。

这是我的代码：

Main.as

package {
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;

    /**
     * ...
     * @author Dean Sinclair
     */

    public class Main extends Sprite {

        public var gameInitialised:Boolean = false;
        public var MIN_X:int = 0;
        public var MAX_X:int = stage.stageWidth;
        public var MIN_Y:int = 0;
        public var MAX_Y:int = stage.stageHeight - 100;

        public var GameGrid:HexGrid = new HexGrid(MIN_X, MAX_X, MIN_Y, MAX_Y);
        public var blackBG:Shape = new Shape();

        public function Main():void {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }

        private function init(e:Event = null):void {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            addEventListener(Event.ENTER_FRAME, update);
            // entry point
        }

        private function update(event:Event):void {
            if (gameInitialised == false) {
                GameGrid.initialiseGrid();
                initialiseBackground();
                gameInitialised = true;
            }

            updateGraphics();
        }

        public function drawGrid():void {
            for (var x:int = 0; x < GameGrid.TOTAL_X; x++) {
                for (var y:int = GameGrid.yArray[x][0]; y < GameGrid.yArray[x][1]; y++) {
                    if (x != GameGrid.nox || y != GameGrid.noy) {
                        GameGrid.Grid[x][y].update();
                        this.stage.addChild(GameGrid.Grid[x][y].image);
                    }
                }
            }
        }

        public function updateGraphics():void {
            this.stage.addChild(blackBG);
            drawGrid();
        }

        public function initialiseBackground():void {
            blackBG.graphics.beginFill(0x000000, 1);
            blackBG.graphics.lineStyle(10, 0xffffff, 1);
            blackBG.graphics.drawRect(0, 0, stage.stageWidth-1, stage.stageHeight-1);
            blackBG.graphics.endFill();
        }

    }

}

HexGrid.as

package {
    import flash.display.Sprite;
    import flash.events.Event;

    /**
     * ...
     * @author Dean Sinclair
     */
    public class HexGrid extends Sprite {

        public static var HEX_RADIUS:int = 0;
        public static var HEX_DIAMETER:int = 0;
        public static var GRID_WIDTH:int = 0;
        public static var GRID_HEIGHT:int = 0;
        public var TOTAL_X:int = 0;

        public var MIN_X:int = 0;
        public var MAX_X:int = 0;
        public var MIN_Y:int = 0;
        public var MAX_Y:int = 0;

        public var Grid:Array;
        public var yArray:Array;

        public function HexGrid(min_x:int, max_x:int, min_y:int, max_y:int) {
            super();
            MIN_X = min_x;
            MAX_X = max_x;
            MIN_Y = min_y;
            MAX_Y = max_y;
        }

        public function initialiseGrid():void {
            setGridDetails();
            setLineLengths();
            setGridPositions();
        }

        public function setGridDetails():void {
            HEX_RADIUS = 25;
            HEX_DIAMETER = 2 * HEX_RADIUS;
            GRID_WIDTH = (((MAX_X - MIN_X) / HEX_DIAMETER) - 1);
            GRID_HEIGHT = ((((MAX_Y - 100) - MIN_Y) / (HEX_DIAMETER - (HEX_DIAMETER / 3))) - 3);
            TOTAL_X = GRID_WIDTH + Math.floor((GRID_HEIGHT - 1) / 2);
        }

        private function setLineLengths():void {
            yArray = new Array(TOTAL_X);
            for (var a:int = 0; a < TOTAL_X; a++) {
                yArray[a] = new Array(2);
            }
            for (var x:int = 0; x < TOTAL_X; x++) {
                if (x < GRID_WIDTH) {
                    yArray[x][0] = 0;
                }else {
                    yArray[x][0] = (x - GRID_WIDTH + 1) * 2;
                }
                yArray[x][1] = 1 + (2 * x);
                if (yArray[x][1] > GRID_HEIGHT) {
                    yArray[x][1] = GRID_HEIGHT;
                }
                trace("Line", x, "   starts at", yArray[x][0], "   ends at", yArray[x][1]);
            }
        }

        public var nox:int = 5;
        public var noy:int = 3;

        private function setGridPositions():void {
            var hexState:int = 4;

            Grid = new Array(TOTAL_X);
            for (var x:int = 0; x < TOTAL_X; x++) {
                Grid[x] = new Array(yArray[x][1]);
                for (var y:int = yArray[x][0]; y < yArray[x][1]; y++) {
                    if(nox!=4 || noy!=6){
                        Grid[x][y] = new HexObject(HEX_DIAMETER + (HEX_DIAMETER * x) - (HEX_RADIUS * y), HEX_DIAMETER + (HEX_DIAMETER * y) - ((HEX_DIAMETER / 3) * y), HEX_RADIUS, 2);
                    }
                } 
            }
        }
    }
}

HexObject.as

package {
    import flash.display.Bitmap;
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;

    /**
     * ...
     * @author Dean Sinclair
     */
    public class HexObject extends Sprite {
        [Embed(source = "../images/hexagons/hex_darkRed.png")]
        private var DarkRedHex:Class;
        [Embed(source = "../images/hexagons/hex_lightBlue.png")]
        private var LightBlueHex:Class;
        [Embed(source = "../images/hexagons/hex_midGreen.png")]
        private var MidGreenHex:Class;

        public var image:Bitmap = new LightBlueHex();
        protected var state:int = 0;
        private var radius:int = 0;

        public function HexObject(xPos:int, yPos:int, hexRadius:int, hexState:int) {
            super();
            x = xPos;
            y = yPos;
            state = hexState;
            radius = hexRadius;
            checkState();
            initialiseGraphics();
        }

        private function checkState():void {
            switch(state) {
                case 1:     // plains
                    image = new MidGreenHex();
                    break;
                case 2:     // hills
                    break;
                case 3:     // rock
                    image = new DarkRedHex();
                    break;
                case 4:     // water
                    image = new LightBlueHex();
                    break;
                default:
                    break;
            }
        }

        private function initialiseGraphics():void {
            image.visible = true;
            image.width = radius * 2;
            image.height = radius * 2;
            image.x = x - radius;
            image.y = y - radius;
        }

        private function onMouseClick(e:MouseEvent):void {
            image.visible = false;
            trace("image.visible =", image.visible);
        }

        public function update():void {
            image.addEventListener(MouseEvent.CLICK, onMouseClick);
        }
    }
}

我已经尝试了无数方法来使事件正常进行，但都没有成功。任何形式的解决方案都是救命稻草，因为我已经为此辛勤工作了几个小时，谢谢！

【问题讨论】：

你在函数中有很多初始化代码，每帧都会调用，我先把它提取出来
我重新设计了代码，这样初始化的代码就不会在每一帧都被调用，而且它更整洁，但它仍然没有显示跟踪。就好像这些对象甚至没有被添加到舞台上，尽管它们显示正确。
我建议您编辑您的帖子以显示更新后的代码。但无论如何，你的问题是图像是一个Bitmap，它不会调度鼠标事件，把它放在一个容器中Sprite
现在更新了帖子。谢谢，这对我的问题有很多启发。不过，我究竟如何将它放入 Sprite 容器中？
在 HexObject 中创建 imageContainer Sprite，然后创建 imageContainer.addChild(image)。现在不再引用其他类中的 obj.image，而是将其更改为 imageContainer。尽管我会重构您的代码以简单地将图像添加为 HexObject（这是一个 Sprite）的子对象，然后从其他类中删除 .image 的所有使用并只处理该对象

标签： actionscript-3 mouseevent stage

【解决方案1】：

VBCPP 解决了我的问题，我正在使用无法调度 MouseEvents 的类 Bitmap。解决方案是从HexObject 中取出image 并将其放入Sprite 类型的容器中，逻辑容器是它所在的对象。我只需在HexObject.as 中添加以下代码：

this.addChild(image);

然后只在将来引用对象，而不是 image。

【讨论】：