有没有办法在一次检查中减少耗时？

Question

我有这个批处理代码，它工作得很好，但是： 每行需要大约 60 秒来执行，我想知道，如果我能更快地做到这一点......

还有 if 语句。我想检查是否每个窗口都关闭了，如果是，我想执行一些操作。但是如果至少有一个窗口仍然打开，那么它应该再次检查它。

:loop
for /f %%i in ('tasklist /v /fi "WINDOWTITLE eq %server1%" /FO Table') do set #1=%%i
for /f %%i in ('tasklist /v /fi "WINDOWTITLE eq %server2%" /FO Table') do set #2=%%i
for /f %%i in ('tasklist /v /fi "WINDOWTITLE eq %server3%" /FO Table') do set #3=%%i
for /f %%i in ('tasklist /v /fi "WINDOWTITLE eq %server4%" /FO Table') do set #4=%%i
for /f %%i in ('tasklist /v /fi "WINDOWTITLE eq %server5%" /FO Table') do set #5=%%i
for /f %%i in ('tasklist /v /fi "WINDOWTITLE eq %server6%" /FO Table') do set #6=%%i
if not %#1%==cmd.exe (
    if not %#2%==cmd.exe (
        if not %#3%==cmd.exe (
            if not %#4%==cmd.exe (
                if not %#5%==cmd.exe (
                    if not %#6%==cmd.exe (
                        goto backup
                    )
                )
            )
        )
    )
) else (
    echo back to loop
    goto openWindow
)

Answer 1

让我提出一个稍微不同的方法。除了所有那些 if 语句之外，您只需在其中一项任务存在时循环即可：

:wait
timeout 1 >nul
for %%a in (%server1% %server2% %server3% %server4% %server5% %server6%) do (
  tasklist /nh /fi "windowtitle eq %%a" |find "  " >nul && goto :wait
)
echo all closed.

或

setlocal enabledelayedexpansion
:wait
timeout 1 >nul
for /l %%a in (1,1,6) do (
  tasklist /nh /fi "windowtitle eq !server%%a!" |find "  " >nul && goto :wait
)
echo all closed.

注意：find " " 查找两个连续的空格，而不是 TAB）

如果您明智地选择窗口标题，您甚至不需要for 循环：

:wait
timeout 1 >nul
tasklist /nh /fi "windowtitle eq MySubWindow*" |find "  " >nul && goto :wait
echo all closed.

窗口标题都以固定字符串开头（此处为MySubWindow），如MySubWindow-1、MySubWindow-2 等（是的，tasklist 可以使用通配符 - 但只能在细绳）。这基本上是“如果存在标题以 MySubWindow 开头的任何窗口，则循环”

Answer 2

Stephan 回答的小优化。

这执行得更快。

:wait
timeout 1 >nul
for %%a in (%server1% %server2% %server3% %server4% %server5% %server6%) do (
  if not defined v%%a tasklist /nh /fi "windowtitle eq %%a" |find "  " >nul && goto :wait
  set v%%a=done
)
echo all closed.

---

Answer 3

您还没有解释您的 6 个批处理文件是如何“打开”的，但是如果它们是通过 START 命令打开的，那么还有一种更简单的方法可以做到这一点：

(
    start call batch1.bat
    start call batch2.bat
    start call batch3.bat
    start call batch4.bat
    start call batch5.bat
    start call batch6.bat
) | pause

echo All 6 Batch files are closed

前面的代码并行运行 6 个 Batch 文件，然后控制流在 pause 命令处停止。当所有 6 个 Batch 文件都终止时，此程序继续。

请注意，没有任何批处理代码检查进程是否结束；这是由操作系统自动完成的。这样，这个程序的等待状态就不会浪费任何CPU时间。更多解释见this answer

Answer 4

如果无法对此进行测试，也许每个循环只运行一个tasklist 命令会更快：

@Echo Off
SetLocal EnableExtensions

:Loop
For /F Tokens^=17^ Delims^=^" %%G In (
    '%SystemRoot%\System32\tasklist.exe /Fi "ImageName Eq cmd.exe" /Fo CSV /NH /V 2^>NUL'
) Do Set /P "=%%G" 0<NUL | %SystemRoot%\System32\findstr.exe /I ^
 "\<%server1%\> \<%server2%\> \<%server3%\> \<%server4%\> \<%server5%\> \<%server6%\>" 1>NUL && GoTo Loop

:Backup

findstr.exe 选项可能需要根据这些变量的内容进行调整。