如何将字符串从一个 vba 表单传递到另一个

Question

我正在尝试将字符串值从一种形式传递到另一种形式。我的第一个表单是“frmLogin”，其中包含用户 ID“strId”和密码“strPassword”（它只是一个常规登录表单）。我试图打开并将字符串传递给的表单是“frmProfile1”。从 frmProfile1，Profile1 用户将文档分配给在 Access 中存储为记录的 Profile2 用户。这些记录将包含分配文档的 Profile1 用户的 ID，因此将 strId 的值从 frmLogin 传递到 frmProfile1 非常重要。

'Project: 
'Form: Login Form (frmLogin)
'Author: Nathan Willett
'Created: 9/10/19
'Current Version: 1.0 - 9/10/19

Option Compare Database
Option Explicit

Public strProfile, strId, strPassword As String

'On 'Button Ok' click, perform the following
Public Sub btnLogin_Click()

    'If ID Login Box is left blank, display "Please enter Login ID"
    If IsNull(Me.txtId) Then
        MsgBox "Please enter Login ID", vbInformation, "Login Error"
        Me.txtId.SetFocus
        Exit Sub
    'If Password Box is left blank, display "Please enter Password"
    ElseIf IsNull(Me.txtPassword) Then
        MsgBox "Please enter Password", vbInformation, "Login Error"
        Me.txtPassword.SetFocus
        Exit Sub
    End If

    Dim rs As Recordset
    Set rs = CurrentDb.OpenRecordset("tblUserList", dbOpenSnapshot, dbReadOnly)
    rs.FindFirst "fldId='" & Me.txtId & "'"

    'If txtID value does not equal fldId, prompt the user
    If rs.NoMatch = True Then
        MsgBox "Incorrect Login ID. Please try again.", vbInformation, "Login Error"
        Me.txtId.SetFocus
        Exit Sub
    End If

    'If txtPassword value does not equal fldPassword, prompt the user
    If rs!fldPassword <> Me.txtPassword Then
        MsgBox "Incorrect Password. Please try again.", vbInformation, "Login Error"
        Me.txtId.SetFocus
        Exit Sub
    End If

    'Look up the users profile version from tblUserList
    strProfile = DLookup("fldPosId", "tblUserList", "fldId='" & Me.txtId.Value & "'")
    strId = rs!fldId
    strPassword = rs!fldPassword

    'Open the corresponding profile form
    Select Case strProfile
        Case "Profile1"
            DoCmd.OpenForm "frmProfile1"
        Case "Profile2"
            DoCmd.OpenForm "frmProfile2"
        Case "Profile3"
            DoCmd.OpenForm "frmProfile3"
        Case "Profile5"
            DoCmd.OpenForm "frmProfile4"
    End Select
    DoCmd.Close acForm, "frmLogin"
End Sub
'On 'Button Cancel' click, close the program
Private Sub btnCancel_Click()
    DoCmd.Close acForm, "frmLogin"
End Sub

'Project:
'Form: frmProfile1
'Author: Nathan Willett
'Created: 9/21/19
'Current Version: 1.0 9/21/19

Option Compare Database
Option Explicit

Dim db As Database
Dim rs As Recordset

Private Sub Form_Open(Cancel As Integer)
    Text468.Text = frmLogin!strId
End Sub

Answer 1

通常，要引用表单上的控件，您会：

 forms!yourFormName.ControlName.Value

或参考子窗体上的控件：

forms!yourFormName.yourSubFormName.Form.ControlName.Value

要打开一个表单并在其上设置一个值，您可以：

DoCmd.OpenForm "yourFormName"
Forms!YourFormName.ControlName.Value = Forms!FormOpeningOtherFormName.Control.Value

这有帮助吗？

对于您的场景，您实际上需要这样做：

Select Case strProfile
    Case "Profile1"
        DoCmd.OpenForm "frmProfile1"
        Forms!frmProfile1.Text468.Text = strId
    Case "frmProfile2"
        DoCmd.OpenForm "frmProfile2"
        Forms!frmProfile2.Text468.Text = strId
    Case "Profile3"
        DoCmd.OpenForm "frmProfile3"
        Forms!frmProfile3.Text468.Text = strId
    Case "Profile4"
        DoCmd.OpenForm "frmProfile4"
        Forms!frmProfile4.Text468.Text = strId
End Select