如何将日期附加到 xcopy 中的目录路径答案

【问题标题】：How to append date to directory path in xcopy如何将日期附加到 xcopy 中的目录路径
【发布时间】：2013-06-08 00:48:10
【问题描述】：

我在 bat 文件中有一个 xcopy 语句.. 你能帮我把今天的日期附加到目的地的目录之一吗 xcopy /S /E /I %sourceFolder% "C:\Shared\copy\%destinationFolder%"

今天的日期是 06072013，所以我希望我的目的地如下所示

C:\Shared\copy-today's date........

谢谢

【问题讨论】：

标签： windows batch-file xcopy

【解决方案1】：

这是获取不依赖于区域设置的日期戳的方法。 Wmic 在 Windows XP Pro 及更高版本中可用。

@echo off
for /f "delims=" %%a in ('wmic OS Get localdatetime  ^| find "."') do set dt=%%a
set datestamp=%dt:~0,8%
set timestamp=%dt:~8,6%
set YYYY=%dt:~0,4%
set MM=%dt:~4,2%
set DD=%dt:~6,2%
set HH=%dt:~8,2%
set Min=%dt:~10,2%
set Sec=%dt:~12,2%

set stamp=%YYYY%-%MM%-%DD%

md "C:\Shared\copy-%stamp%"
xcopy here...

【讨论】：

【解决方案2】：

xcopy /S /E /I %sourceFolder% "C:\Shared\copy-%date:/=%\%destinationFolder%"

【讨论】：

【解决方案3】：

只需在您的命令中使用%date%：

xcopy /S /E /I %sourceFolder% "C:\Shared\copy\copy-%date%"

注意：这将使日期保持原始格式。

假设您的本地日期格式是Fri 06/07/2013，您可以通过像这样切割字符串将其格式化为06072013：

%date:~4,2%%date:~7,2%%date:~10,4%

所以最后的命令是：

xcopy /S /E /I %sourceFolder% "C:\Shared\copy\copy-%date:~4,2%%date:~7,2%%date:~10,4%"

【讨论】：

喜欢这个答案的简单性和单线性。

【解决方案4】：

这样的……

for /f "tokens=2-4 delims=/ " %%A in ('echo.%Date%') do set Dest=C:\Shared\copy-%%A%%B%%C
xcopy /S /E /I "%sourceFolder%" "%Dest%"

【讨论】：