哪个libc时间给了我一天中的时间？

Question

Fedora 33 乐

我想用 NativeCall 与 lic.so.6 谈谈我正在写的一个例子。我找到了

• https://www.gnu.org/software/libc/manual/html_node/Function-Index.html
• https://www.gnu.org/software/libc/manual/html_node/Getting-the-Time.html#index-clock_005fgettime

但我不知道哪一个只会给我一天中的时间 (21:02:03)

挠头，

Answer 1

要让 libc.so.6 获取本地时间，您首先必须从 time 获取原始系统时间，然后输入 localtime 原始系统时间以获取您的小时、分钟等。

例如：

#!/usr/bin/env raku
use NativeCall;


class tm is repr('CStruct') { 
   has int32   $.tm_sec;              # Seconds.    [0-60] (1 leap second)
   has int32   $.tm_min;            # Minutes.  [0-59] 
   has int32   $.tm_hour;       # Hours.    [0-23]
   has int32   $.tm_mday;       # Day.      [1-31]
   has int32   $.tm_mon;            # Month.    [0-11]
   has int32   $.tm_year;       # Year  - 1900.   Add 1900 to this to get a four digit year
   has int32   $.tm_wday;       # Day of week.  [0-6]
   has int32   $.tm_yday;         # Days in year.[0-365]
   has int32   $.tm_isdst;    # DST.        [-1/0/1]
   has int64   $.tm_gmtoff;     # Seconds east of UTC.
   has byte    $.tm_zone;    # Timezone abbreviation.
   
   # note: the mysterious "time_t" structure is a "long, long int" or int64
  
     
   # /usr/lib64/libc.so.6    `'c',v6` converts to "libc.so.6"
   # C: time (&rawtime);     /* "&rawtime" is the address of "rawtime" */
   sub  time( int64 is rw ) is native( 'c', v6 ) { * };    # "is rw" makes it a pointer
   
   # C: timeinfo = localtime (&rawtime);   /* "&rawtime" is the address of "rawtime" */
   sub  localtime( int64 is rw ) returns tm is native( 'c', v6 ) { * };  # "is rw" makes it a pointer
   

   method GetRawTime( --> int64 ) {
      my int64 $rawtime;
      time( $rawtime );
      return $rawtime;
   }
          
   method GetLocalTime() returns tm  {
      # my Str $SubName = &?ROUTINE.name;
      my $time = tm.new;
      my int64 $rawtime = 0;
      
      $rawtime = tm.GetRawTime();      
      $time = localtime( $rawtime );
      return $time;
   }    
   
}

my int64 $RawTime = 0;
$RawTime = tm.GetRawTime();
print "raw time = <" ~ $RawTime ~ ">\n";

my $SysTime = tm.new;
$SysTime    = tm.GetLocalTime();
print "Local Time HH:MM:SS <" ~ $SysTime.tm_hour ~ ":" ~ 
      $SysTime.tm_min ~ ":" ~ $SysTime.tm_sec ~ ">\n";
print "year = <" ~ $SysTime.tm_year + 1900 ~ ">\n";

示例输出：

$ LinSysTime.pl6
raw time = <1608970172>
Local Time HH:MM:SS <0:9:32>
year = <2020>

Answer 2

原则上我不应该试图写一个答案。^[1]但是有些人说不耐烦和/或傲慢可能是一种美德......

给我一​​天中的时间（21:02:03）

您链接的页面仅列出了介绍性文档中所说的“与人们通常认为...时间的方式无关”的功能。^[3]

---

我查看了 Håkon 链接的模块，以及它使用的模块：P5localtime。它包括这一行：

my sub get-ctime(int64 is rw --> Str) is native is symbol<ctime> {*}

这将调用 C 函数 ctime，该函数记录在您链接的网站的 Formatting Calendar Time 页面上。

我的猜测是你想调用ctime_r 函数或类似函数。

---

我记得最近阅读了你和了解此类事情的人（ugexe？）之间的交流，关于如何具体选择 glibc.so.6 而不是其他版本，所以我会跳过这个皱纹。

脚注

^[1] 很高兴为您提供一天中的时间，尽管它可能不是您想要的时间。我对相关成分几乎一无所知^[2]。我回答你的问题的唯一借口是，我有时有足够的时间以及那种傲慢和不耐烦来回答关于我一无所知的主题的问题，这不是拉里的美德。

^[2] 我不记得使用 C 来编写任何生产代码。我不知道 libc 时间函数。我只使用 NativeCall 做一些琐碎的事情，比如我记得在阅读 this blog post 时所做的一些“hello world”测试。

^[3] 您正在查看的页面 -- Getting the time -- 对您来说可能听起来很有希望，但如果您在网站你会来到一个标题为Time Basics 的页面，它强烈建议我使用Formatting Calendar Time 页面或Broken-down Time 页面中的函数。^[4]

^[4] 虽然我确实有疑问。首先，我不知道我在说什么。^[2] 其次，每个函数都有这样的注释，令人不安：

AS-不安全的堆锁

您可以自行阅读解释这些术语的 POSIX Safety Concepts 文档，以便您进行相应调整。