Terraform 有条件地指定某些文本

Question

在 Terraform 中，我试图提出一个条件，即搜索特定键以稍后执行操作。下面是我定义的地图变量的示例。我想做的是让 Terraform “过滤”某些键并执行某些操作。任何如何实现这一点的建议都会有所帮助。

variable "volumes" {
 type = map(object({
    size              = string
    availability_zone = string
  }))
  default = {
    "Primary" = {
      size              = "200"
      availability_zone = "us-west-2a"
    }
    "PrimarySecondary" = {
      size              = "100"
      availability_zone = "us-west-2a"
    }
    "Worker1" = {
      size              = "200"
      availability_zone = "us-west-2b"
    }
    "Worker1Secondary" = {
      size              = "100"
      availability_zone = "us-west-2b"
    }
    "Worker2" = {
      size              = "200"
      availability_zone = "us-west-2c"
    }
    "Worker2Secondary" = {
      size              = "100"
      availability_zone = "us-west-2c"
    }
  }
}

resource "aws_ebs_volume" "partition" {
  for_each          = var.volumes
  availability_zone = each.value.availability_zone
  size              = each.value.size

  tags = {
    Name = each.key
  }
}

resource "aws_volume_attachment" "ebs_att" {
  for_each    = aws_ebs_volume.partition
  device_name = each.key == ("Primary" || "Worker1" || "Worker2") ? "/dev/sdf" : "/dev/sdg"
  volume_id   = each.value.id
  instance_id = aws_instance.private[each.key].id
}

错误

Error: Invalid operand

  on vpc.tf line 49, in resource "aws_volume_attachment" "ebs_att":
  49:   device_name = each.key == ("Primary" || "Worker1" || "Worker2") ? "/dev/sdf" : "/dev/sdg"

Unsuitable value for right operand: a bool is required.

Answer 1

这里的表达式 "Primary" || "Worker1" || "Worker2" 被 Terraform 拒绝，因为 || 是布尔 OR 运算符，它只能用于布尔值，不能用于字符串。

您的意图似乎是说“如果each.key 是这些值之一”，在这种情况下，一种方法是使用the contains function：

  device_name = contains(["Primary", "Worker1", "Worker2"], each.key) ? "/dev/sdf" : "/dev/sdg"

我会考虑的另一种选择是使用显示每个键的设备名称的地图创建一个本地值，如下所示：

locals {
  volume_device_names = {
    Primary = "/dev/sdf"
    Worker1 = "/dev/sdf"
    Worker2 = "/dev/sdf"
    PrimarySecondary = "/dev/sdg"
    Worker1Secondary = "/dev/sdg"
    Worker2Secondary = "/dev/sdg"
  }
}

那么你的条件表达式就可以变成地图查找了：

  device_name = local.volume_device_names[each.key]

这有一些不同的权衡，根据您的需要，这可能是也可能不是优势：

• 如果调用者在变量值中指定了一个意外的键名，那么第一个示例将默认为/dev/sdg，而第二个示例将产生映射查找错误。如果您的有效键集是固定集，那么在调用者不小心打错字时返回错误可能会有所帮助。
• 在第一个示例中，为音量键选择设备名称的规则内嵌在aws_ebs_volume_attachment 资源配置中，这意味着我们可以查看该资源名称并直接了解它将如何选择一个。但是，这意味着规则与variable "volumes" 的定义“相距甚远”（从阅读模块的人的角度来看），这可能会让人更难看出该映射的键在决定设备如何获取时很重要随附的。将其分解为 locals 块意味着它可以与 variable "volumes" 块相邻放置，以便阅读该变量定义的人更容易找到。

还有一些其他变体可以在这两者之间做出不同的妥协，但是这个答案已经足够长了，所以除非你有具体的问题，否则我会将这些作为练习。