如何指定连接超时（以毫秒为单位）并发送多个 TCP 连接？

Question

我有多个阻塞的 TCP 客户端试图连接服务器并将数据发送到服务器。然而，每个操作不应超过 500 毫秒，因为数据是时间相关的。超时时，它应该重试。我见过alarm() 方法，但它只接受秒。有什么好的方法吗？

Answer 1

Time::HiRes 模块为您提供了一个具有微秒粒度的函数ualarm。

Answer 2

如果每个连接都有一个子进程，则可以使用Time::HiRes 的ualarm。否则，我不明白你为什么会想使用alarm。它甚至对线程没有帮助（因为信号被发送到进程）。

更好的方法是记录连接的建立时间，如果您在随后的 0.5 秒后收到来自客户端的数据，则断开连接。 Time::HiRes 提供了一个返回小数秒的time 版本。

无论您如何提供并行性（线程、子进程、select、非阻塞操作），这种方法都有效。它适用于 TCP 和 UDP。它甚至是便携的。

如果一切都在同一个线程和进程中，您可以通过在从任何连接获取数据时扫描所有连接以查找超时来更快地丢弃死连接。

---

alarm 不会帮助你处理线程。

1. 如果在启动线程之前设置处理程序，线程中的调用不会中断。

   use strict;
   use warnings;
   use threads;
   
   use Time::HiRes qw( time ualarm );
   
   local $SIG{ALRM} = sub { };
   
   {
      ualarm(2 * 1_000_000);
      my $s = time;
      sleep(5);
      my $e = time;
      print "Slept for ".($e-$s)." seconds\n";
   }
   
   for my $thread_idx (0..1) {
      async {
         ualarm(2 * 1_000_000) if $thread_idx == 0;
         my $s = time;
         sleep(5);
         my $e = time;
         print "Thread $thread_idx slept for ".($e-$s)." seconds\n";
      };
   }
   
   $_->join for threads->list;
   

   输出

   Slept for 2.00284504890442 seconds
   Thread 0 slept for 5.00048089027405 seconds
   Thread 1 slept for 5.00327205657959 seconds
   

2. 在线程中设置处理程序完全没有影响。

   use strict;
   use warnings;
   use threads;
   
   use Time::HiRes qw( time ualarm );
   
   for my $thread_idx (0..1) {
      async {
         local $SIG{ALRM} = sub { };
         ualarm(2 * 1_000_000) if $thread_idx == 0;
         my $s = time;
         sleep(5);
         my $e = time;
         print "Thread $thread_idx slept for ".($e-$s)." seconds\n";
      };
   }
   
   $_->join for threads->list;
   

   输出

   Alarm clock