使用 Excel/VB 根据父产品列表创建产品变体列表

Question

我正在使用产品 CSV 导入套装插件经营一家 Woocommerce 商店。我需要首先上传一个包含父产品的列表，然后是一个包含产品变体的列表。创建第二个列表非常耗费人力，因此我正在寻找一种方法来尽可能自动生成此列表。

下面是一个简短的父产品列表的样子：

包含父产品的实际列表将包含更多产品特征。

产品变体的结果应如下所示：

如您所见，可以看到产品变体（子）固有父产品的所有产品特性以及尺寸和颜色变量之一。如果子 sku 也能自动生成就好了。

我希望在不同的工作表（与父产品列表分开）中生成输出数据（产品变体）。

有人对如何在 Excel 中执行此操作有任何想法吗？我不是 Excel 向导，所以希望您能给我一些关于如何实施您的解决方案的指导。

Answer 1

这里的逻辑是读取每一行，直到找到一个空行，然后拆分颜色和大小。然后为颜色创建一个外循环，为尺寸创建一个内循环（这将处理所有变化）。您还需要一个变量来保存子 sku 计数器，并在产品的变化完成时将其重置。以下内容将帮助您入门：

Sub ProductVariations()

Dim productRow As Long, variationRow As Long
Dim size As String
Dim color As String
Dim skuCounter As Integer
Dim skuChild As String
Dim sizeArray() As String
Dim colorArray() As String
Dim sizeElement As Variant
Dim colorElement As Variant
Dim productsSheet As Worksheet
Dim variationsSheet As Worksheet

productRow = 2
variationRow = 2

Set productsSheet = ActiveWorkbook.Sheets(1)
Set variationSheet = ActiveWorkbook.Sheets(2)

'loop through each row until a blank row is found
While productsSheet.Cells(productRow, 1).Value <> ""

   'get the size and color values for the current row
   size = productsSheet.Cells(productRow, 3)
   color = productsSheet.Cells(productRow, 4)

   'make sure a size and color exists then process
   If Len(size) > 0 And Len(color) > 0 Then

       'reset the sku counter
       skuCounter = 0

       'split the size and color into arrays
       sizeArray = Split(size, "|")
       colorArray = Split(color, "|")

       'loop through each size
       For Each sizeElement In sizeArray

           'loop through each color
           For Each colorElement In colorArray

               'increment the child counter for this variation
               skuCounter = skuCounter + 1

               'set the appropriate cells in the variations sheet (you have some more work to do here
               skuChild = productsSheet.Cells(productRow, 2).Value & "-" & skuCounter

               variationSheet.Cells(variationRow, 1).Value = productsSheet.Cells(productRow, 1)
               variationSheet.Cells(variationRow, 3).Value = skuChild

               'increment the variation row so the next variation goes in the next row
               variationRow = variationRow + 1

           Next colorElement

       Next sizeElement

   End If

   'very important increment the next row or only the first row will ever get processed
   productRow = productRow + 1
Wend 
End Sub