PLS-00306：调用“OUTPUT_ARRAY”时参数的数量或类型错误

Question

我被这个错误困住了，真的不知道如何解决它。也许我以不正确的方式传递数组？

这是主 sql 文件。

DECLARE
  v_array_length NUMBER := &v_array_length;
BEGIN
  DECLARE
    TYPE number_array_type IS TABLE OF NUMBER(6, 2) INDEX BY BINARY_INTEGER;
    v_array NUMBER_ARRAY_TYPE;
  BEGIN
    --Isvediams
    IOPACKAGE.OUTPUT_MESSAGE('Original array:');
    --Sugeneruoja atsitiktinius array elementus is intervalo [1, 1000]
    FOR i IN 1..v_array_length LOOP
            v_array(i) := SYS.DBMS_RANDOM.VALUE(1, 1000);
          END LOOP;
    IOPACKAGE.OUTPUT_ARRAY(v_array);
  END;
END;

这是IOpackage sql文件

CREATE OR REPLACE PACKAGE IOpackage IS
  l_message VARCHAR2(100);
  PROCEDURE output_message(l_message IN VARCHAR2);
  TYPE number_array_type IS TABLE OF NUMBER(6, 2) INDEX BY BINARY_INTEGER;
  PROCEDURE output_array(v_array NUMBER_ARRAY_TYPE);
END IOpackage;

这是 IOpackage_body 文件。

CREATE OR REPLACE PACKAGE BODY IOpackage IS
  PROCEDURE output_message(l_message IN VARCHAR2) IS
  BEGIN
    DBMS_OUTPUT.PUT_LINE(l_message);
  END output_message;
  PROCEDURE output_array(v_array IN NUMBER_ARRAY_TYPE) IS
  BEGIN
    FOR i IN 1..v_array.COUNT LOOP
              DBMS_OUTPUT.PUT(v_array(i) || ' ');
            END LOOP;
    DBMS_OUTPUT.PUT_LINE('');
  END output_array;
END IOpackage;

Answer 1

主 sql 文件 中的类型定义不是包子例程所期望的类型。 IOPACKAGE.OUTPUT_ARRAY-subroutine 需要类型 IOPACKAGE.NUMBER_ARRAY_TYPE。您不必重新定义类型。以下应该有效：

declare
  v_array IOPACKAGE.NUMBER_ARRAY_TYPE;
begin
  IOPACKAGE.OUTPUT_ARRAY(v_array);
end;

查看IOPACKAGE.NUMBER_ARRAY_TYPE 和NUMBER_ARRAY_TYPE 之间的区别。它们相似但不相同。