未找到 CMAKE 交叉编译库

Question

我的 cmake 交叉编译器项目出现奇怪的问题。

找到了我自己的库，但没有找到我工具链中的（系统）库。

以前我在 debian 挤压机上使用 KDevelop。 现在在我的带有 debian wheezy 的新机器上配置失败。 它找不到像m 或pthread 这样的系统库。

在我的旧机器上，以下工作完美无缺，但我不记得我做了什么特别的事情来完成这项工作。

这是我的CMakeLists.txt 文件之一

cmake_minimum_required(VERSION 2.8)
SET(CMAKE_SYSTEM_NAME Linux)
SET(CMAKE_SYSTEM_VERSION 2.6.36.4)
SET(CMAKE_C_COMPILER arm-angstrom-linux-gnueabi-gcc)
SET(CMAKE_CXX_COMPILER arm-angstrom-linux-gnueabi-g++)
include_directories(../include
  ../../../sample/include)

project(testmain)

add_executable(testmain
   some_c-source-file.c)

set(CMAKE_LIBRARY_PATH ../lib/arm-26/lib
  ../../../sample/lib/arm-26/lib)
find_library(LIBS_TEST NAMES akku)
find_library(LIBS_M NAMES m)
find_library(LIBS_PTHREAD NAMES pthread )
target_link_libraries(akkumain
  ${LIBS_TEST}
  ${LIBS_M}
  ${LIBS_PTHREAD})

set(CMAKE_C_FLAGS "-Wall -Werror")
set(CMAKE_C_FLAGS_DEBUG "-g3 -O2 -rdynamic")
set(CMAKE_C_FLAGS_RELEASE "-g0 -O0")
set(CMAKE_CXX_FLAGS "-Wall -Werror")
set(CMAKE_CXX_FLAGS_DEBUG "-g3 -O2 -rdynamic")
set(CMAKE_CXX_FLAGS_RELEASE "-g0 -O0")

这是尝试使用 KDevelop 编译时显示的消息：（重复一遍：这是在我的旧机器上运行的）

/home/user/testmain/build> /usr/bin/cmake -DCMAKE_BUILD_TYPE=Debug /home/user/testmain/
-- The C compiler identification is GNU 4.3.3
-- The CXX compiler identification is GNU 4.3.3
-- Check for working C compiler: /usr/local/angstrom/arm/bin/arm-angstrom-linux-gnueabi-gcc
-- Check for working C compiler: /usr/local/angstrom/arm/bin/arm-angstrom-linux-gnueabi-gcc -- works
-- Detecting C compiler ABI info
-- Detecting C compiler ABI info - done
-- Check for working CXX compiler: /usr/local/angstrom/arm/bin/arm-angstrom-linux-gnueabi-g++
-- Check for working CXX compiler: /usr/local/angstrom/arm/bin/arm-angstrom-linux-gnueabi-g++ -- works
-- Detecting CXX compiler ABI info
-- Detecting CXX compiler ABI info - done

CMake Error: The following variables are used in this project, but they are set to NOTFOUND.
Please set them or make sure they are set and tested correctly in the CMake files:
LIBS_M
    linked by target "akkumain" in directory /home/user/testmain
LIBS_PTHREAD
    linked by target "akkumain" in directory /home/user/testmain

所以找到了 LIBS_TEST。但不是libm 或libpthread。 我对不同的项目进行了尝试：找到了我的所有库，但没有找到“系统”库。

我已经尝试过不同的东西，比如

set(CMAKE_FIND_LIBRARY_PREFIXES lib )
set(CMAKE_FIND_LIBRARY_SUFFIXES .a )

还有一些我不记得的事情。

唯一有效的是当我手动指定目录时：

find_library(ASTLIBS_M NAMES m PATHS /usr/local/angstrom/arm/arm-angstrom-linux-gnueabi/usr/lib)

在向我的CMakeLists.txt 指定后，找到了库，我可以编译我的项目而不会出现任何错误。

