Delphi中GetLastError和FormatMessage的正确用法是什么？

Question

我在 Delphi 2006（也是 Delphi 7）中使用第三方组件时遇到问题，在执行对该组件的函数调用时出现“未指定错误”。您是否有在 Delphi 中使用 GetLastError 和 FormatMessage 的示例代码，可以让我访问有关错误的更多信息？ TIA :)

Answer 1

Delphi 中有一个集成的辅助函数：SysErrorMessage。它本质上是FormatMessage 的包装器，但在您的情况下使用起来要简单得多。只需提供您需要文字说明的错误代码即可。

例如，您可以使用它来显示最后一个错误：

ShowMessage(SysErrorMessage(GetLastError))

如果你想用这个消息引发异常，那就更简单了：

RaiseLastOSError;

重要提示：确保失败的函数和你的GetLastError调用之间没有额外的API调用，否则最后的错误将被重置。

Answer 2

虽然 DR 是正确的，但这种方法存在一个问题：它不允许您指定发生错误的上下文。见过错误“API 函数失败”。不知道它是哪个功能以及它发生在哪里？

这就是我编写 RaiseLastOsErrorEx 和 Win32CheckEx 函数的原因：

procedure RaiseLastOsErrorEx(const _Format: string);
begin
  RaiseLastOsErrorEx(GetLastError, _Format);
end;

procedure RaiseLastOsErrorEx(_ErrorCode: integer; _Format: string); overload;
var
  Error: EOSError;
begin
  if _ErrorCode <> ERROR_SUCCESS then
    Error := EOSError.CreateFmt(_Format, [_ErrorCode, SysErrorMessage(_ErrorCode)])
  else
    Error := EOsError.CreateFmt(_Format, [_ErrorCode, _('unknown OS error')]);
  Error.ErrorCode := _ErrorCode;
  raise Error;
end;

function GetLastOsError(out _Error: string; const _Format: string = ''): DWORD;
begin
  Result := GetLastOsError(GetLastError, _Error, _Format);
end;

function GetLastOsError(_ErrCode: integer; out _Error: string; const _Format: string = ''): DWORD;
var
  s: string;
begin
  Result := _ErrCode;
  if Result <> ERROR_SUCCESS then
    s := SysErrorMessage(Result)
  else
    s := _('unknown OS error');
  if _Format <> '' then
    try
      _Error := Format(_Format, [Result, s])
    except
      _Error := s;
    end else
    _Error := s;
end;

function Win32CheckEx(_RetVal: BOOL; out _ErrorCode: DWORD; out _Error: string;
  const _Format: string = ''): BOOL;
begin
  Result := _RetVal;
  if not Result then
    _ErrorCode := GetLastOsError(_Error, _Format);
end;

（它们是我的 dzLib 库的 u_dzMiscUtils 单元的一部分，可在此处获得： https://osdn.net/projects/dzlib-tools/svn/view/dzlib/trunk/src/u_dzMiscUtils.pas?view=markup&root=dzlib-tools#l313