【问题标题】:How do you recursively delete a named directory from all volumes in Batch?如何从批处理中的所有卷中递归删除命名目录?
【发布时间】:2018-08-07 07:49:09
【问题描述】:
echo off
for /d /r "c:\" %%a in (TemporaryFolder) do if exist "%%a" echo Removing %%a & rmdir /s /q "%%a"

这个for loop 会从 C:\ 驱动器中删除每个名为“TemporaryFolder”的目录。我将如何通过每个已安装的卷(即 A:\ - Z:) 来删除目录“TemporaryFolder”?

编辑(此测试无效):

@echo off
echo Deleting Temporary Folders... Please be patient.
For /F "Tokens=*" %%A In ('MountVol^|Find ":\"') Do For /F "Delims=" %%B In ('Dir /B/S/AD-S-L "%%ATemporaryFolder" 2^>Nul') Do RD /S/Q "%%B" 2>Nul & echo Deleting %%B
echo Successfully deleted.
pause

【问题讨论】:

  • 使用另一个 For 循环并将其嵌套在其中。
  • 顺便说一句,如果您只运行脚本的第一部分,您会发现它的效率是多么低,请在命令提示符处尝试此操作以查看 For /D /R "C:\" %A In (TemporaryFolder) Do @Echo "%A"。现在也可以从命令提示符For /F "Delims=" %A In ('Dir /B/S/AD-S-L "C:\TemporaryFolder" 2^>Nul') Do @Echo "%A" 尝试我的实现。

标签: batch-file mounted-volumes


【解决方案1】:

根据我的评论,这是一个嵌套的 For 循环的示例,应该按照要求进行:

For /F "Tokens=*" %%A In ('MountVol^|Find ":\"') Do For /F "Delims=" %%B In ('Dir /B/S/AD-S-L "%%ATemporaryFolder" 2^>Nul') Do RD /S/Q "%%B" 2>Nul

外部For 循环运行MountVol 命令,该命令将安装的驱动器路径返回为%%A。嵌套的For 循环对位于%%A 内的名为TemporaryFolder 的人执行递归目录搜索。

编辑

这是同一例程的多行版本,添加了消息:

@Echo Off
Set "objFolder=TemporaryFolder"
Echo Please be patient...
For /F "Tokens=*" %%A In ('MountVol^|Find ":\"') Do (
    Echo Deleting directories named %objFolder% from %%A
    For /F "Delims=" %%B In ('Dir /B/S/AD-S-L "%%A%objFolder%" 2^>Nul') Do (
        Echo Deleting %%B
        RD /S/Q "%%B" 2>Nul && Echo Successfully deleted %%B
    )
)
Pause

您应该只修改objFolder 行2 上的名称。


这个不是MountVol,而是使用PowerShell 来获取驱动器,并且也匹配系统和重新分析点,(考虑到您需要适当的权限才能删除系统目录) :

@Echo Off
Set "objFolder=TemporaryFolder"
Echo Please be patient...
For /F "Tokens=*" %%A In (
    'PowerShell -NoP "GDr -P FileSystem|?{!$_.Used -Eq ''}|Select -Exp Root"'
) Do (Echo Deleting directories named %objFolder% from %%A
    For /F "Delims=" %%B In ('Dir /B/S/AD "%%A%objFolder%" 2^>Nul') Do (
        Echo Deleting %%B
        RD /S/Q "%%B" 2>Nul && Echo Successfully deleted %%B
    )
)
Pause

【讨论】:

  • 嘿,非常感谢您的回答,我编辑了我的答案,并进行了测试,但它不起作用。你不会碰巧知道为什么吧?
  • @sheepiiHD,它不起作用绝对不是一个合适的评论,请尝试提供更有意义的解释,以便我可以帮助您确定您做错了什么!如果您认为从命令提示符运行它构成了正确的测试,那么您就错了,因为%% 的所有实例都需要更改为%。
  • 它不会递归遍历每个卷,不会遍历每个目录,也不会删除任何内容。相比之下,我的脚本需要 10-15 秒才能完成。您的脚本需要不到 1 秒的时间,并且不会进行任何更改。
  • @sheepiiHD,我的代码工作正常,你的实现可能没有,但我没有时间猜测问题是什么。如果您希望解决问题,请更加努力地解释您的问题!同时,我将提供一个多行版本,以更接近您现在编辑的问题,(我不知道您已经完成了)。作为一个具体说明,如果您在命令提示符下运行DIR /?,您会注意到/Aoptions D、-S 和-L 专门匹配Directories,它们是Not System 和Not Reparse Points!
  • @sheepiiHD,还请注意,我的外部循环使用MountVol 输出已安装的卷,如果您想搜索例如已分配给网络位置的驱动器号,那么也许MountVol 不是您需要的,并且您提供的问题参数不正确。
猜你喜欢
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 2014-05-31
  • 2012-10-19
  • 1970-01-01
  • 1970-01-01
  • 2018-08-22
相关资源
最近更新 更多