突出显示 Excel 中包含另一行中每个数字的行？答案

【问题标题】：Highlight rows in Excel that contain every number from another row?突出显示 Excel 中包含另一行中每个数字的行？
【发布时间】：2019-10-04 01:46:47
【问题描述】：

我有一个包含数千行 6 列的电子表格，每列都有一个数字。

我要做的是突出显示其中的数字与另一行中的所有数字匹配的任何行。

例如：

A1: 22, B1: 19, C1: 11, D1: 17, E1: 08, F1: 01
A2: 08, B2: 17, C2: 22, D2: 01, E2: 19, F2: 11

如果我只有这些行，我希望这两行都被突出显示，因为它们中的所有数字都与另一行中的所有数字匹配。

这个可以吗？

【问题讨论】：

如果从 A 列到 F 列的行数与电子表格中另一行的数字完全相同（在我的示例中，这将是第二行），则突出显示整行。
不重复。如果你看我上面的例子，这两行不是重复的，但它们确实包含彼此完全相同的数字，只是在不同的列中。我想要的是以某种方式标记任何符合此标准的行。我认为突出显示是最好的方法。
你是怎么做到的？

标签： excel excel-formula spreadsheet conditional-formatting

【解决方案1】：

在我的解决方案中，我使用了一些辅助列。

单元格G2中的公式是

=SMALL($A2:$F2,COLUMN()-6)&";"

拖到L列，再往下拖到第8行。逻辑是把A列到F列的数字从小到大排序，并在每个末尾添加特殊符号分号;价值。

单元格M2中的公式是

=G2&H2&I2&J2&K2&L2

将其拖到第 8 行。逻辑是将值组合成一个字符串。如果您有权访问 TEXTJOIN 函数，则可以使用此 数组公式 =TEXTJOIN(";",0,SMALL($A2:$F2,ROW($1:$6))) 而无需创建辅助列 G 到 L。因为它是一个数组公式，您完成公式栏中的公式后需要按Ctrl+Shift+Enter。

单元格N2中的公式是

=COUNTIF($M$2:$M$8,M2)>1

将其拖到第 8 行。逻辑是找出该字符串是否在该范围内多次出现，如果出现则返回 TRUE。

最后，突出显示A1:F8，使用以下公式设置条件格式规则并选择所需的突出显示颜色：

=$N2

如果您有任何问题，请告诉我。干杯:)

【讨论】：

它完全符合我的要求。非常感谢。
@acmarston 乐于助人:)

【解决方案2】：

假设A列到F列的数据都是2位数的文本值

在 A1:F1 中，输入：22,19,11,17,08,01

在 A2:F2 中，输入：08,17,22,01,19,11

在助手中，将G1公式复制下来：

=TEXT(SUM(LARGE(--MID(A1&B1&C1&D1&E1&F1,{1,3,5,7,9,11},2),{1;2;3;4;5;6})*{1;100;10000;1000000;100000000;10000000000}),"000000000000")

然后，选择 A1:G2 >> 条件格式 >> 新规则 >> 选择，使用公式……>>

在规则框中输入：

=COUNTIF($G$1:$G$2,$G1)>1

点击格式>>选择单元格背景颜色

确定 >> 完成

【讨论】：