在变量中使用引号的批处理问题

Question

这里的批处理脚本相对较新，我一直在到处寻找答案，但什么也没找到。

到目前为止，这是我所拥有的批处理脚本..

@echo off

set addtext="text to add includes spaces"

for /f "delims=" %%l in (file.txt) do (
    echo %%l %addtext% >> tmpfile.txt
)

我希望在文件的每一行中添加一行文本，但我的问题在于双引号。我不希望引号与文本一起显示。
我在那里只有引号，因为我希望添加到每一行的文本字符串中有空格。

Answer 1

@echo off
    setlocal enableextensions disabledelayedexpansion
    set "addtext=text to add includes spaces"

    for /f "delims=" %%l in (file.txt) do (
        >> tmpfile.txt echo %%l %addtext%
    )

这应该可行。只是不要在变量的值中包含引号，而是使用它们来包装赋值。

如果字符串可能包含更多有问题的字符，这是一个更安全的版本

@echo off
    setlocal enableextensions disabledelayedexpansion
    set "addtext=text to add includes spaces, > redirections & more problems !"

    (for %%a in ("%addtext%") do for /f "delims=" %%l in (file.txt) do (
        echo %%l %%~a
    )) >> tmpfile.txt 

1. 引号不包含在值中，但包含赋值
2. 为防止访问变量时出现问题，它用引号括起来，存储在 for 可替换参数 (%%a) 中，并在请求时不带引号回显 (%%~a)
3. 只是为了获得更好的性能（也应该在第一个代码中使用）而不是打开/写入/关闭每一行的输出文件（每个echo 的重定向），重定向是针对完整的for 命令处理的.