嵌套多个.cmd文件，先决条件按一定顺序运行[重复]

Question

我无法弄清楚这背后的逻辑。我有 11 个.cmd 文件需要按特定顺序运行。其中5个可以同时启动，后5个直接依赖前5个对应，最后一个文件依赖于第二组5个运行。

工作流程图片：

• 第 1 步是启动 QAQC 进程 1-5。
• 第 2 步是在每个 QAQC 进程完成时启动相应的 CONVERT 进程。
• 第 3 步是在所有 5 个CONVERT 进程完成后合并所有输出。

我想我需要为每个文件创建一个 .cmd 或 .bat 文件，然后在一个文件中调用这 5 个文件。

file1.cmd:

 call QAQC1
 call CONVERT1

file2.cmd:

call QAQC2
call CONVERT2

等等……

最终文件会是这样的：

FINAL_FINAL.cmd:

start "QAQC1.cmd" QAQC1.cmd
start "QAQC2.cmd" QAQC2.cmd
start "QAQC3.cmd" QAQC3.cmd
start "QAQC4.cmd" QAQC4.cmd
start "QAQC5.cmd" QAQC5.cmd 

我仍然不清楚这是否正确，或者在调用将所有内容合并在一起并需要所有 10 个其他文件完成的最终文件之前，我将如何完成所有这些步骤。任何帮助将不胜感激！

Answer 1

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1,1,5) do (
  set /a x=!random! %% 10
  >QAQC%%a.cmd (
    echo @echo QAQC%%a
    echo @timeout !x!
  )
  >CONVERT!%%a.cmd (
    echo @echo CONVERT%%a
    echo @timeout !x!
  )
)
echo @echo merge running >merge.cmd
echo @timeout 3 >>merge.cmd
REM ignore anything before this line; it just creates a test environment

@echo off
echo wait for qaqcX and convertX to finish...
( start cmd /c "qaqc1.cmd & convert1.cmd"
  start cmd /c "qaqc2.cmd & convert2.cmd"
  start cmd /c "qaqc3.cmd & convert3.cmd"
  start cmd /c "qaqc4.cmd & convert4.cmd"
  start cmd /c "qaqc5.cmd & convert5.cmd"
) | pause >nul
call merge.cmd
echo done.