HelloWorld：使用 CMake 下载、构建和链接 Boost

Question

我有一个 Hello, World 风格的小程序，我想使用 CMake 以端到端的方式进行更多工作。在这种情况下，这意味着我可以下载 Boost 库，编译它们，最后编译我的小 Hello, World 并将 Boost 库链接到它。

目录布局目前看起来像这样

cmaketest |- build //我希望这里有 CMake 生成的 IDE 文件。 |- 源 |- 主.cpp |- 你好.cpp |- 你好.hpp |- 依赖 //我想在这里有内置的 Boost 库和头文件。 |- downloads //这包含下载的 zip 文件。 |- temp //临时文件。

我有以下 CMakeLists.txt，目前我生成 Visual Studio 2015 项目文件，如下所示：cmake build -G "Visual Studio 14 2015 Win64"。一切都好，我将开始解决方案，CMake 抱怨它找不到 Boost，去下载它开始构建（在下面的代码中，我设置为获取以前获取的文件）。但是建了一段时间后，问题就出现了……

1. Boost 文件似乎以根目录出现在\cmaketest\CMakeFiles\build\Boost-prefix\src\Boost 中。我如何才能将它们构建为\depends\boost（或达到此效果）以及如何包含要链接到解决方案的库？这个链接是我遇到的另一个问题，我知道如何包含这个奇怪目录中的标题，但这并不是我真正想要的。
2. 看起来 VS IDE 首先警告找不到 Boost 标头（请参阅主程序），然后开始 Boost 构建。这可以避免吗？
3. 如何让Boost库从VS解决方案中消失？ IE。不做一个项目，而只是依赖于头文件和库？
4. 如果 Boost 包已经在磁盘上，是否有内置方法可以避免下载它？看起来它无论如何都会被检索到，我考虑过检查文件是否存在。

main.cpp（我想这是本例中的相关文件）

//The Boost headers are included just to check the linker.
#include "hello.hpp"
#include <boost/date_time/posix_time/posix_time.hpp>
#include <boost/date_time/posix_time/posix_time_io.hpp>
#include <iostream>
using std::cout;
using std::endl;

int main()
{
    hello helloer;
    cout << helloer.greet("World here") << endl;

    return EXIT_SUCCESS;
}

然后是CMakeLists.txt 文件。

cmake_minimum_required(VERSION 3.6 FATAL_ERROR)
set(CMAKE_VERBOSE_MAKEFILE ON)
project(Cmaketest)

if(POLICY CMP0042)
   cmake_policy(SET CMP0042 NEW)
endif()

if(POLICY CMP0066)
   cmake_policy(SET CMP0066 NEW)
endif()

# Default build type if none was specified.
if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  set(CMAKE_BUILD_TYPE Debug CACHE STRING "Choose the type of build." FORCE)
  message(STATUS "Setting build type to '${CMAKE_BUILD_TYPE} as none was specified.")

  # Possible values of build type for CMake GUI.
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
endif()

# The path to extra modules.
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)

# Setup build locations.
if(NOT CMAKE_RUNTIME_OUTPUT_DIRECTORY)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
endif()
set(CMAKE_CURRENT_BINARY_DIR    
${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/build)

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

include(ExternalProject)
include(ProcessorCount)
ProcessorCount(N)
if(NOT N EQUAL 0)
    set(CMAKE_BUILD_FLAGS -j${N})
endif()
# set(BOOST_VERSION 1.63.0)
# Boost related settings:    
# https://cmake.org/cmake/help/v3.6/module/FindBoost.html.
# Should one check the environment variables and flags here explicitly
# to remove the complaint about missing Boost library? Or should perhaps
# BOOST_ROOT be set? Point to what?
find_package(Boost)
if(NOT Boost_FOUND)
    # It shouldn't hurt to enable extensive diagnostics, just in case.
    # Also, a different set of files is downloaded for UNIX and WIN32
    # due to file permissions and line-feeds (Windows should handle
    # also Unix style line-feeds).
    set(Boost_DETAILED_FAILURE_MSG on)
    add_definitions(${Boost_LIB_DIAGNOSTIC_DEFINITIONS})
    set(Boost_Bootstrap_Command)
    if(UNIX)
       set(Boost_Url     "http://sourceforge.net/projects/boost/files/boost/1.63.0/boost_1_63_0.tar.gz")
        set(Boost_Sha1 "2cecf1848a813de55e5770f324f084c568abca0a")
        set(Boost_Bootstrap_Command ./bootstrap.sh)
        set(Boost_b2_Command ./b2)
     elseif(WIN32)
        set(Boost_Url "http://sourceforge.net/projects/boost/files/boost/1.63.0/boost_1_63_0.zip")
        set(Boost_Sha1 "4364989afbe6b11f2d5e59df902c3ca4d7851824")
        set(Boost_Bootstrap_Command bootstrap.bat)
        set(Boost_b2_Command b2.exe)
    endif()
        set(Config_Libraries "chrono,filesystem,program_options,system,thread,test")
ExternalProject_Add(Boost
    TMP_DIR "${CMAKE_CURRENT_SOURCE_DIR}/temp"
    DOWNLOAD_DIR "${CMAKE_CURRENT_SOURCE_DIR}/downloads"
    URL "${CMAKE_CURRENT_SOURCE_DIR}/downloads/boost_1_63_0.zip"
    URL_HASH "SHA1=${Boost_Sha1}"
    BUILD_IN_SOURCE 1
    UPDATE_COMMAND ""
    PATCH_COMMAND ""
    CONFIGURE_COMMAND ${Boost_Bootstrap_Command} --without-icu --with_libraries=${Config_Libraries}
    BUILD_COMMAND  ${Boost_b2_Command}
        # --prefix="${CMAKE_CURRENT_SOURCE_DIR}/depends"
        --without-python
        --address-model=64
        --architecture=x64
        --threading=multi
        --link=static
        --variant=release
        --layout=tagged
        --build-type=complete
        -j${N}
    INSTALL_COMMAND ""
    # INSTALL_DIR "${CMAKE_CURRENT_SOURCE_DIR}/depends"

    #As it happens, these directories are currently empty...
    # set(BOOST_ROOT ${CMAKE_CURRENT_SOURCE_DIR}/depends/include/boost-1_63)
    # set(Boost_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/depends/boost_1_63/include)
    # set(Boost_LIBRARY ${CMAKE_CURRENT_SOURCE_DIR}/depends/boost_1_63/lib)
)
endif()

 set(Boost_USE_STATIC_LIBS OFF)
 set(Boost_USE_MULTITHREADED ON)
 set(Boost_USE_STATIC_RUNTIME OFF)
 include_directories(${CMAKE_SOURCE_DIR}/src)

# Grabbing just all the test project files.
file(GLOB SOURCES "src/*.*")
add_executable(cmaketest ${SOURCES})
# TARGET_LINK_LIBRARIES(cmaketest ${Boost_LIBRARY})

Answer 1

我会尝试给您一些提示，尝试回答您的问题。

1) 使用这个 sn-p，您应该能够在正确的目录中拥有源代码和构建文件。我保留了TMP_DIR "${Cmaketest_SOURCE_DIR}/temp"，但在我的项目中我不使用那条线。

