如何通过批处理启动 .wzmul 文件答案

【问题标题】：How to launch a .wzmul file through batch如何通过批处理启动 .wzmul 文件
【发布时间】：2017-03-16 14:41:31
【问题描述】：

我有一个在用户计算机上安装 WinZip 的脚本，但是，我需要将 .wzmul 文件移动到正确的位置，我已经成功完成了所有这些，但是当我尝试使用 @987654323 启动文件时@ 命令它只会启动另一个 cmd。

@echo off

set winzip_path=\\mgtutils01\windows7apps\WinZip\WinZip15
set exec_name=winzip150.msi
set reg_name=WinZip.wzmul
set reg_path="C:\Program Files (x86)\WinZip"

pushd %winzip_path%

xcopy "%winzip_path%\%exec_name%" "%USERPROFILE%\Desktop"
msiexec /i "%USERPROFILE%\Desktop\%exec_name%" /QN /L*V "%USERPROFILE%\AppData\Local\winzip_log.txt"
@echo "DONE!!"
xcopy "%winzip_path%\%reg_name%" %reg_path%
start /wait %reg_path%\%reg_name%

如何正确打开此类文件？

【问题讨论】：

你不运行它。您只需将其复制到安装路径即可。
这是我们的手动安装说明：copy to desktop the \\mgtutils01\Windows7Apps\WinZip15 folder run winzip150.msi to install the application Uncheck Open application copy winzip.wzmul C:\Program Files\WinZip folder Go to C:\Program Files\WinZip folder and double click winzip.wzmul Click Yes to register
我从来没有这样做过。第一个 Winzip 启动后会自行注册。
请edit您的问题并添加安装说明并将其格式化为可读形式（如您所见，无法正确格式化cmets）

标签： windows batch-file windows-7

【解决方案1】：

根据我的经验，当您第一次启动 Winzip 时，如果程序目录中存在多许可证，该程序将进行注册。但本质上，由于您引用路径的方式，您的批处理文件存在一些问题。最佳实践是不要在变量中分配引号，而是使用引号来保护变量中的空格和特殊字符。基本上 START 命令将引号视为窗口标题。因此，对批处理文件的这些更改应该可以工作。您还使用 PUSHD 到 Winzip 路径，因此您无需在代码中指定 Winzip 路径。它已经是工作目录了。

@echo off

set "winzip_path=\\mgtutils01\windows7apps\WinZip\WinZip15"
set "exec_name=winzip150.msi"
set "reg_name=WinZip.wzmul"
set "reg_path=C:\Program Files (x86)\WinZip"

pushd "%winzip_path%"

xcopy "%exec_name%" "%USERPROFILE%\Desktop\"
msiexec /i "%USERPROFILE%\Desktop\%exec_name%" /QN /L*V "%USERPROFILE%\AppData\Local\winzip_log.txt"
@echo "DONE!!"
xcopy "%reg_name%" "%reg_path%\"
start "" /wait "%reg_path%\%reg_name%"

POPD

【讨论】：