找不到参数的方法 cppFlags() arguments()

Question

我正在尝试使用

std::function

但是编译器会报错

Error:(50, 10) error: no type named 'function' in namespace 'std'

我已尝试修改 build.gradle 文件

externalNativeBuild {
    ndkBuild {
        path "src/main/jni/Android.mk"
    }
    cmake {
        cppFlags "-std=c++11"
        arguments "-DANDROID_STL=gnustl_static"
        path 'src/main/jni/CMakeLists.txt'
    }
}

但它不接受path以外的参数并抛出以下错误

Error:(28, 0) Could not find method arguments() for arguments [-DANDROID_STL=gnustl_static] on object of type com.android.build.gradle.internal.dsl.CmakeOptions.

请帮助我能够使用

std::function

更新

感谢 @Alex Cohn 我能够配置标志和参数，现在我的文件看起来像这样

apply plugin: 'com.android.library'

android {
    compileSdkVersion 25
    buildToolsVersion '26.0.2'

    defaultConfig {
        minSdkVersion 15
        targetSdkVersion 25
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
        externalNativeBuild {
            cmake {
                cppFlags "-std=c++11"
                arguments "-DANDROID_STL=gnustl_static"
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    externalNativeBuild {
        /*   ndkBuild {
               path "src/main/jni/Android.mk"
           }*/
        cmake {
            // cppFlags "-std=c++11"
            //arguments "-DANDROID_STL=gnustl_static"
            path 'src/main/jni/CMakeLists.txt'
        }
    }
}

dependencies {
    compile 'com.android.support:support-annotations:25.0.1'
}

Answer 1

build.gradle 中有两个完全不同的块，名为 externalNativeBuild（感谢 Google）。

One 在 android 顶级块下，它指定了原生构建脚本的路径，cmake 或 ndkBuild（但不是两者都有）。

other 可用于从 gradle 指定本机构建的一些参数。此块通常是 defaultConfig 块的子块，但也可以为 flavors 出现（参见 example）。

这些 externalNativeBuild 块也可以有 cmake 或 ndkBuild 子级，但只有与 path 匹配的子级设置（见上文）是相关的，另一个被忽略。

最后，将你的块分成两部分，并将每一块放在 build.gradle 层次结构中的正确位置。