ExternalProject_Add(Boost
    TMP_DIR "${Cmaketest_SOURCE_DIR}/temp"
    DOWNLOAD_DIR "${Cmaketest_SOURCE_DIR}/downloads"
    URL "${Cmaketest_SOURCE_DIR}/downloads/boost_1_63_0.zip"
    URL_HASH "SHA1=${Boost_Sha1}"
    SOURCE_DIR ${Cmaketest_SOURCE_DIR}/downloads/boost_1_63_0
    BUILD_IN_SOURCE 1
    UPDATE_COMMAND ""
    PATCH_COMMAND ""
    CONFIGURE_COMMAND ${Boost_Bootstrap_Command} --without-icu --with_libraries=${Config_Libraries}
    BUILD_COMMAND  ${Boost_b2_Command}
        --prefix="${Cmaketest_SOURCE_DIR}/depends/boost_1_63_0"
        --without-python
        --address-model=64
        --architecture=x64
        --threading=multi
        --link=static
        --variant=release
        --layout=tagged
        --build-type=complete
        -j${N}
    INSTALL_COMMAND ${Boost_b2_Command} --prefix="${Cmaketest_SOURCE_DIR}/depends/boost_1_63_0" --without-python
        --address-model=64
        --architecture=x64
        --threading=multi
        --link=static
        --variant=release
        --layout=tagged
        --build-type=complete
        -j${N} install
    INSTALL_DIR "${Cmaketest_SOURCE_DIR}/depends/boost_1_63_0"
)

set(BOOST_ROOT ${Cmaketest_SOURCE_DIR}/depends/boost_1_63_0)
set(Boost_LIBRARY ${Cmaketest_SOURCE_DIR}/depends/boost_1_63_0/lib)
set(Boost_INCLUDE_DIR ${Cmaketest_SOURCE_DIR}/depends/boost_1_63_0/include)
include_directories(${Boost_INCLUDE_DIR})

要注意您没有调用“安装”，因此一旦在那个“奇怪”目录中构建，文件就不会移动到指定的前缀。还要注意使用${Cmaketest_SOURCE_DIR} 而不是以前的。
尝试打印两者，看看是否有区别。

2) 要解决在未找到 Boost 时收到的警告，您应该编写：

find_package(Boost QUIET)  

3）为了解决这个问题，我猜你无法生成项目文件，即，而不是

cmake build -G "Visual Studio 14 2015 Win64"  

只需要cmake . 或cmake ..，具体取决于您将进行源内构建还是源外构建。我建议进行源外构建，但这是您的选择。
4) FindBoost.cmake (FindBoost.cmake) 使您可以将任意路径传递到 Boost 目录。您可以在配置中使用它来提示 CMake 在您提供的位置查找 Boost，例如您可以通过以下方式调用 cmake：

cmake -DBOOST_ROOT=/path_to_cmaketest_dir/depends/boost_1_63_0 ..  

如果您的系统可能很挑剔，您可以指定所有内容：

cmake -DBOOST_ROOT=/path_to_cmaketest_dir/depends/boost_1_63_0 -DBOOST_LIBRARYDIR=/path_to_cmaketest_dir/depends/boost_1_63_0/lib DBOOST_INCLUDEDIR=/path_to_cmaketest_dir/depends/boost_1_63_0/include ..  

请注意，在最后两个 sn-ps 中，我假设配置了源外构建。
另请注意，如果您已经安装或下载了 Boost 包，则在 1) 中的代码片段中使用 ${Cmaketest_SOURCE_DIR} 应该也可以解决 4) 所以当它找不到 Boost 时它会尝试下载但它不会，因为现在cmake 应该可以看到文件（.zip）。

Answer 2

请参阅CMaker_Boost，在配置时使用 CMake 构建 Boost。现在在 Linux 和 Android、gcc 和 clang 上进行了测试。其他系统未测试。我希望这会有所帮助。