为交互式 IO 编写循环：do-notation 和布局的问题

Question

我刚开始使用 Haskell，它完全让我感到困惑。我之前学过 Java 和 Python，这对我来说更有意义。

我目前正在尝试获取用户输入，检查它是否有效，如果不是：打印错误并再次获取输入；如果有效：从中生成一个布尔值。

更准确地说，我想要一个是/否输入，其中“y”将产生 True，“n”将产生 False，任何其他输入都会在命令行中打印一条消息并要求输入 y/n再次。

例如：

Continue? y/n:
> assd
Invalid input.
Continue? y/n:
> y
(something happens)
Continue? y/n:
> n
(Close program)

用farmiliar格式写，这样的函数：

boolean inputBool() {
    while(True) {
       str = input("Continue? y/n: ");
       if (str == "y") {
           return True;
       } else if (str == "n") {
           return False;
       } else {
           print("Invalid input");
       }
}

--main program--

while(inputBool()) {
    doSomething();
}

自从我刚开始使用haskell（实际上是今天）以来，我不太清楚我能做什么或不能做什么。 我在想类似的东西：

yesno :: Bool
yesno = do
        putStr "Continue? y/n: " 
        str <- readLn
        if (str == "y") then True else (
            if (str == "n") then False else (
                do
                putStrLn "Invalid input."
                yesno
            )    
        )

由于许多原因，这不起作用。我的主要问题是我不知道这个“做什么”是做什么的。我刚刚读到它在需要 io 操作时使用并以某种方式执行以下表达式。在haskell中阅读完所有内容都会评估为一个值后，这对我来说没有意义。 “做什么”评价什么？ 另外，预计会有什么缩进？这似乎是一种随机。 我知道该函数必须评估为我的布尔值，使用此“do”操作似乎不可能。但是，如何将某些内容打印到控制台并仍然使其成为计算结果为 True 或 False 的表达式的一部分？

感谢您的帮助。

（顺便说一句。互联网上有活跃的haskell论坛吗？我找不到任何=/）

Answer 1

由于你的函数需要进行IO，所以它必须在IO monad中返回一个值，所以它的类型需要是yesno :: IO Bool，并且需要将True和False的值提升到monad中通过return。您还需要getLine 而不是readLn，因为您需要原始字符串，而不是解析值（这可能会导致解析错误）。最后，您需要在调用getLine 之前先hFlush stdout，否则提示符仍将坐在缓冲区中等待换行符（这需要您导入System.IO）。

我已经把提示字符串变成了一个参数，所以你可以使用这个函数来询问各种是/否问题：

import System.IO

yesno :: String -> IO Bool
yesno prompt = do
          putStr $ prompt ++ " y/n: "
          hFlush stdout
          str <- getLine
          case str of
            "y" -> return True
            "n" -> return False
            _   -> do
              putStrLn "Invalid input."
              yesno prompt

然后，您可以从交互循环中调用您的函数：

main :: IO ()
main = do
         fun <- yesno "Is Haskell fun?"
         if fun
          then putStrLn "rock on"
          else putStrLn "read more tutorials"
         continue <- yesno "Continue?"
         if continue then main else return ()