在两个不同的列中查找包含两个单元格值的行

Question

我编写了一对 If 语句来检查两个单元格中的两个列的值（例如，检查 A 列的 B3.Value，检查 G 列的 B2.Value），只是意识到这不会返回结果基于存在于同一行中的那些值，但前提是它们完全存在于表中。

我的目标是让代码检查 A 列中是否存在具有 B3.Value 的行和 G 列中的 B2.Value。这些列位于表的 DataBodyRange 中（因为范围将是动态的）。现在，我得到的错误代码是

Dim tblData As ListObject
Dim checkDate As Date
Dim reportSup As Range
Dim reportDate As Range

Set tblData = Worksheets("Data").ListObjects(1)
Set reportSup = Worksheets("Daily").Range("B2")
Set reportDate = Worksheets("Daily").Range("B3")

  checkDate = WorksheetFunction.Max(Worksheets("Data") _
    .ListObjects("Data") _
    .ListColumns("Date") _
    .DataBodyRange)

  If reportDate.Value = checkDate Then

    If Not IsError(Application.Match(reportSup.Value, _
      tblData.ListColumns(7).DataBodyRange, 0)) Then

      MsgBox "You have already reported for this period. " & _
        "Please enter a different date."
      reportDate.Select
      Exit Sub

    End If

  End If

我不确定是否应该使用 EVALUATE 或 INDEX 来找到满足这两个条件的行，以便如果该行存在，则弹出 MsgBox，否则继续执行其余代码。

Answer 1

如果我正确理解了您的问题，这就是您想要的。它使用 Find 在 A 列中查找 B3 值，然后检查相应的 G 列值。我假设这只会发生一次，因此如果不是这种情况，则需要修改代码。

Sub x()

Dim tblData As ListObject
Dim reportSup As Range
Dim reportDate As Range, rFind As Range, s As String

Set tblData = Worksheets("Data").ListObjects(1)
Set reportSup = Worksheets("Daily").Range("B2")
Set reportDate = Worksheets("Daily").Range("B3")

With tblData.ListColumns(1).DataBodyRange
    Set rFind = .Find(What:=reportDate, LookAt:=xlWhole, MatchCase:=False, SearchFormat:=False)
    If Not rFind Is Nothing Then
        s = rFind.Address
        Do
            If rFind.Offset(, 6).Value = reportSup.Value Then
                MsgBox "Both values found in row " & rFind.Row
                Exit Sub
            Else
                Set rFind = .FindNext(rFind)
            End If
         Loop While rFind.Address <> s
    End If
End With

End Sub