awk 用空格打印从第 n 到最后的所有列

Question

我有以下输入文件：

a 1  o p
b  2 o p p
c     3 o p p  p

在最后一行中，最后一个p's 之间有一个双空格， 和列有不同的间距

我使用的解决方案来自：Using awk to print all columns from the nth to the last。

awk '{for(i=2;i<=NF;i++){printf "%s ", $i}; printf "\n"}'

它工作正常，直到它在最后一列达到双倍空格并删除一个空格。

在使用 awk 的同时如何避免这种情况？

Answer 1

既然你想保留空格，我们就用cut：

$ cut -d' ' -f2- file
1 o p
2 o p p
3 o p p  p

或者例如从第 4 列开始：

$ cut -d' ' -f4- file
p
p p
p p  p

只要您要删除的列用一个空格分隔，这将起作用。

---

如果您要删除的列也包含不同数量的空格，您可以使用 Ed Morton 在Print all but the first three columns 中的漂亮解决方案：

awk '{sub(/[[:space:]]*([^[:space:]]+[[:space:]]+){1}/,"")}1'
                                                   ^
                                        number of cols to remove

测试

$ cat a
a 1 o p
b    2 o p p
c  3 o p p  p
$ awk '{sub(/[[:space:]]*([^[:space:]]+[[:space:]]+){2}/,"")}1' a
o p
o p p
o p p  p

Answer 2

GNU sed

删除前 n 个字段

sed -r 's/([^ ]+ +){2}//' file

GNU awk 4.0+

awk '{sub("([^"FS"]"FS"){2}","")}1' file

GNU awk

awk --re-interval '{sub("([^"FS"]"FS"){2}","")}1' file

万一 FS 不起作用（Eds 建议）

awk '{sub(/([^ ] ){2}/,"")}1' file

将 2 替换为您要删除的字段数

编辑

另一种方式（不需要重新间隔）

awk '{for(i=0;i<2;i++)sub($1"[[:space:]]*","")}1' file

进一步编辑

按照 EdMorton 的建议，在 sub 中使用字段是不好的，因为它们可能包含元字符，所以这里有一个替代方案（再次！）

awk '{for(i=0;i<2;i++)sub(/[^[:space:]]+[[:space:]]*/,"")}1' file

输出

o p
o p p
o p p  p

Answer 3

在 Perl 中，您可以使用 split 和捕获来保留分隔符：

perl -ne '@f = split /( +)/; print @f[ 1 * 2 .. $#f ]'
#                                      ^
#                                      |
#                              column number goes
#                              here (starting from 0)

Answer 4

如果您想在第二列开始后保留 所有 个空格，这可以解决问题：

{
    match($0, ($1 "[ \\t*]+"))
    print substr($0, RSTART+RLENGTH)
}

对 match 的调用定位行上第一个“标记”的开始以及第一个标记的长度和它后面的空格。然后，您只需打印 之后的所有内容。

您可以将其概括为以这种方式忽略前 N 个标记：

BEGIN {
    N = 2
}

{
    r = ""
    for (i=1; i<=N; i++) {
        r = (r $i "[ \\t*]+")
    }
    match($0, r)
    print substr($0, RSTART+RLENGTH)
}

将上述脚本应用于您的示例输入会产生：

o p
o p p
o p p  p