【问题标题】:CMake + GoogleTestCMake + 谷歌测试
【发布时间】:2012-03-30 03:47:21
【问题描述】:

我刚刚下载了 googletest,用 CMake 生成了它的 makefile 并构建了它。现在,我需要在我的测试项目中使用它。

使用 CMake,有人建议我不要直接指向 gtest 库(使用 include _directories 或 link_directories),而是使用 find_package()。

问题是,生成的 gtest makefile 没有安装目标。我无法理解 find_package(GTest REQUIRED) 在没有某种安装的情况下如何工作。此外,将 gtest 文件夹作为子文件夹放在我的项目中是不可能的。

感谢您的帮助。

【问题讨论】:

    标签: cmake googletest


    【解决方案1】:

    这是一个不寻常的案例;大多数项目都指定了安装规则。

    CMake 的ExternalProject_Add 模块可能是完成这项工作的最佳工具。这允许您从项目中下载、配置和构建 gtest,然后链接到 gtest 库。

    我已经在 Windows 上使用 Visual Studio 10 和 11 以及在 Ubuntu 上使用 GCC 4.8 和 Clang 3.2 测试了以下 CMakeLists.txt - 它可能需要针对其他平台/编译器进行调整:

    cmake_minimum_required(VERSION 2.8.7 FATAL_ERROR)
    project(Test)
    
    # Create main.cpp which uses gtest
    file(WRITE src/main.cpp "#include \"gtest/gtest.h\"\n\n")
    file(APPEND src/main.cpp "TEST(A, B) { SUCCEED(); }\n")
    file(APPEND src/main.cpp "int main(int argc, char **argv) {\n")
    file(APPEND src/main.cpp "  testing::InitGoogleTest(&argc, argv);\n")
    file(APPEND src/main.cpp "  return RUN_ALL_TESTS();\n")
    file(APPEND src/main.cpp "}\n")
    
    # Create patch file for gtest with MSVC 2012
    if(MSVC_VERSION EQUAL 1700)
      file(WRITE gtest.patch "Index: cmake/internal_utils.cmake\n")
      file(APPEND gtest.patch "===================================================================\n")
      file(APPEND gtest.patch "--- cmake/internal_utils.cmake   (revision 660)\n")
      file(APPEND gtest.patch "+++ cmake/internal_utils.cmake   (working copy)\n")
      file(APPEND gtest.patch "@@ -66,6 +66,9 @@\n")
      file(APPEND gtest.patch "       # Resolved overload was found by argument-dependent lookup.\n")
      file(APPEND gtest.patch "       set(cxx_base_flags \"\${cxx_base_flags} -wd4675\")\n")
      file(APPEND gtest.patch "     endif()\n")
      file(APPEND gtest.patch "+    if (MSVC_VERSION EQUAL 1700)\n")
      file(APPEND gtest.patch "+      set(cxx_base_flags \"\${cxx_base_flags} -D_VARIADIC_MAX=10\")\n")
      file(APPEND gtest.patch "+    endif ()\n")
      file(APPEND gtest.patch "     set(cxx_base_flags \"\${cxx_base_flags} -D_UNICODE -DUNICODE -DWIN32 -D_WIN32\")\n")
      file(APPEND gtest.patch "     set(cxx_base_flags \"\${cxx_base_flags} -DSTRICT -DWIN32_LEAN_AND_MEAN\")\n")
      file(APPEND gtest.patch "     set(cxx_exception_flags \"-EHsc -D_HAS_EXCEPTIONS=1\")\n")
    else()
      file(WRITE gtest.patch "")
    endif()
    
    # Enable ExternalProject CMake module
    include(ExternalProject)
    
    # Set the build type if it isn't already
    if(NOT CMAKE_BUILD_TYPE)
      set(CMAKE_BUILD_TYPE Release)
    endif()
    
    # Set default ExternalProject root directory
    set_directory_properties(PROPERTIES EP_PREFIX ${CMAKE_BINARY_DIR}/ThirdParty)
    
    # Add gtest
    ExternalProject_Add(
        googletest
        SVN_REPOSITORY http://googletest.googlecode.com/svn/trunk/
        SVN_REVISION -r 660
        TIMEOUT 10
        PATCH_COMMAND svn patch ${CMAKE_SOURCE_DIR}/gtest.patch ${CMAKE_BINARY_DIR}/ThirdParty/src/googletest
        # Force separate output paths for debug and release builds to allow easy
        # identification of correct lib in subsequent TARGET_LINK_LIBRARIES commands
        CMAKE_ARGS -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
                   -DCMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG:PATH=DebugLibs
                   -DCMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE:PATH=ReleaseLibs
                   -Dgtest_force_shared_crt=ON
        # Disable install step
        INSTALL_COMMAND ""
        # Wrap download, configure and build steps in a script to log output
        LOG_DOWNLOAD ON
        LOG_CONFIGURE ON
        LOG_BUILD ON)
    
    # Specify include dir
    ExternalProject_Get_Property(googletest source_dir)
    include_directories(${source_dir}/include)
    
    # Add compiler flag for MSVC 2012
    if(MSVC_VERSION EQUAL 1700)
      add_definitions(-D_VARIADIC_MAX=10)
    endif()
    
    # Add test executable target
    add_executable(MainTest ${PROJECT_SOURCE_DIR}/src/main.cpp)
    
    # Create dependency of MainTest on googletest
    add_dependencies(MainTest googletest)
    
    # Specify MainTest's link libraries
    ExternalProject_Get_Property(googletest binary_dir)
    if(MSVC)
      set(Suffix ".lib")
    else()
      set(Suffix ".a")
      set(Pthread "-pthread")
    endif()
    target_link_libraries(
        MainTest
        debug ${binary_dir}/DebugLibs/${CMAKE_FIND_LIBRARY_PREFIXES}gtest${Suffix}
        optimized ${binary_dir}/ReleaseLibs/${CMAKE_FIND_LIBRARY_PREFIXES}gtest${Suffix}
        ${Pthread})
    

    如果你在一个空目录(比如MyTest)中将它创建为 CMakeLists.txt,那么:

    cd MyTest
    mkdir build
    cd build
    cmake ..
    

    这应该在MyTest/src 中创建一个基本的main.cpp 并创建一个项目文件(Windows 上为MyTest/build/Test.sln)

    当您构建项目时,它应该将 gtest 源下载到 MyTest/build/ThirdParty/src/googletest,并在 MyTest/build/ThirdParty/src/googletest-build 中构建它们。然后您应该能够成功运行 MainTest 目标。

    【讨论】:

    • 对我来说似乎很复杂。有没有办法直接引用google test CMakeLists.txt 文件?还是应该将 googletest 库添加为子目录?
    • 我认为这并不比将 googletest 添加为子目录复杂得多,但如果您可以选择,那么可以确定 - 将 googletest 添加为源代码树的子目录并通过 ADD_SUBDIRECTORY 将其拉入. (您确实在原始问题中指定了这不是一个选项)。
    • 是的,确实如此。我想使用更好的解决方案。但是一个子目录似乎比你提供的解决方案更好更干净......但我只是从 CMake 世界开始......;)
    • 我同意它可能会稍微简单一些,但我不认为它更干净。使用ADD_SUBDIRECTORY 选项,您最终会在您自己的源代码树中获得第三方源代码,而ExternalProject_Add 将第三方代码转储到您的(一次性)构建树中,而您的源代码树只剩下您自己的源代码。不过这取决于您 - 我不会强烈推荐其中一个。
    • +1 用于在您的第一个解决方案中保持源代码树清洁。我将研究这两种解决方案,看看哪一种最适合我。非常感谢您的大力帮助!
    【解决方案2】:

    问原始问题已经很久了,但是为了其他人的利益,可以使用ExternalProject 下载gtest 源,然后使用add_subdirectory() 将其添加到您的构建中。这样做有以下优点:

    • gtest 是作为主构建的一部分构建的,因此它使用相同的编译器标志等,并且不需要安装在任何地方。
    • 无需将 gtest 源代码添加到您自己的源代码树中。

    以正常方式使用,ExternalProject 不会在配置时(即运行 CMake 时)进行下载和解包,但您可以让它这样做。我写了一篇关于如何做到这一点的博客文章,其中还包括一个通用实现,它适用于任何使用 CMake 作为其构建系统的外部项目,而不仅仅是 gtest。你可以在这里找到它:

    https://crascit.com/2015/07/25/cmake-gtest/

    更新:上述方法现在也是part of the googletest documentation。

    【讨论】:

    • 太棒了! - 为什么这不是 CMake 内置的?可以提交吗?
    【解决方案3】:

    我的回答是基于firegurafiku 的回答。我通过以下方式对其进行了修改:

    1. 将CMAKE_ARGS 添加到ExternalProject_Add 调用中,以便与msvc 一起使用。
    2. 从文件位置而不是下载获取 gtest 源
    3. 添加了 IMPORTED_LOCATION 的可移植(用于 MSVC 和非 MSVC)定义和用法
    4. 解决了当INTERFACE_INCLUDE_DIRECTORIES 不存在时调用 set_target_properties 在配置时不起作用的问题,因为尚未构建外部项目。

    我更喜欢将 gtest 保留为外部项目,而不是将其源代码直接添加到我的项目中。一个原因是因为我不喜欢在搜索代码时包含 gtest 源代码。我的代码需要的任何特殊的构建标志,在构建 gtest 时也应该使用,可以添加到对 ExternalProject_Add 的调用中的 CMAKE_ARGS 的定义中

    这是我修改后的方法:

    include(ExternalProject)
    
    # variables to help keep track of gtest paths
    set(GTEST_PREFIX "${CMAKE_CURRENT_BINARY_DIR}/gtest")
    set(GTEST_LOCATION "${GTEST_PREFIX}/src/GTestExternal-build")
    set(GTEST_INCLUDES "${GTEST_PREFIX}/src/GTestExternal/include")
    
    # external project download and build (no install for gtest)
    ExternalProject_Add(GTestExternal
        URL ${CMAKE_CURRENT_SOURCE_DIR}/../googletest
        PREFIX "${GTEST_PREFIX}"
    
        # cmake arguments
        CMAKE_ARGS -Dgtest_force_shared_crt=ON
    
        # Disable install step
        INSTALL_COMMAND ""
    
        # Wrap download, configure and build steps in a script to log output
        LOG_DOWNLOAD ON
        LOG_CONFIGURE ON
        LOG_BUILD ON
        )
    
    # variables defining the import location properties for the generated gtest and
    # gtestmain libraries
    if (MSVC)
        set(GTEST_IMPORTED_LOCATION
            IMPORTED_LOCATION_DEBUG           "${GTEST_LOCATION}/Debug/${CMAKE_STATIC_LIBRARY_PREFIX}gtest${CMAKE_STATIC_LIBRARY_SUFFIX}"
            IMPORTED_LOCATION_RELEASE         "${GTEST_LOCATION}/Release/${CMAKE_STATIC_LIBRARY_PREFIX}gtest${CMAKE_STATIC_LIBRARY_SUFFIX}"
            )
        set(GTESTMAIN_IMPORTED_LOCATION
            IMPORTED_LOCATION_DEBUG           "${GTEST_LOCATION}/Debug/${CMAKE_STATIC_LIBRARY_PREFIX}gtest_main${CMAKE_STATIC_LIBRARY_SUFFIX}"
            IMPORTED_LOCATION_RELEASE         "${GTEST_LOCATION}/Release/${CMAKE_STATIC_LIBRARY_PREFIX}gtest_main${CMAKE_STATIC_LIBRARY_SUFFIX}"
            )
    else()
        set(GTEST_IMPORTED_LOCATION
            IMPORTED_LOCATION                 "${GTEST_LOCATION}/${CMAKE_STATIC_LIBRARY_PREFIX}gtest${CMAKE_STATIC_LIBRARY_SUFFIX}")
        set(GTESTMAIN_IMPORTED_LOCATION
            IMPORTED_LOCATION                 "${GTEST_LOCATION}/${CMAKE_STATIC_LIBRARY_PREFIX}gtest_main${CMAKE_STATIC_LIBRARY_SUFFIX}")
    endif()
    
    # the gtest include directory exists only after it is build, but it is used/needed
    # for the set_target_properties call below, so make it to avoid an error
    file(MAKE_DIRECTORY ${GTEST_INCLUDES})
    
    # define imported library GTest
    add_library(GTest IMPORTED STATIC GLOBAL)
    set_target_properties(GTest PROPERTIES
        INTERFACE_INCLUDE_DIRECTORIES     "${GTEST_INCLUDES}"
        IMPORTED_LINK_INTERFACE_LIBRARIES "${CMAKE_THREAD_LIBS_INIT}"
        ${GTEST_IMPORTED_LOCATION}
        )
    
    # define imported library GTestMain
    add_library(GTestMain IMPORTED STATIC GLOBAL)
    set_target_properties(GTestMain PROPERTIES
        IMPORTED_LINK_INTERFACE_LIBRARIES GTest
        ${GTESTMAIN_IMPORTED_LOCATION}
        )
    
    # make GTest depend on GTestExternal
    add_dependencies(GTest GTestExternal)
    
    #
    # My targets
    #
    
    project(test_pipeline)
    add_executable(${PROJECT_NAME} test_pipeline.cpp)
    set_target_properties(${PROJECT_NAME} PROPERTIES DEBUG_POSTFIX ${CMAKE_DEBUG_POSTFIX})
    target_link_libraries(${PROJECT_NAME} ${TBB_LIBRARIES})
    target_link_libraries(${PROJECT_NAME} GTest)
    

    【讨论】:

    • 感谢您对先前答案的大力更正。顺便说一句,在 Visual Studio 中,我为与 gtest 链接的任何项目按“重建”,它也会重新下载并重建 gtest。这是正常行为吗?为什么要重建“外部项目”?
    • CMake ExternalProject 行为的细节对我来说仍然有点神秘。我描述的方式,gtest已经是本地的,所以至少不会重新下载。一般来说,在 Visual Studio 中,Rebuild 不仅会重建选定的项目,还会重建它所依赖的所有其他项目。 cmake 生成的解决方案/项目中必须有一些东西使 ExternalProject Add 目标成为依赖项。因此 gtest 得到重建。为避免这种情况,您可以执行“仅项目重建”,或者您可以转到 Build -> Batch Build 并清理要重建的项目。
    • 感谢您的回答!此外,如果您只是执行上述操作,您的应用程序将不会使用默认设置在 Visual Studio 中构建(您将收到多个符号链接错误),因为 gtest 库使用 /MT 运行时而不是默认 /MD。这是一个常见问题解答条目:github.com/google/googletest/blob/master/googletest/docs/…
    • 我认为CMAKE_ARGS -Dgtest_force_shared_crt=ON 会导致 gtest 使用 /MD 构建?
    【解决方案4】:

    使用ExternalProject 模块和cmake 的导入库功能有一个不太复杂的解决方案。它从存储库中检查代码,构建它并从构建的静态库中创建目标(它们在我的系统上是 libgtest.a 和 libgtest_main.a)。

    find_package(Threads REQUIRED)
    include(ExternalProject)
    
    set(GTEST_PREFIX "${CMAKE_CURRENT_BINARY_DIR}/gtest")
    ExternalProject_Add(GTestExternal
        SVN_REPOSITORY http://googletest.googlecode.com/svn/trunk
        SVN_REVISION -r HEAD
        TIMEOUT 10
        PREFIX "${GTEST_PREFIX}"
        INSTALL_COMMAND "")
    
    set(LIBPREFIX "${CMAKE_STATIC_LIBRARY_PREFIX}")
    set(LIBSUFFIX "${CMAKE_STATIC_LIBRARY_SUFFIX}")
    set(GTEST_LOCATION "${GTEST_PREFIX}/src/GTestExternal-build")
    set(GTEST_INCLUDES "${GTEST_PREFIX}/src/GTestExternal/include")
    set(GTEST_LIBRARY  "${GTEST_LOCATION}/${LIBPREFIX}gtest${LIBSUFFIX}")
    set(GTEST_MAINLIB  "${GTEST_LOCATION}/${LIBPREFIX}gtest_main${LIBSUFFIX}")
    
    add_library(GTest IMPORTED STATIC GLOBAL)
    set_target_properties(GTest PROPERTIES
        IMPORTED_LOCATION                 "${GTEST_LIBRARY}"
        INTERFACE_INCLUDE_DIRECTORIES     "${GTEST_INCLUDES}"
        IMPORTED_LINK_INTERFACE_LIBRARIES "${CMAKE_THREAD_LIBS_INIT}")
    
    add_library(GTestMain IMPORTED STATIC GLOBAL)
    set_target_properties(GTestMain PROPERTIES
        IMPORTED_LOCATION "${GTEST_MAINLIB}"
        IMPORTED_LINK_INTERFACE_LIBRARIES
            "${GTEST_LIBRARY};${CMAKE_THREAD_LIBS_INIT}")
    
    add_dependencies(GTest GTestExternal)
    

    您可能希望在此处替换 SVN_REVISION 或添加 LOG_CONFIGURE 和 LOG_BUILD 选项。 GTest 和 GTestMain 目标创建后,可以这样使用:

    add_executable(Test
        test1.cc
        test2.cc)
    target_link_libraries(Test GTestMain)
    

    或者,如果你有自己的main() 函数:

    add_executable(Test
        main.cc
        test1.cc
        test2.cc)
    target_link_libraries(Test GTest)
    

    【讨论】:

    • 如何添加include目录?
    • @Jeff:更新答案,抱歉半年延迟。请参阅目标的INTERFACE_INCLUDE_DIRECTORIES 属性。
    • 我必须删除行 INTERFACE_INCLUDE_DIRECTORIES "${GTEST_INCLUDES}" 才能使用我自己的 main() 函数进行这项工作
    • @JansenduPlessis:我认为它会受到影响,但您可以将CMAKE_ARGS 和CMAKE_CACHE_ARGS 参数传递给ExternalProject_Add。也许在有 Catch 和 Boost.Test 这样的纯标头库时使用 GoogleTest 是个坏主意。
    • 与其删除 INTERFACE_INCLUDE_DIRECTORIES 行,不如创建路径,以便在设置需要它的目标属性时 cmake 不会阻塞。我在调用set_target_properies之前使用file(MAKE_DIRECTORY ${GTEST_INCLUDES})。
    【解决方案5】:

    这个话题有点老了,但是出现了一种在 CMake 中包含外部库的新方法。

    #Requires CMake 3.16+
    include(FetchContent)
    
    FetchContent_Declare(
      googletest
      GIT_REPOSITORY https://github.com/google/googletest.git
      GIT_TAG        release-1.8.0
    )
    
    FetchContent_MakeAvailable(googletest)
    

    如果要支持早期版本的cmake:

    # Requires CMake 3.11+
    include(FetchContent)
    
    FetchContent_Declare(
      googletest
      GIT_REPOSITORY https://github.com/google/googletest.git
      GIT_TAG        release-1.8.0
    )
    
    FetchContent_GetProperties(googletest)
    if(NOT googletest_POPULATED)
      FetchContent_Populate(googletest)
      add_subdirectory(${googletest_SOURCE_DIR} ${googletest_BINARY_DIR})
    endif()
    

    然后你只需添加

    enable_testing()
    
    add_executable(test ${SOURCES} )
    
    target_link_libraries(test gtest_main ${YOUR_LIBS})
    
    add_test(NAME tests COMMAND test)
    

    延伸阅读:https://cmake.org/cmake/help/latest/module/FetchContent.html

    【讨论】:

      【解决方案6】:

      当您通过以下方式获得libgtest-dev 包时

      sudo apt install libgtest-dev
      

      源存储在位置/usr/src/googletest

      您可以简单地将您的CMakeLists.txt 指向该目录,以便它可以找到必要的依赖项

      类似下面的东西

      add_subdirectory(/usr/src/googletest gtest)
      target_link_libraries(your_executable gtest)
      

      【讨论】:

      • 考虑为此使用 FindPackage
      猜你喜欢
      • 1970-01-01
      • 2020-11-11
      • 2018-11-24
      • 1970-01-01
      • 2012-08-17
      • 2014-04-04
      • 2011-04-02
      • 1970-01-01
      • 2011-06-14
      相关资源
      最近更新 更多