有没有办法配置 YAP（和/或 SWI 序言），以便在对 term_to_atom/2 的任何调用中保留变量名称？。
例如，当我执行此操作时：
term_to_atom(member(X, [1,2]), A).
我得到这个答案：
A = 'member(_131405,[1,2])'
X 已被其内部表示取代。
但是，我想得到这个答案：
A = 'member(X,[1,2])'
感谢您的帮助！
【问题讨论】：
标签： prolog
涉及两个问题。如何将变量名X 获取到系统中，以及如何将带有此类变量的术语获取到原子中。
您输入的X 由顶层读取，将其转换为没有关联名称的常规变量。让我们在 YAP 中看看：
?- read(Term).
|: X+3*Y+X.
Term = _A+3*_B+_A
|: 是 YAP 的输入提示符。我们已经输入了 X+3*Y+X. 但是，变量 Term 包含 _A 和 _B（由顶层选择的名称）代替了 X 和 Y。所以信息一旦被read/1读取就丢失了，无法恢复。
您必须使用更通用的内置阅读器read_term/2,3 和选项variable_names/1 以不同方式访问该信息。
?- read_term(T,[variable_names(Eqs)]).
|: X+3*Y+X.
Eqs = ['X'=_A,'Y'=_B],
T = _A+3*_B+_A
所以读取选项variable_names/1 为您提供了恢复变量名称的信息。对于read_term/2 读取的每个命名变量，都有一个结构Name = Variable，其中Name 是表示变量名称的原子。上面，'X' 是名字大写的 X。
匿名变量，即名称为_ 的变量，不会出现在变量名列表中。可以像这样快速提取它们：
?- read_term(T,[variable_names(Eqs)]),
term_variables(Eqs, Named),
term_variables(Named+T, Vars),
append(Named, Anons, Vars).
阅读完毕。
现在开始写作。我们不能直接写这个词，但必须附上列表Eqs。我们将新谓词称为term_to_atom(Term, Eqs, Atom)。在 YAP 和 SWI 中都有 with_output_to(Output, Goal)，它将 Goal 的输出写入到不同的目的地，例如 atom(A)。因此，您现在可以使用 write_term/2 随意编写术语。一个例子：
?- with_output_to(atom(A),write_term('a b'+X,[quoted(true)])).
A = '\'a b\'+_131284'.
变量_131284 看起来很丑。要获取与其名称关联的变量以进行打印，我们可以实现term_to_atom/3，如下所示：
term_to_atom(T, Eqs, A) :-
with_output_to(atom(A), write_term(T,[variable_names(Eqs),quoted(true)]) ).
然后像这样使用它：
?- read_term(T,[variable_names(Eqs)]), term_to_atom(T, Eqs, Atom).
|: X+3*Y+X.
Atom = 'X+3*Y+X',
Eqs = ['X'=_A,'Y'=_B],
T = _A+3*_B+_A
variable_names/1 exists as a write option 在 ISO、Minerva、Jekejeke、GNU、B、SWI、YAP 和 SICStus 中。
在将术语写入列表的鼻祖 SICStus 中，有人写道：
:- use_module(library(codesio)).
term_to_atom(T, Eqs, Atom) :-
write_term_to_codes(T, Codes, [variable_names(Eqs),quoted(true)]),
atom_codes(Atom, Codes).
以下是针对 6.3.4 之前的 YAP 的 ISO 不兼容解决方法。不再需要了。至于与单独写入选项的区别：term_to_atom/3 如下定义会干扰约束，无法正确渲染'$VAR'/1。
但目前我们只能近似理想的选择
variable_names/1。要使用我们自己的变量名打印术语， 变量必须在 YAP 中替换为'$VAR'(Codes)其中Codes是字符代码列表。这不完全是 相同，但非常接近。这进入一个文件：:- use_module(library(apply)). :- use_module(library(lambda)). write_eqs_term(T, Eqs) :- \+ \+ ( maplist(\Eq^( Eq = (N='$VAR'(Chs)), atom_codes(N,Chs)), Eqs), write_term(T,[numbervars(true),quoted(true)]) ). term_to_atom(T, Eqs, A) :- with_output_to(atom(A), write_eqs_term(T, Eqs) ).对于 SWI，您必须将
atom_codes(N,Chs)替换为N = Ch。 并首先安装library(lambda)。它已预装在 YAP 中。
【讨论】：