在 awk 中，为什么 "" 和 "\n\n" 对于 RS 参数的处理方式相同？

Question

这是文件的内容：

Person Name
123 High Street
(222) 466-1234

Another person
487 High Street
(523) 643-8754

这两件事给出了相同的结果：

$ awk 'BEGIN{FS="\n"; RS="\n\n"} {print $1, $3}' file_contents

$ awk 'BEGIN{FS="\n"; RS=""} {print $1, $3}' file_contents

两种情况给出的结果都是：

Person Name (222) 466-1234
Another person (523) 643-8754

RS="\n\n"其实是有道理的，但是为什么RS=""也被这样对待呢？

Answer 1

他们的待遇不同。

• RS="" 在 all awks 中调用段落模式，因此输入被分成由连续的空行序列分隔的记录，如果现有 FS 是单个字符，则将换行符添加到 FS（注意： POSIX 标准在这方面是不正确的，因为它暗示 \n 将被添加到任何 FS 中，但事实并非如此，请参阅 https://lists.gnu.org/archive/html/bug-gawk/2019-04/msg00029.html）。
• RS="\n\n" 在 GNU awk 中工作以将记录分隔符设置为单个空行并且不影响 FS。在所有其他 awk 中，第二个 \n 将被忽略（RS 中超过 1 个字符是每个 POSIX 未定义的行为，因此它们可以做任何事情，但这是迄今为止最常见的实现）。

看看当您的 2 个文本块之间有 3 个空行并使用 \n 以外的 FS（例如 ,）时会发生什么：

$ cat file
Person Name
123 High Street
(222) 466-1234



Another person
487 High Street
(523) 643-8754

.

$ gawk 'BEGIN{FS=","; RS=""} {print NR, NF, "<" $0 ">\n"}' file
1 3 <Person Name
123 High Street
(222) 466-1234>

2 3 <Another person
487 High Street
(523) 643-8754>

.

$ gawk --posix 'BEGIN{FS=","; RS=""} {print NR, NF, "<" $0 ">\n"}' file
1 3 <Person Name
123 High Street
(222) 466-1234>

2 3 <Another person
487 High Street
(523) 643-8754>

.

$ gawk 'BEGIN{FS=","; RS="\n\n"} {print NR, NF, "<" $0 ">\n"}' file
1 1 <Person Name
123 High Street
(222) 466-1234>

2 0 <>

3 1 <Another person
487 High Street
(523) 643-8754>

.

$ gawk --posix 'BEGIN{FS=","; RS="\n\n"} {print NR, NF, "<" $0 ">\n"}' file
1 1 <Person Name>

2 1 <123 High Street>

3 1 <(222) 466-1234>

4 0 <>

5 0 <>

6 0 <>

7 1 <Another person>

8 1 <487 High Street>

9 1 <(523) 643-8754>

10 0 <>

注意NR 和NF 的不同值以及正在打印的不同$0 内容。

Answer 2

因为POSIX awk specification是这么说的。

如果RS 为空，则记录由<newline> 加上一个或多个空行组成的序列分隔，前导或尾随空行不应导致输入的开头或结尾处为空记录，并且无论FS 的值是什么，<newline> 始终是字段分隔符。