Unix - 并排打印公共行

Question

我想比较 2 个未排序的文件并并排打印公共行

文件1

一个 1 2
b 2 4
c 1 4
e 1 2

文件2
0 3
c 1 4
d 3 4
b 2 4

输出1

1 2 0 3
b 2 4 2 4
c 1 4 1 4

输出2
1 2 0 3
b 2 4 2 4
c 1 4 1 4
d 3 4
e 1 2

我可以使用 Join 实现，但我想使用 awk 查找命令。

我们可以不对文件进行排序并使用awk来获取output1和output2吗？

Answer 1

$ awk '
    NR==FNR {line[$1]=$0; next} 
    $1 in line {
        f2fields = gensub($1 FS, "", 1)
        print line[$1], f2fields > "output1"
        print line[$1], f2fields > "output2"
        seen[$1]++
        next
    } 
    {print > "output2"} 
    END { for (key in line) if (!(key in seen)) print line[key] > "output2" }
' file1 file2

$ cat output1
a 1 2 0 3
c 1 4 1 4
b 2 4 2 4

$ cat output2
a 1 2 0 3
c 1 4 1 4
d 3 4
b 2 4 2 4
e 1 2

输出{1,2}文件的顺序由1）file2的记录顺序决定，然后2）file1中没有出现在file2中的记录被“随机”输出（以哈希顺序）。

Answer 2

你可以像这样使用 GNU awk 做到这一点：

script.awk

BEGIN { PROCINFO["sorted_in"] = "@ind_str_asc" }

FNR == NR { lines[$1] = $0; next }
FNR != NR { if( $1 in lines ) {
              k = $1
              # strip unnecessary key $1 from $0
              $1 = ""
              lines[ k ] = lines[ k ] $0
            }
            else lines[$1] = $0;
          }

END { for( k in lines ) print lines[ k ] }

像这样使用它：awk -f script.awk file1 file2

PROCINFO 对 gnu awk 来说是特殊的。如果你不需要排序并且没有gnu awk，你可以注释掉第一行，看看会发生什么。