在 Perl 中通过引用仅传递一些子例程参数

Question

我正在编写一个带有多个参数的子例程。这些参数中的大多数都是标准的按值传递排序，在子例程中对它们所做的更改在子例程之外无关紧要。但是其中一个是一个对象（祝福引用），如果它被传入，我想对其进行更改，它在子例程之外可用。如果它没有传入，我想实例化它并同样对待它就好像它被传入（但最终返回）一样。

例如：

---

my $foo = Private::Foo->new();

# $foo->{'something'} eq 'old value'

Private::Foo->do_things('abc', 'xyz', $foo);

# $foo->{'something'} eq 'new value'

my $foo2 = Private::Foo->do_things('def');

# $foo2->{'something'} eq 'old value'

---

package Private::Foo;

# ...

sub do_things {
    my ($self, $arg1, $arg2, $foo) = @_;

    unless (defined $foo) {
         $foo = Private::Foo->new();
    }

    if ($arg1 eq 'abc') {
        $foo->{'something'} = 'new value';

        return;
    }

    return $foo;
}

---

我希望使用尽可能简洁的语法来执行此操作，并且可以使用 Perl v5.22 及更高版本中提供的任何功能。 （我试图弄清楚如何使用refaliasing 做到这一点，但它不是很干净。）

我错过了什么？

Answer 1

首先，子程序参数总是通过引用传递。

$ perl -e'sub f { $_[0] = "def"; }   my $x = "abc"; f($x); CORE::say $x;'
def

更重要的是，您的代码完全符合您的要求。

$ perl -e'
    {
        package Private::Foo;

        sub new { my $class = shift; bless({ something => "old_value" }, $class) }

        sub do_things {
            my ($self, $arg1, $arg2, $foo) = @_;

            unless (defined $foo) {
                 $foo = Private::Foo->new();
            }

            if ($arg1 eq "abc") {
                $foo->{something} = "new value";
                return;
            }

            return $foo;
        }
    }

    use feature qw( say );

    my $foo = Private::Foo->new();
    Private::Foo->do_things("abc", "xyz", $foo);
    say $foo->{something};

    my $foo2 = Private::Foo->do_things("def");
    say $foo2->{something};
'
new value
old_value

也就是说，你可以清理一下你的方法：

sub do_things {
    my ($class, $arg1, $arg2, $foo) = @_;

    $foo //= $class->new();

    if ($arg1 eq 'abc') {
        $foo->{something} = 'new value';
    }

    return $foo;
}

如果你清理你的调用约定会更好。

Private::Foo->do_something($arg1, $arg2, $foo);

my $foo2 = Private::Foo->do_something($arg1, $arg2);

意义远不如

$foo->do_something($arg1, $arg2);

( my $foo2 = Private::Foo->new )->do_something($arg1, $arg2);