但是：这不是我想要的，因为我有 LOT 的项目和许多库，我不想编辑我所有的 CMakeLists.txt... :(

有没有人知道是什么让我的旧机器找到了系统库而没有在我的 IDE/CMake 文件中指定任何特殊内容？

编辑： 我刚刚注意到我的一个可执行文件在 Linker 阶段抛出了一些错误，它无法从 glibc 中找到一些符号 - 似乎我的 debian wheezy 系统有更多问题。 - 我希望我能弄清楚...

编辑：

也许我应该做一个简短的总结：我的代码编译得很好，但是我的工具链中的所有库都没有找到，但是如果我手动将路径添加到我的工具链的库中，它会编译但在链接器阶段失败。

Answer 1

您是否尝试过使用工具链文件？我还交叉编译到 ARM 和 AVR 一个 LOT，它工作得很好，没有麻烦（我也使用 KDevelop，它与 CMake 一起工作得很好）。要点是通过 CMAKE_FIND_ROOT_PATH 变量指定工具链根文件系统的路径。尝试将所有这些放在一个文件中，我通常以我要交叉编译的架构命名（在这种情况下，我将其命名为 arm-unknown-linux-gnueabi.cmake）：

# the name of the target operating system
SET(CMAKE_SYSTEM_NAME Linux)

# which C and C++ compiler to use
SET(CMAKE_C_COMPILER   arm-unknown-linux-gnueabi-gcc)
SET(CMAKE_CXX_COMPILER arm-unknown-linux-gnueabi-g++) 

# here is the target environment located
SET(CMAKE_FIND_ROOT_PATH  /home/claudio/TS-7400/rootfs) 

# adjust the default behaviour of the FIND_XXX() commands:
# search headers and libraries in the target environment, search 
# programs in the host environment
set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY BOTH)
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE BOTH)

注意变量 CMAKE_FIND_ROOT_PATH_MODE_xxx 变量控制CMake 将在何处查找二进制文件、库和头文件。我通常将 PROGRAM 设置为NEVER，因此它从不使用跨架构根文件系统中的二进制文件，因为它们无论如何都不会在您的主机上运行。对于库和头文件BOTH 意味着它将首先搜索您指定的ROOT_PATH，然后如果找不到，它将通过您的主机系统目录。

这样，当你想要交叉编译一个项目时，你所要做的就是创建一个构建目录（这样它就不会将你的源代码与构建过程中创建的文件混合在一起），然后运行 ​​cmake 从那里指定您要使用的工具链文件（我假设您的 CMakeLists.txt 与您的工具链文件一起位于您的源所在的同一目录 - project_sources_dir 在我的示例中）：

cd project_sources_dir
mkdir build
cd build
cmake -DCMAKE_TOOLCHAIN_FILE=../arm-unknown-linux-gnueabi.cmake ..

使用工具链文件的全部意义在于，如果您想为您的主机编译完全相同的项目，您不必更改CMakeLists.txt 中的任何一行。只需运行 cmake 而不指定工具链文件：

cd project_sources_dir
mkdir build
cd build
cmake ..

并且您的项目已准备好为您的主机编译本机。如果这还不够，您可以在CMake Cross Compiling 上查看更多详细信息

Answer 2

CMake 的 find_library 模块搜索某些默认路径。如果您的旧机器上的系统库恰好位于一个这样的位置，则无需任何额外工作即可找到它们。

但是，由于您的新机器到这些库的路径似乎是“/usr/local/angstrom/arm/arm-angstrom-linux-gnueabi/usr/lib”，因此您需要将此告知 CMake。

一种方式，如您所展示的（显式添加路径）。但在这种情况下，路径可能特定于那台机器 - 所以你最好只在那台机器上调用 CMake 时设置该路径。您可以将其添加到CMAKE_PREFIX_PATH，例如：

cmake . -DCMAKE_PREFIX_PATH=/usr/local/angstrom/arm/arm-angstrom-linux-gnueabi/usr

（注意：这种情况下的路径在调用find_library 时会附加“lib”）。

或者，如果您只想影响find_library 搜索路径，而不是所有 find_xxx 模块，请设置CMAKE_LIBRARY_PATH

cmake . -DCMAKE_LIBRARY_PATH=/usr/local/angstrom/arm/arm-angstrom-linux-gnueabi/usr/lib