根据条件计算列值（当前行和前一行的值）

Question

我正在尝试通过结合我对金融的兴趣来学习一些 SQL。目前我正在尝试根据交易列表（在 SQL Server 中）计算一些投资组合数据。

这是我的桌子：

create table StockTransactions 
(
    TransactionID int,
    Instrument varchar(32),
    TransactionType varchar(32),
    Units int,
    Price float,
    TransactionSum as case
        when TransactionType = 'Buy' then (-(Units * Price))
        when TransactionType = 'Sell'  then (Units * Price)
        else 0
        end,
    PurchaseCost float
)

样本数据：

insert into StockTransactions (TransactionID, Instrument, TransactionType, Units, Price)
values 
(1, 'Apple', 'Buy', 10, 120),
(2, 'Microsoft', 'Buy', 20, 290),
(3, 'Apple', 'Buy', 10, 125),
(4, 'Apple', 'Sell', 5, 140),
(5, 'Apple', 'Buy', 10, 130),
(6, 'Apple', 'Sell', 10, 135)

此表中的结果：

TransactionID	Instrument	TransactionType	Units	Price	TransactionSum	PurchaseCost
1	Apple	Buy	10	120	-1200	NULL
2	Microsoft	Buy	20	290	-5800	NULL
3	Apple	Buy	10	125	-1250	NULL
4	Apple	Sell	5	140	700	NULL
5	Apple	Buy	10	130	-1300	NULL
6	Apple	Sell	10	135	1350	NULL

我正在尝试计算 PurchaseCost 列的值。我想要的值是：

Row	PurchaseCost
1	-1200
2	-5800
3	-2450
4	-1837.5
5	-3137.5
6	-2353.13

逻辑如下。如果已进行购买，则应将 TransactionSum 添加到该工具的最新先前 PurchaseCost。但是，当进行销售时，应该减去一定的金额。

在第四次交易中，我卖出了 20 股 Apple 股票中的 5 股。因此，我想减去之前 PurchaseCost 的 1/4，得到新的 PurchaseCost 值 -1837.5。

在交易 6 中，我卖出了 25 股 Apple 股票中的 10 股，然后想将 PurchaseCost 降低到 2353.13（之前价值的 60%）。

我自己似乎无法弄清楚如何做到这一点。有什么想法吗？

Answer 1

您可以创建存储过程来计算每一行 这里是使用临时表计算和选择的代码

IF OBJECT_ID('tempdb..#TempStock') IS NOT NULL DROP TABLE #TempStock

DECLARE @TransId int
DECLARE @TempInst varchar(32)
DECLARE @TempPurchase float
DECLARE @TempUnit int
DECLARE @TempTrans varchar(32)
DECLARE @LastPurchase float
DECLARE @LastUnits int

CREATE TABLE #TempStock (
    TransactionID int,
    Instrument varchar(32),
    Units int,
    PurchaseCost float
)

DECLARE MY_CURSOR CURSOR
FOR SELECT DISTINCT TransactionID 
FROM StockTransactions


OPEN MY_CURSOR
FETCH NEXT FROM MY_CURSOR INTO @TransId
WHILE @@FETCH_STATUS = 0
BEGIN 
    SELECT @TempInst = Instrument, @TempTrans = TransactionType, @TempUnit = Units, @TempPurchase = TransactionSum FROM StockTransactions
    WHERE TransactionID = @TransId

    SELECT  TOP 1 @LastPurchase = PurchaseCost, @LastUnits = Units
    FROM #TempStock
    WHERE Instrument = @TempInst
    ORDER BY TransactionID DESC
    
    IF @@ROWCOUNT = 0
    BEGIN
        SELECT @LastPurchase = 0, @LastUnits = 0 
    END

    IF @TempTrans = 'Buy'
    BEGIN
        INSERT INTO #TempStock (TransactionID, Instrument, Units, PurchaseCost)
        VALUES (
            @TransId,
            @TempInst,
            ISNULL(@LastUnits,0) + ISNULL(@TempUnit,0),
            ISNULL(@LastPurchase,0) + ISNULL(@TempPurchase,0)
        )
    END
    ELSE IF @TempTrans = 'Sell'
    BEGIN
        INSERT INTO #TempStock (TransactionID, Instrument, Units, PurchaseCost)
        VALUES (
            @TransId,
            @TempInst,
            ISNULL(@LastUnits,0) - ISNULL(@TempUnit,0),
            (ISNULL(@LastPurchase,0) * (ISNULL(@LastUnits,0) - ISNULL(@TempUnit,0))) / ISNULL(@LastUnits,0)
        )
    END
    
    FETCH NEXT FROM MY_CURSOR INTO @TransId
END
CLOSE MY_CURSOR
DEALLOCATE MY_CURSOR

SELECT TransactionID, PurchaseCost FROM #TempStock

DROP TABLE #TempStock

您可以从该临时表更新主表