生成明显不一致的合金实例

Question

我正在为 Java 的一个子集做一个合金元模型。

下面我们有一些签名：

abstract sig Id {}
sig Package{}
sig ClassId, MethodId,FieldId extends Id {}
abstract sig Accessibility {}
one sig public, private_, protected extends Accessibility {}
abstract sig Type {}
abstract sig PrimitiveType extends Type {}
one sig Int_, Long_ extends PrimitiveType {}

sig Class extends Type {
    package: one Package,
    id: one ClassId,
    extend: lone Class,
    methods: set Method,
    fields: set Field
}
sig Field {
    id : one FieldId,
    type: one Type,
    acc : lone Accessibility
}
sig Method {
    id : one MethodId,
    param: lone Type,
    acc: lone Accessibility,
    return: one Type,
    b: one Body
}
abstract sig Body {}
sig LiteralValue extends Body {} // returns a random value
abstract sig Qualifier {}
one sig this_, super_ extends Qualifier {}
sig MethodInvocation extends Body {
    id_methodInvoked : one Method, 
    q: lone Qualifier
}
//        return new A().k();
sig ConstructorMethodInvocation extends Body {
    id_Class : one Class, 
    cmethodInvoked: one Method
}{
    (this.@cmethodInvoked in (this.@id_Class).methods) || (this.@cmethodInvoked in ((this.@id_Class).^extend).methods && (this.@cmethodInvoked).acc != private_)
}
//        return x;
//        return this.x;
//        return super.x;
sig FieldInvocation extends Body {
    id_fieldInvoked : one Field, 
    qField: lone Qualifier
}
//        return new A().x;
sig ConstructorFieldInvocation extends Body {
    id_cf : one Class, 
    cfieldInvoked: one Field
}{
    (this.@cfieldInvoked in (this.@id_cf).fields) || ( this.@cfieldInvoked in ((this.@id_cf).^extend).fields && (this.@cfieldInvoked).acc != private_)
}

在 Java 语言中，如果该方法不是私有方法，我们只能调用类内部的方法（通过该类的实例化）。我试图通过以下签名在我的合金模型中表示此限制：

sig ConstructorMethodInvocation extends Body {

    id_Class : one Class, 
    cmethodInvoked: one Method
}{
    (this.@cmethodInvoked in (this.@id_Class).methods || this.@cmethodInvoked in ((this.@id_Class).^extend).methods && (this.@cmethodInvoked).acc != private_)

因此，alloy 中的 ConstructorMethodInvocation 签名试图表示 java 中的构造，例如 new A().x()。另外，方法 x() 只能在它不是类 A 的私有方法时才能被调用。所以，为了避免调用类 id_Class 的私有方法，我设置了以下限制（在 ConstructorMethodInvocation 签名中）：

(this.@cmethodInvoked in (this.@id_Class).methods || this.@cmethodInvoked in ((this.@id_Class).^extend).methods && (this.@cmethodInvoked).acc != private_)

但是，尽管有此限制，求解器仍坚持生成实例（用于 ConstructorMethodInvocation），其中 cmethodInvoked 是 id_Class 的私有方法。 ConstructorFieldInvocation 也是如此。

有人看到我做错了吗？

Answer 1

这是因为您在ConstructorMethodInvocation sig 的附加事实中放错了括号：现在的方式是，您有一个顶级析取，它允许（cmethodInvoked 在id_Class.methods 中）或（它是在id_Class.^extend.methods 而不是私人的）。如果您将附加的事实块更改为

{
   this.@cmethodInvoked in this.@id_Class.*extend.methods 
   this.@cmethodInvoked.acc != private_
}

您将获得预期的行为（星号运算符 (*) 是反射传递闭包，它的含义基本上与您打算编写的原始析取相同；您仍然可以使用旧约束并修复括号）。

为了检查不存在任何 ConstructorMethodInvocation 方法是私有的实例，我执行了

check {
  no c: ConstructorMethodInvocation {
    c.cmethodInvoked.acc = private_
  }
}

没有找到反例。