比较两个字符串时类型不匹配

Question

我有以下代码将用户窗体 (GUI) 上的组合框与工作簿 sheet2 上的填充单元格进行比较，我收到“类型不匹配”错误。这一切都在起作用，直到另一个子将一些数据转移到工作表 2 上正在比较的单元格中。

我的问题在于if Worksheets(sheet2).cells(1,i).value = LCase(GUI.superCB.Value) then

Worksheets(sheet2).cells(1,i).value 现在在手表中显示为 Variant/Integer，这让我觉得当数据移动时，它改变了该单元格的“样式”。

Private Sub NextButton_Click() ''' adds check boxes to frame

Dim i As Integer
'Dim superColm As Integer
For i = 5 To 12
    If Worksheets(Sheet2).Cells(1, i).Value = LCase(GUI.superCB.Value) Then 'problem line is right here
        superColm = i
        Exit For
    Else
    End If
Next i

NextButton.Visible = False
superCB.Visible = False

Run.Visible = True
Frame1.Visible = True



    Dim chk As Control
    Dim idx As Integer

    Dim lastrow As Integer
    lastrow = Worksheets(Sheet2).Cells(Rows.Count, superColm).End(xlUp).Row

    For idx = 1 To lastrow - 1
        Set chk = GUI.Frame1.Controls.add("Forms.CheckBox.1", idx, True)
        'set chk = gui.Frame1.Controls.Add(
        chk.Visible = True
        chk.Left = 5
        chk.Top = (idx - 1) * (chk.Height + 2)
        chk.Caption = Cells(idx + 1, superColm) & "   " & idx
    Next
    With Me.Frame1
        .ScrollBars = fmScrollBarsVertical
            If lastrow <= 10 Then
                .ScrollHeight = .InsideHeight * 1.5
            ElseIf lastrow <= 15 Then
                .ScrollHeight = .InsideHeight * 2.25
            ElseIf lastrow <= 20 Then
                .ScrollHeight = .InsideHeight * 3
            ElseIf lastrow <= 25 Then
                .ScrollHeight = .InsideHeight * 3.9
            ElseIf lastrow <= 30 Then
                .ScrollHeight = .InsideHeight * 4.75
            ElseIf lastrow <= 35 Then
                .ScrollHeight = .InsideHeight * 5.35
            Else
                .ScrollHeight = .InsideHeight * 6.25
            End If
        .ScrollWidth = .InsideWidth * 9
    End With
End Sub

如果我将工作表 2 作为活动工作表 Cells(1,i).value 将起作用，但我最终需要对用户隐藏工作表 2。通过这项工作，我认为单元格样式不是问题。

我已尝试转到 Excel.Workbooks("Shawn_sch_v1.2.xlsm").worksheets(sheet2).cells(1,i).value 以及所有内容到基本单元格（），希望它缺少工作表参考，但没有任何帮助。

Answer 1

String 可以安全地与 VBA 中的任何其他数据类型进行比较...除了Error。

将Variant/Error 与任何内容进行比较都会引发类型不匹配错误。

此代码隐式访问 ActiveSheet 的任何内容：

chk.Caption = Cells(idx + 1, superColm) & "   " & idx

Cells 应使用您要使用的特定 Worksheet 对象进行限定。如果活动工作表包含无法强制转换为String 的值（例如#VALUE! 或#REF!），则会引发类型不匹配错误。

Worksheets(Sheet2).Cells(1, i).Value = ...

这里Sheet2 是一个标识符。 Worksheets 索引器需要整数值或字符串。如果Sheet2 是ThisWorkbook 中工作表的代号，则无需从Worksheets 中取消引用它 - 只需使用它：

Sheet2.Cells(1, i).Value = ...

Worksheet 类没有默认属性，因此Debug.Print Worksheets(Sheet2) 抛出错误 438 对象不支持此属性或方法 - 以及后续像.Cells(1, i) 这样的成员调用也会引发类型不匹配 错误。如果您没有包含工作表名称的Sheet2 字符串变量，我怀疑这就是您现在遇到的错误...这意味着上面的所有内容都在等着咬您:)

如果Sheet2 是一个包含有效工作表名称的字符串变量，您可以使用IsError 函数来验证Variant 是否是Variant/Error：

If Not IsError(Sheet2.Cells(1, i).Value) Then
    ' value is safe to compare against a string
Else
    ' comparing the cell value to anything will throw error 13
End If

最后，我建议不要将Rows 用作全局变量，因为它已经是一个全局范围标识符（[_Global].Rows，隐含地引用ActiveSheet）。现在，在不破坏代码的情况下，使用 Find/Replace 重命名该变量将非常困难：Rubberduck 的“重命名”重构可能有助于安全地执行此操作（免责声明：我管理该 OSS VBIDE 插件项目)。

Answer 2

这将通过首先检查范围对象数据类型来解决。

Worksheets(Sheet2).Cells(1, i).Value 是范围对象。这可以在每次修改范围时更改数据类型，具体取决于修改方式。

LCase(GUI.superCB.Value) 这似乎是一个表单控件。如果范围是整数，则无法进行比较。

试试这样的：

Dim i As Integer
Dim iRange as String
'Dim superColm As Integer
`This is untested
For i = 5 To 12
iRange = Worksheets(sheet2).Cells(1, i).Text
If iRange = LCase(GUI.superCB.Value) Then 'problem line is right here
    superColm = i
    Exit For
Else
End If
Next i

这个想法是首先确保数据类型相同。

您可能需要使用.Text 或.Value2 而不是.Value 作为范围。如果范围对象可能是 Empty 或 Nothing ，那么您还需要检查这些。

编辑：将 .Value 更改为 .Text Edit2：这个答案不正确。