在已知文件名的批处理文件中获取文件大小

Question

我正在尝试编写一个简单的批处理文件，让我可以比较两个文件大小，其中两个文件名都是已知的，并在批处理文件本身中设置。

但事实证明，仅仅获得一个文件大小是很困难的。这是复制问题的最小代码段：

IF EXIST "flava.jpg" (

  REM Get current filesize 
  FOR /F %%A in ("flava.jpg") DO SET _existingFileSize=%%~zA

  ECHO %_existingFileSize%

) ELSE (

  ECHO File not found.

)

从我读过的here 来看，它应该回显变量的内容。怎么回事？

Answer 1

setlocal enabledelayedexpansion
IF EXIST "flava.jpg" (
  REM Get current filesize 
  FOR /F %%A in ("flava.jpg") DO SET _existingFileSize=%%~zA
  ECHO !_existingFileSize!
) ELSE (
  ECHO File not found.
)

或

IF EXIST "flava.jpg" (
  REM Get current filesize 
  FOR /F %%A in ("flava.jpg") DO SET _existingFileSize=%%~zA
  CALL ECHO %%_existingFileSize%%
) ELSE (
  ECHO File not found.
)

或

set "_existingfilesize="
FOR /F %%A in ("flava.jpg") DO SET _existingFileSize=%%~zA
if defined _existingfilesize (echo %_existingfilesize%) else (echo file not found)

问题是在块语句(a parenthesised series of statements) 中，整个块被解析并然后执行。块中的任何%var% 都将替换为该变量的值在解析块时 - 在块执行之前 - 同样适用于FOR ... DO (block)。

因此，IF (something) else (somethingelse) 将在遇到IF 时使用%variables% 的值执行。

解决此问题的两种常见方法是 1) 使用 setlocal enabledelayedexpansion 并使用 !var! 代替 %var% 来访问 var 的更改值或 2) 调用子程序以使用改变了值。

因此请注意CALL ECHO %%var%% 的使用，它显示var 的更改值。 CALL ECHO %%errorlevel%% 显示，但遗憾的是 RESETS 错误级别。

Answer 2

试试这个打印一个或多个文件的文件大小。我制作了一个子程序，让编写复杂的代码块变得更加容易。如果您需要两个命名文件，请使用精确的 file 值。

@echo off
set file=*.bat
for %%A in (%file%) do call :DOIT %%A
goto :END

:DOIT
echo %1 size is %~z1
goto :EOF

:END
pause