Delphi - 如何将“类型”作为参数传递

Question

我想知道是否可以将声明的类型（在本例中为记录）传递给我的函数。我什至不会问它是否不是 SizeOf() 函数，因为它可以将类型作为参数。

我正在翻译来自 C 的代码，我希望它尽可能接近原始代码。 C 程序将 PushArray 和 PushStruct 声明为宏。由于Delphi没有宏支持，我正在尝试将它们变成函数。

我用谷歌搜索了一下，似乎我可以使用泛型类型。 与function PushStruct<T>(Arena : Pmemory_arena; dtype : <T>) 类似，但您只能在 OOP 类型的应用程序中使用它。

function PushSize_(Arena : Pmemory_arena; Size : memory_index) : pointer;
begin
    Assert((Arena^.Used + Size) <= Arena^.Size);
    Result := Arena^.Base + Arena^.Used;
    Arena^.Used := Arena^.Used + Size;
end;

function PushStruct(Arena : Pmemory_arena; dtype : ?) : pointer;
begin 
    result := PushSize_(Arena, sizeof(dtype));
end;

function PushArray(Arena : Pmemory_arena; Count: uint32; dtype : ?) : pointer;
begin
    result := PushSize_(Arena, (Count)*sizeof(dtype))
end;

这里是原始的 C 代码：

#define PushStruct(Arena, type) (type *)PushSize_(Arena, sizeof(type))
#define PushArray(Arena, Count, type) (type *)PushSize_(Arena, (Count)*sizeof(type))
void *
PushSize_(memory_arena *Arena, memory_index Size)
{
    Assert((Arena->Used + Size) <= Arena->Size);
    void *Result = Arena->Base + Arena->Used;
    Arena->Used += Size;

    return(Result);
}

Answer 1

C 代码没有将类型传递给函数。预处理器正在扩展宏并计算大小。从函数的原型可以看出：

void *PushSize_(memory_arena *Arena, memory_index Size)

由于您在 Delphi 中没有宏，因此您无法安排直接翻译。就个人而言，如果是我，我不会尝试完全匹配 C 代码。我会传递大小并将其留给调用者使用SizeOf。我不认为这是一个可怕的负担。它仍然给你留下了一些非常接近直译的东西——你所缺少的只是方便的宏。

如果你想使用泛型，你可以这样做，但这需要你使用静态方法。例如：

type
  TMyClass = class
    class function PushSize(Arena: Pmemory_arena; Size: memory_index): Pointer; static;
    class function PushStruct<T>(Arena: Pmemory_arena): Pointer; static;
  end;
....
class function TMyClass.PushSize(Arena: Pmemory_arena; Size: memory_index): Pointer;
begin
  Result := ....;
end;

class function TMyClass.PushStruct<T>(Arena: Pmemory_arena): Pointer;
begin
  Result := PushSize(Arena, SizeOf(T));
end;

如果你想返回一个看起来像这样的类型化指针：

type
  TMyClass<T> = class
    type P = ^ T;
    class function PushSize(Arena: Pmemory_arena; Size: memory_index): Pointer; static;
    class function PushStruct(Arena: Pmemory_arena): P; static;
  end;
....
class function TMyClass<T>.PushSize(Arena: Pmemory_arena; Size: memory_index): Pointer;
begin
  Result := ....;
end;

class function TMyClass<T>.PushStruct(Arena: Pmemory_arena): P;
begin
  Result := PushSize(Arena, SizeOf(T));
end;

显然你会知道用什么名字代替TMyClass！

我不相信泛型在这里很合适，因为我猜你想要尽可能直译。在这种情况下我不会选择使用泛型。

Answer 2

您可以通过简单地根据需要为每种记录类型声明自己的 Push* 函数来“扩展宏”：

type
  // just guessing here...
  PMemoryArena = ^TMemoryArena;
  TMemoryArena = record
    Base: Pointer;
    Used: Cardinal;
    Size: Cardinal;
  end;
  TMemoryIndex = Cardinal;
  // 1st example record type
  PMyRecord1 = ^TMyRecord1;
  TMyRecord1 = record
    I1: Integer;
    I2: Integer;
  end;
  // 2nd example record type
  PMyRecord2 = ^TMyRecord2;
  TMyRecord2 = record
    D1: Double;
    D2: Double;
  end;

function PushSize_(Arena: PMemoryArena; Size: TMemoryIndex): Pointer; inline;
begin
  Assert(Arena^.Used + Size <= Arena^.Size);
  Result := Pointer(NativeUInt(Arena^.Base) + Arena^.Used);
  Inc(Arena^.Used, Size);
end;

function PushMyRecord1(Arena: PMemoryArena): PMyRecord1;
begin
  Result := PMyRecord1(PushSize_(Arena, SizeOf(TMyRecord1)));
end;

function PushMyRecord2(Arena: PMemoryArena): PMyRecord2;
begin
  Result := PMyRecord2(PushSize_(Arena, SizeOf(TMyRecord2)));
end;

Answer 3

这似乎有点不必要。

为什么不，例如

function PushStruct(Arena : Pmemory_arena) : pointer;
begin 
    result := PushSize_(Arena, sizeof( Arena ));
end;